File Coverage

blib/lib/Music/ModalFunction.pm

Criterion	Covered	Total	%
statement	79	79	100.0
branch	38	52	73.0
condition	2	6	33.3
subroutine	16	16	100.0
pod	3	3	100.0
total	138	156	88.4

package Music::ModalFunction;
our $AUTHORITY = 'cpan:GENE';

# ABSTRACT: Query for modal and scalar musical functions

our $VERSION = '0.0504';

use strictures 2;
use AI::Prolog ();
use Carp qw(croak);
use MIDI::Util qw(midi_format);
use Moo;
use Music::Note ();
use Music::Scales qw(get_scale_notes);
use namespace::clean;


has [qw(chord_note chord mode_note mode mode_function mode_roman key_note key key_function key_roman)] => (
    is => 'ro',
);

has [qw(verbose use_scales hash_results)] => (
    is      => 'ro',
    isa     => sub { croak "$_[0] is not a boolean" unless $_[0] =~ /^[01]$/ },
    default => sub { 0 },
);

has _chord_key => (
    is      => 'ro',
    default => sub { [qw(method chord_note chord key_note key key_function key_roman)] },
);

has _pivot_chord_keys => (
    is      => 'ro',
    default => sub { [qw(method chord_note chord mode_note mode mode_function mode_roman key_note key key_function key_roman)] },
);

has _roman_key => (
    is      => 'ro',
    default => sub { [qw(method mode mode_roman key key_roman)] },
);

has [qw(_modes _scales _database _prolog)] => (
    is => 'lazy',
);

sub _build__modes {
    return {
        ionian => [
            { chord => 'maj', roman => 'r_I',   function => 'tonic' },
            { chord => 'min', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'min', roman => 'r_iii', function => 'mediant' },
            { chord => 'maj', roman => 'r_IV',  function => 'subdominant' },
            { chord => 'maj', roman => 'r_V',   function => 'dominant' },
            { chord => 'min', roman => 'r_vi',  function => 'submediant' },
            { chord => 'dim', roman => 'r_vii', function => 'leading_tone' },
        ],
        dorian => [
            { chord => 'min', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'min', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'maj', roman => 'r_III', function => 'mediant' },
            { chord => 'maj', roman => 'r_IV',  function => 'subdominant' },
            { chord => 'min', roman => 'r_v',   function => 'dominant' },
            { chord => 'dim', roman => 'r_vi',  function => 'submediant' },
            { chord => 'maj', roman => 'r_VII', function => 'subtonic' },
        ],
        phrygian => [
            { chord => 'min', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'maj', roman => 'r_II',  function => 'supertonic' },
            { chord => 'maj', roman => 'r_III', function => 'mediant' },
            { chord => 'min', roman => 'r_iv',  function => 'subdominant' },
            { chord => 'dim', roman => 'r_v',   function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',  function => 'submediant' },
            { chord => 'min', roman => 'r_vii', function => 'subtonic' },
        ],
        lydian => [
            { chord => 'maj', roman => 'r_I',   function => 'tonic' },
            { chord => 'maj', roman => 'r_II',  function => 'supertonic' },
            { chord => 'min', roman => 'r_iii', function => 'mediant' },
            { chord => 'dim', roman => 'r_iv',  function => 'subdominant' },
            { chord => 'maj', roman => 'r_V',   function => 'dominant' },
            { chord => 'min', roman => 'r_vi',  function => 'submediant' },
            { chord => 'min', roman => 'r_vii', function => 'leading_tone' },
        ],
        mixolydian => [
            { chord => 'maj', roman => 'r_I',   function => 'tonic' },
            { chord => 'min', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'dim', roman => 'r_iii', function => 'mediant' },
            { chord => 'maj', roman => 'r_IV',  function => 'subdominant' },
            { chord => 'min', roman => 'r_v',   function => 'dominant' },
            { chord => 'min', roman => 'r_vi',  function => 'submediant' },
            { chord => 'maj', roman => 'r_VII', function => 'subtonic' },
        ],
        aeolian => [
            { chord => 'min', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'dim', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'maj', roman => 'r_III', function => 'mediant' },
            { chord => 'min', roman => 'r_iv',  function => 'subdominant' },
            { chord => 'min', roman => 'r_v',   function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',  function => 'submediant' },
            { chord => 'maj', roman => 'r_VII', function => 'subtonic' },
        ],
        locrian => [
            { chord => 'dim', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'maj', roman => 'r_II',  function => 'supertonic' },
            { chord => 'min', roman => 'r_iii', function => 'mediant' },
            { chord => 'min', roman => 'r_iv',  function => 'subdominant' },
            { chord => 'maj', roman => 'r_V',   function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',  function => 'submediant' },
            { chord => 'min', roman => 'r_vii', function => 'subtonic' },
        ],
    }
}

sub _build__scales {
    return {
        harmonic_minor => [
            { chord => 'min', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'dim', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'aug', roman => 'r_III', function => 'mediant' },
            { chord => 'min', roman => 'r_iv',  function => 'subdominant' },
            { chord => 'maj', roman => 'r_V',   function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',  function => 'submediant' },
            { chord => 'dim', roman => 'r_vii', function => 'subtonic' },
        ],
        melodic_minor => [
            { chord => 'min', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'min', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'aug', roman => 'r_III', function => 'mediant' },
            { chord => 'maj', roman => 'r_IV',  function => 'subdominant' },
            { chord => 'maj', roman => 'r_V',   function => 'dominant' },
            { chord => 'dim', roman => 'r_vi',  function => 'submediant' },
            { chord => 'dim', roman => 'r_vii', function => 'subtonic' },
        ],
        pentatonic => [
            { chord => 'maj', roman => 'r_I',   function => 'tonic' },
            { chord => 'min', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'min', roman => 'r_iii', function => 'mediant' },
            { chord => 'maj', roman => 'r_IV',  function => 'subdominant' },
            { chord => 'min', roman => 'r_vi',  function => 'submediant' },
        ],
        pentatonic_minor => [
            { chord => 'min', roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'dim', roman => 'r_ii',  function => 'supertonic' },
            { chord => 'min', roman => 'r_iv',  function => 'subdominant' },
            { chord => 'min', roman => 'r_v',   function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',  function => 'submediant' },
        ],
        blues => [
            { chord => 'min',  roman => 'r_i',   function => 'parallel_minor' },
            { chord => 'maj',  roman => 'r_III', function => 'supertonic' },
            { chord => 'sus4', roman => 'r_IV',  function => 'subdominant' },
            { chord => 'maj',  roman => 'r_bV',  function => 'flat5' },
            { chord => 'min',  roman => 'r_v',   function => 'dominant' },
            { chord => 'sus4', roman => 'r_VII', function => 'leading_tone' },
        ],
        diminished => [
            { chord => 'maj', roman => 'r_I',    function => 'tonic' },
            { chord => 'dim', roman => 'r_bii',  function => 'flat2' },
            { chord => 'maj', roman => 'r_bIII', function => 'flat3' },
            { chord => 'dim', roman => 'r_iii',  function => 'mediant' },
            { chord => 'maj', roman => 'r_bV',   function => 'flat5' },
            { chord => 'dim', roman => 'r_v',    function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',   function => 'submediant' },
            { chord => 'dim', roman => 'r_vii',  function => 'leading_tone' },
        ],
        augmented => [
            { chord => 'aug', roman => 'r_I',    function => 'tonic' },
            { chord => 'aug', roman => 'r_bIII', function => 'flat3' },
            { chord => 'maj', roman => 'r_III',  function => 'mediant' },
            { chord => 'maj', roman => 'r_V',    function => 'dominant' },
            { chord => 'maj', roman => 'r_VI',   function => 'submediant' },
            { chord => 'aug', roman => 'r_VII',  function => 'leading_tone' },
        ],
    }
}

sub _build__database {
    my ($self) = @_;

    # consider every note
    my @chromatic = get_scale_notes('c', 'chromatic', 0, 'b');
    my $database = '';

    my $list = $self->use_scales ? $self->_scales : $self->_modes;

    # build a prolog fact for each base note
    for my $base (@chromatic) {
        my ($mode_base) = map { lc } midi_format($base);

        # consider each mode or scale properties
        for my $item (sort keys %$list) {
            # get the notes of the base note mode or scale
            my @notes = get_scale_notes($base, $item);
#            warn "Basics: $base $item [@notes]\n" if $self->verbose;

            my @pitches; # notes suitable for the prolog database

            # convert the notes to flatted, lower-case
            for my $note (@notes) {
                my $n = Music::Note->new($note, 'isobase');
                $n->en_eq('flat') if $note =~ /#/;
                push @pitches, map { lc } midi_format($n->format('isobase'));
            }

            my $i = 0; # increment

            for my $pitch (@pitches) {
                # get the properties of the given mode or scale
                my ($chord, $function, $roman);
                if ($self->use_scales) {
                    $chord    = $self->_scales->{$item}[$i]{chord};
                    $function = $self->_scales->{$item}[$i]{function};
                    $roman    = $self->_scales->{$item}[$i]{roman};
                }
                else {
                    $chord    = $self->_modes->{$item}[$i]{chord};
                    $function = $self->_modes->{$item}[$i]{function};
                    $roman    = $self->_modes->{$item}[$i]{roman};
                }

                # append to the database of facts
                $database .= "chord_key($pitch, $chord, $mode_base, $item, $function, $roman).\n"
                    if $chord && $function && $roman;

                $i++;
            }
        }
    }
    # append the prolog rules
    $database .= <<'RULES';
pivot_chord_keys(ChordNote, Chord, Key1Note, Key1, Key1Function, Key1Roman, Key2Note, Key2, Key2Function, Key2Roman) :-
    % bind the chord to the function of the first key
    chord_key(ChordNote, Chord, Key1Note, Key1, Key1Function, Key1Roman),
    % bind the chord to the function of the second key
    chord_key(ChordNote, Chord, Key2Note, Key2, Key2Function, Key2Roman),
    % the functions cannot be the same
    Key1Function \= Key2Function.

roman_key(Mode, ModeRoman, Key, KeyRoman) :-
    chord_key(_, _, _, Mode, ModeFunction, ModeRoman),
    chord_key(_, _, _, Key, KeyFunction, KeyRoman),
    ModeFunction \= KeyFunction.
RULES
#    warn "Database: $database\n" if $self->verbose;

    return $database;
}

sub _build__prolog {
    my ($self) = @_;
    return AI::Prolog->new($self->_database);
}


sub chord_key {
    my ($self) = @_;
    my $query = sprintf 'chord_key(%s, %s, %s, %s, %s, %s).',
        defined $self->chord_note   ? $self->chord_note   : 'ChordNote',
        defined $self->chord        ? $self->chord        : 'Chord',
        defined $self->key_note     ? $self->key_note     : 'KeyNote',
        defined $self->key          ? $self->key          : 'Key',
        defined $self->key_function ? $self->key_function : 'KeyFunction',
        defined $self->key_roman    ? $self->key_roman    : 'KeyRoman';
    return $self->_querydb('chord_key', $query);
}


sub pivot_chord_keys {
    my ($self) = @_;
    my $query = sprintf 'pivot_chord_keys(%s, %s, %s, %s, %s, %s, %s, %s, %s, %s).',
        defined $self->chord_note    ? $self->chord_note    : 'ChordNote',
        defined $self->chord         ? $self->chord         : 'Chord',
        defined $self->mode_note     ? $self->mode_note     : 'ModeNote',
        defined $self->mode          ? $self->mode          : 'Mode',
        defined $self->mode_function ? $self->mode_function : 'ModeFunction',
        defined $self->mode_roman    ? $self->mode_roman    : 'ModeRoman',
        defined $self->key_note      ? $self->key_note      : 'KeyNote',
        defined $self->key           ? $self->key           : 'Key',
        defined $self->key_function  ? $self->key_function  : 'KeyFunction',
        defined $self->key_roman     ? $self->key_roman     : 'KeyRoman';
    return $self->_querydb('pivot_chord_keys', $query);
}


sub roman_key {
    my ($self) = @_;
    my $query = sprintf 'roman_key(%s, %s, %s, %s).',
        defined $self->mode       ? $self->mode       : 'Mode',
        defined $self->mode_roman ? $self->mode_roman : 'ModeRoman',
        defined $self->key        ? $self->key        : 'Key',
        defined $self->key_roman  ? $self->key_roman  : 'KeyRoman';
    return $self->_querydb('roman_key', $query);
}

sub _querydb {
    my ($self, $method, $query) = @_;

    warn "$method query: $query\n" if $self->verbose;

    $self->_prolog->query($query);

    my $attr = '_' . $method;

    my @return;

    while (my $result = $self->_prolog->results) {
#warn __PACKAGE__,' L',__LINE__,' ',,"R: @$result\n";
        if ($self->hash_results) {
            my %result;
            @result{ @{ $self->$attr } } = @$result;
            push @return, \%result;
        }
        else {
            push @return, $result;
        }
    }

    return \@return;
}

1;

__END__