File Coverage

blib/lib/Mojolicious/Plugin/RedirectHost.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	14	14	100.0
condition	3	5	60.0
subroutine	4	4	100.0
pod	1	1	100.0
total	49	51	96.0

package Mojolicious::Plugin::RedirectHost;

use Mojo::Base 'Mojolicious::Plugin';
use Mojo::URL;

our $VERSION = '1.05';    # VERSION

# where to look for options
my $CONFIG_KEY   = 'redirect_host';
my $DEFAULT_CODE = 301;
my $EXCEPT_PATH  = '/robots.txt';

sub register {
  my ($self, $app, $params) = @_;

  my %options;
  if (ref $params eq 'HASH' && scalar keys %$params) {
    %options = %$params;
  }
  elsif (ref $app->config($CONFIG_KEY) eq 'HASH') {
    %options = %{$app->config($CONFIG_KEY)};
  }

  unless ($options{host}) {
    my $msg = 'RedirectHost plugin: define "host" option at least!';
    $app->log->error($msg) unless $options{silent};

    return;
  }

  $app->hook(
    before_dispatch => sub {
      my $c    = shift;
      my $url  = $c->req->url->to_abs;
      my $path = $c->req->url->path;


      # don't need redirection
      return if $url->host eq $options{host};

      # except_robots?
      if ($options{er}) {
        return if $path eq $EXCEPT_PATH;
      }

      # main host
      $url->host($options{host});

      # code
      $c->res->code($options{code} || $DEFAULT_CODE);


      $c->redirect_to($url->to_string);
    }
  );

  return;
}

1;

# ABSTRACT: Redirects requests from mirrors to the main host (useful for SEO)

__END__