File Coverage

blib/lib/Music/ScaleNote.pm

Criterion	Covered	Total	%
statement	71	71	100.0
branch	17	26	65.3
condition	18	26	69.2
subroutine	12	12	100.0
pod	2	2	100.0
total	120	137	87.5

package Music::ScaleNote;
our $AUTHORITY = 'cpan:GENE';

# ABSTRACT: Manipulate the position of a note in a scale

our $VERSION = '0.0805';

use Moo;
use strictures 2;
use Carp qw(croak);
use Array::Circular ();
use List::SomeUtils qw( first_index );
use MIDI::Util qw(midi_format);
use Music::Note ();
use Music::Scales qw( get_scale_notes );
use namespace::clean;


has scale_note => (
    is      => 'ro',
    default => sub { 'C' },
);


has scale_name => (
    is      => 'ro',
    default => sub { 'major' },
);


has note_format => (
    is      => 'ro',
    default => sub { 'ISO' },
);


has offset => (
    is      => 'ro',
    isa     => sub { die 'Not a negative or positive integer' unless $_[0] =~ /^-?\d+$/ },
    default => sub { 1 },
);


has flat => (
    is      => 'ro',
    default => sub { 0 },
);


has verbose => (
    is      => 'ro',
    default => sub { 0 },
);


sub get_offset {
    my ( $self, %args ) = @_;

    my $name   = $args{note_name};
    my $format = $args{note_format} || $self->note_format;
    my $offset = $args{offset} || $self->offset;
    my $flat   = $args{flat} || $self->flat;

    croak 'note_name, note_format or offset not provided'
        unless $name || $format || $offset;

    my $note = Music::Note->new( $name, $format );
    $note->en_eq('flat') if $flat && $note->format('isobase') =~ /#/;

    printf "Given note: %s, Format: %s, ISO: %s, Offset: %d\n",
        $name, $format, $note->format('ISO'), $offset
        if $self->verbose;

    my @scale = get_scale_notes( $self->scale_note, $self->scale_name );
    @scale = midi_format(0, @scale);
    if ( $flat ) {
        for ( @scale ) {
            if ( $_ =~ /#/ ) {
                my $equiv = Music::Note->new( $_, $format );
                $equiv->en_eq('flat');
                $_ = $equiv->format('isobase');
            }
        }
    }
    print "\tScale: @scale\n"
        if $self->verbose;

    my $ac = Array::Circular->new( @scale );

    my $posn = first_index { $note->format('isobase') eq $_ } @scale;
    if ( $posn >= 0 ) {
        printf "\tPosition: %d\n", $posn
            if $self->verbose;
        $ac->index( $posn );
    }
    else {
        croak 'Scale position not defined!';
    }

    $ac->next( $offset );

    my $octave = $note->octave;
    $octave += $ac->loops;

    $note = Music::Note->new( $ac->current . $octave, 'ISO' );

    printf "\tOctave: %d, ISO: %s, Formatted: %s\n",
        $octave, $note->format('ISO'), $note->format($format)
        if $self->verbose;

    return $note;
}


sub step {
    my ( $self, %args ) = @_;

    my $name  = $args{note_name};
    my $steps = $args{steps} || 1;
    my $flat  = $args{flat} || $self->flat;

    croak 'note_name not provided'
        unless $name;

    my $note = Music::Note->new( $name, $self->note_format );
    my $num  = $note->format('midinum');

    printf "Given note: %s, ISO: %s, Formatted: %d\n",
        $name, $note->format('ISO'), $num
        if $self->verbose;

    $num += $steps;
    $note = Music::Note->new( $num, 'midinum' );
    $note->en_eq('flat') if $flat && $note->format('isobase') =~ /#/;

    printf "\tNew steps: %d, ISO: %s, Formatted: %s\n",
        $steps, $note->format('ISO'), $note->format( $self->note_format )
        if $self->verbose;

    return $note;
}

1;

__END__