File Coverage

blib/lib/Mojolicious/Command/credentials.pm

Criterion	Covered	Total	%
statement	27	58	46.5
branch	0	30	0.0
condition	0	3	0.0
subroutine	9	11	81.8
pod	1	1	100.0
total	37	103	35.9

package Mojolicious::Command::credentials;
$Mojolicious::Command::credentials::VERSION = '0.007';
use Mojo::Base 'Mojolicious::Command', -signatures;

use Env '$EDITOR';
use File::Slurper qw/read_binary write_binary/;
use File::Temp 'tempfile';
use Getopt::Long 'GetOptionsFromArray';
use IPC::Cmd 'can_run';
use List::Util 'first';
use Text::ParseWords 'shellwords';
use YAML::PP 'LoadFile';

has description => 'Edit the applications credentials';

has usage => sub { shift->extract_usage };

sub run($self, $command, @args) {
	die $self->usage unless defined $command;

	my $credentials = $self->app->credentials;

	if ($command eq 'edit') {
		my $editor = $EDITOR // first { can_run($_) } qw/editor vi nano/;
		die 'Could not find an editor' if not defined $editor;
		GetOptionsFromArray(\@args, 'yaml' => \my $yaml, 'editor=s' => \$editor) or die "Invalid arguments";
		my $name = shift @args or die 'No credential name given';

		my $suffix = $yaml ? '.yaml' : undef;
		my ($fh, $filename) = tempfile(UNLINK => 1, SUFFIX => $suffix);
		write_binary($filename, $credentials->get($name)) if $credentials->has($name);

		system shellwords($editor), $filename and die 'Could not save file';

		my $data = read_binary($filename);
		write_binary($filename, scalar('\0' x length $data));
		YAML::PP->new->load_string($data) if $yaml; # YAML validity check
		$credentials->put($name, $data);
	} elsif ($command eq 'show') {
		my $name = shift @args or die 'No credential name given';
		print $credentials->get($name);
	} elsif ($command eq 'list') {
		say for $credentials->list;
	} elsif ($command eq 'remove') {
		my $name = shift @args or die 'No credential name given';
		$credentials->remove($name);
	} elsif ($command eq 'recode') {
		print 'Please input new key in hex form: ';
		chomp(my $encoded_key = <>);
		my $key = pack "H*", $encoded_key;
		$credentials->recode($key);
	} else {
		die "Unknown subcommand $command"
	}
}

1;

# ABSTRACT: Manage your app's credentials

__END__