Mojo/Server/Morbo/Backend/Poll.pm untested

filter: Statementstmt 0.0% 0 / 30 Branchbran 0.0% 0 / 8 Conditioncond 0.0% 0 / 13 MC/DCmcdc 0.0% 0 / 8 Subroutinesub 0.0% 0 / 4 Podpod 0.0% 0 / 2 totaltotal 0.0% 0 / 65 CC 5 SCAR 29.7
CC
5
Cov
0%
modified_files
30.0
_list
2.0
BEGIN
2.0
CRAP 19.5
1 package Mojo::Server::Morbo::Backend::Poll;
2 use Mojo::Base 'Mojo::Server::Morbo::Backend';
3  
4 use Mojo::File qw(path);
5  
6 sub modified_files {
7 my $self = shift;
8  
9 my $cache = $self->{cache} //= {};
10 my $known_files = {map { $_ => 1 } keys %$cache};
11 my @files;
12 for my $file (map { -f $_ && -r _ ? $_ : _list($_) } @{$self->watch}) {
13 delete $known_files->{$file};
14 my ($size, $mtime) = (stat $file)[7, 9];
15 next unless defined $size and defined $mtime;
16 my $stats = $cache->{$file} ||= [$^T, $size];
17 next if $mtime <= $stats->[0] && $size == $stats->[1];
18 @$stats = ($mtime, $size);
19 push @files, $file;
20 }
21  
22 for my $file (keys %$known_files) {
23  
24 # Any leftover file means they were deleted
25 push @files, $file;
26 delete $cache->{$file};
27 }
28  
29 sleep $self->watch_timeout unless @files;
30  
31 return \@files;
32 }
33  
34 sub _list { path(shift)->list_tree->map('to_string')->each }
35  
36 1;
37  
38 =encoding utf8
39  
40 =head1 NAME
41  
42 Mojo::Server::Morbo::Backend::Poll - Morbo default backend
43  
44 =head1 SYNOPSIS
45  
46 use Mojo::Server::Morbo::Backend::Poll;
47  
48 my $backend = Mojo::Server::Morbo::Backend::Poll->new;
49 if (my $files = $backend->modified_files) {
50 ...
51 }
52  
53 =head1 DESCRIPTION
54  
55 L<Mojo::Server::Morbo::Backend::Poll> is the default backend for L<Mojo::Server::Morbo>.
56  
57 =head1 ATTRIBUTES
58  
59 L<Mojo::Server::Morbo::Backend::Poll> inherits all attributes from L<Mojo::Server::Morbo::Backend>.
60  
61 =head1 METHODS
62  
63 L<Mojo::Server::Morbo::Backend::Poll> inherits all methods from L<Mojo::Server::Morbo::Backend> and implements the
64 following new ones.
65  
66 =head2 modified_files
67  
68 my $files = $backend->modified_files;
69  
70 Check file size and mtime to determine which files have changed, this is not particularly efficient, but very portable.
71  
72 # All files that have been modified
73 say for @{$backend->modified_files};
74  
75 =head1 SEE ALSO
76  
77 L<Mojolicious>, L<Mojolicious::Guides>, L<https://mojolicious.org>.
78  
79 =cut