File Coverage

blib/lib/Mojolicious/Plugin/Statsd/Adapter/Memory.pm

Criterion	Covered	Total	%
statement	21	23	91.3
branch	5	12	41.6
condition	14	18	77.7
subroutine	3	3	100.0
pod	2	2	100.0
total	45	58	77.5

package Mojolicious::Plugin::Statsd::Adapter::Memory;

use Mojo::Base -base;

our $VERSION = '0.06';

# scalar values: counter
# hashref values: timings (keys: samples[] avg min max)
has stats => sub {
  {}
};

sub timing {
  my ($self, $names, $time, $sample_rate) = @_;

  if (($sample_rate // 1) != 1) {
    return unless rand() <= $sample_rate;
  }

  my $stats = $self->stats;
  for my $key (@$names) {
    my $timing = $stats->{$key} //= {};

    ($timing->{samples} //= 0) += 1;

    $timing->{avg} =
      (($timing->{avg} // 0) + $time) / $timing->{samples};

    if (!exists $timing->{min} or $timing->{min} > $time) {
      $timing->{min} = $time;
    }

    if (!exists $timing->{max} or $timing->{max} < $time) {
      $timing->{max} = $time;
    }
  }
  return 1;
}

sub counter {
  my ($self, $counters, $delta, $sample_rate) = @_;

  if (($sample_rate // 1) != 1) {
    return unless rand() <= $sample_rate;
  }

  my $stats = $self->stats;

  for my $name (@$counters) {
    ($stats->{$name} //= 0) += $delta;
  }
  return 1;
}

1;

# ABSTRACT In-Memory stat recording

__END__