File Coverage

lib/Neo4j/Driver/ResultSummary.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	2	2	100.0
condition	8	8	100.0
subroutine	11	11	100.0
pod	5	7	100.0
total	55	57	100.0

use v5.12;
use warnings;

package Neo4j::Driver::ResultSummary 1.02;
# ABSTRACT: Details about the result of running a query


use Carp qw(croak);

use Neo4j::Driver::SummaryCounters;


sub new {
	# uncoverable pod (private method)
	my ($class, $result, $notifications, $query, $server_info) = @_;

	return bless {
		counters => $result->{stats},
		notifications => $notifications,
		plan => $result->{plan},
		query => $query,
		server_info => $server_info,
	}, $class;
}


sub counters {
	my ($self) = @_;

	$self->{counters} //= {};
	return Neo4j::Driver::SummaryCounters->new( $self->{counters} );
}


sub notifications {
	my ($self) = @_;

	$self->{notifications} //= [];
	return @{ $self->{notifications} };
}


sub plan {
	my ($self) = @_;

	return $self->{plan};
}


sub statement {
	# uncoverable pod (see query)
	warnings::warnif deprecated => "statement() in Neo4j::Driver::ResultSummary is deprecated; use query() instead";
	&query;
}


sub query {
	my ($self) = @_;

	$self->{query} //= [ '', {} ];
	return ref $self->{query} eq 'ARRAY' ? {
		text       => $self->{query}->[0],
		parameters => $self->{query}->[1],
	} : {
		text       => $self->{query}->{statement},
		parameters => $self->{query}->{parameters} // {},
	};
}


sub server {
	my ($self) = @_;

	return $self->{server_info};
}


1;

__END__