File Coverage

blib/lib/Net/Async/FastCGI.pm

Criterion	Covered	Total	%
statement	32	35	91.4
branch	2	2	100.0
condition			n/a
subroutine	10	11	90.9
pod	3	3	100.0
total	47	51	92.1

#  You may distribute under the terms of either the GNU General Public License
#  or the Artistic License (the same terms as Perl itself)
#
#  (C) Paul Evans, 2005-2024 -- [e-mail]

package Net::Async::FastCGI 0.26;

use v5.14;
use warnings;

use Carp;

use base qw( IO::Async::Listener );
IO::Async::Listener->VERSION( '0.35' );

use Net::Async::FastCGI::ServerProtocol;

# The FCGI_GET_VALUES request might ask for our maximally supported number of
# concurrent connections or requests. We don't really have an inbuilt maximum,
# so just respond these large numbers
our $MAX_CONNS = 1024;
our $MAX_REQS  = 1024;

=head1 NAME

C - use FastCGI with L

=head1 SYNOPSIS

As an adapter:

   use Net::Async::FastCGI;
   use IO::Async::Loop;

   my $loop = IO::Async::Loop->new();

   my $fastcgi = Net::Async::FastCGI->new(
      on_request => sub {
         my ( $fastcgi, $req ) = @_;

         # Handle the request here
      }
   );

   $loop->add( $fastcgi );

   $fastcgi->listen(
      service => 1234,
      on_resolve_error => sub { die "Cannot resolve - $_[-1]\n" },
      on_listen_error  => sub { die "Cannot listen - $_[-1]\n" },
   );

   $loop->run;

As a subclass:

   package MyFastCGIResponder;
   use base qw( Net::Async::FastCGI );

   sub on_request
   {
      my $self = shift;
      my ( $req ) = @_;

      # Handle the request here
   }

   ...

   use IO::Async::Loop;

   my $loop = IO::Async::Loop->new();

   my $fastcgi;
   $loop->add( $fastcgi = MyFastCGIResponder->new( service => 1234 ) );

   $fastcgi->listen(
      service => 1234,
      on_resolve_error => sub { die "Cannot resolve - $_[-1]\n" },
      on_listen_error  => sub { die "Cannot listen - $_[-1]\n" },
   );

   $loop->run;

=head1 DESCRIPTION

This module allows a program to respond asynchronously to FastCGI requests,
as part of a program based on L. An object in this class represents
a single FastCGI responder that the webserver is configured to communicate
with. It can handle multiple outstanding requests at a time, responding to
each as data is provided by the program. Individual outstanding requests that
have been started but not yet finished, are represented by instances of
L.

=cut

=head1 EVENTS

The following events are invoked, either using subclass methods or CODE
references in parameters:

=head2 on_request $req

Invoked when a new FastCGI request is received. It will be passed a new
L object.

=cut

=head1 PARAMETERS

The following named parameters may be passed to C or C:

=over 8

=item on_request => CODE

CODE references for C event handler.

=item default_encoding => STRING

Sets the default encoding used by all new requests. If not supplied then
C will apply.

=item stream_stdin => BOOL

If true, requests will expect to handling streaming of stdin data. In this
mode, the C event handler will be invoked once parameters for a
new request have been received, even if the stdin stream is not yet complete.

=back

=cut

sub _init
{
   my $self = shift;
   my ( $params ) = @_;
   $self->SUPER::_init( $params );

   $params->{default_encoding} = "UTF-8";
}

sub configure
{
   my $self = shift;
   my %params = @_;

   foreach (qw( on_request default_encoding stream_stdin )) {
      exists $params{$_} and
         $self->{$_} = delete $params{$_};
   }

   $self->SUPER::configure( %params );
}

sub on_stream
{
   my $self = shift;
   my ( $stream ) = @_;

   $self->add_child( Net::Async::FastCGI::ServerProtocol->new(
      transport    => $stream,
      fcgi         => $self,
      stream_stdin => $self->{stream_stdin},
   ) );
}

=head1 METHODS

=cut

=head2 listen

   $fcgi->listen( %args );

Start listening for connections on a socket, creating it first if necessary.

This method may be called in either of the following ways. To listen on an
existing socket filehandle:

=over 4

=item handle => IO

An IO handle referring to a listen-mode socket. This is now deprecated; use
the C key to the C or C methods instead.

=back

Or, to create the listening socket or sockets:

=over 4

=item service => STRING

Port number or service name to listen on.

=item host => STRING

Optional. If supplied, the hostname will be resolved into a set of addresses,
and one listening socket will be created for each address. If not, then all
available addresses will be used.

=back

This method may also require C or C
callbacks for error handling - see L for more detail.

=cut

sub listen
{
   my $self = shift;
   my %args = @_;

   $self->SUPER::listen( %args, socktype => 'stream' );
}

sub _request_ready
{
   my $self = shift;
   my ( $req ) = @_;

   $self->invoke_event( on_request => $req );

   $req->_start;
}

sub _default_encoding
{
   my $self = shift;
   return $self->{default_encoding};
}

=head1 Limits in FCGI_GET_VALUES

The C FastCGI request can enquire of the responder the
maximum number of connections or requests it can support. Because this module
puts no fundamental limit on these values, it will return some arbitrary
numbers. These are given in package variables:

   $Net::Async::FastCGI::MAX_CONNS = 1024;
   $Net::Async::FastCGI::MAX_REQS  = 1024;

These variables are provided in case the containing application wishes to make
the library return different values in the request. These values are not
actually used by the library, other than to fill in the values in response of
C.

=head1 Using a socket on STDIN

When running a local FastCGI responder, the webserver will create a new INET
socket connected to the script's STDIN file handle. To use the socket in this
case, it should be passed as the C argument.

=head1 SEE ALSO

=over 4

=item *

L - Fast CGI drop-in replacement of L; single-threaded,
blocking mode.

=item *

L - The Common Gateway
Interface Specification

=item *

L - FastCGI Specification

=back

=head1 AUTHOR

Paul Evans

=cut

0x55AA;