File Coverage

lib/Modern/Open.pm

Criterion	Covered	Total	%
statement	173	209	82.7
branch	34	58	58.6
condition	8	33	24.2
subroutine	32	34	94.1
pod	5	7	71.4
total	252	341	73.9

package Modern::Open;
######################################################################
#
# Modern::Open - Autovivification, Autodie, and 3-args open support
#
# https://metacpan.org/dist/Modern-Open
#
# Copyright (c) 2014, 2015, 2018, 2019, 2020, 2021, 2023, 2026 INABA Hitoshi
######################################################################

use 5.00503;
use vars qw($VERSION $_fh_seq);
use strict;
BEGIN { if ($] < 5.006 && !defined(&warnings::import)) { $INC{'warnings.pm'} = 'stub';
        eval 'package warnings; sub import {}' } } use warnings; local $^W=1;

$VERSION = '0.15';
$VERSION = $VERSION;
$_fh_seq = 0;

BEGIN { pop @INC if $INC[-1] eq '.' } # CVE-2016-1238: Important unsafe module load path flaw
use Fcntl;

#---------------------------------------------------------------------
sub Modern::Open::confess (@) {
    my $i = 0;
    my @confess = ();
    while (my($package, $filename, $line, $subroutine) = caller($i)) {
        push @confess, "[$i] $filename($line) $subroutine\n";
        $i++;
    }
    print STDERR "\n", @_, "\n";
    print STDERR CORE::reverse @confess;
    die;
}

#---------------------------------------------------------------------
sub Modern::Open::open (*$;$) {
    my $handle;

    if (defined $_[0]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        $_fh_seq++;
        my $fhn = "Modern::Open::FH::H${_fh_seq}";
        no strict 'refs';
        $handle = $fhn;
        $_[0] = \*{$fhn};
    }

    if (@_ >= 4) {
        Modern::Open::confess "Too many arguments for open";
    }
    elsif (@_ == 3) {
        my($mode, $filename) = @_[1, 2];

        if ($mode eq '-|') {
            no strict 'refs';
            my $return = CORE::open($handle, qq{$filename |});
            if ($return or defined wantarray) {
                return $return;
            }
            else {
                Modern::Open::confess "Can't open($_[0],$_[1],$_[2]): $!";
            }
        }
        elsif ($mode eq '|-') {
            no strict 'refs';
            my $return = CORE::open($handle, qq{| $filename});
            if ($return or defined wantarray) {
                return $return;
            }
            else {
                Modern::Open::confess "Can't open($_[0],$_[1],$_[2]): $!";
            }
        }
        else {
            my %flags = (
                '<'   => O_RDONLY,
                '>'   => O_WRONLY | O_TRUNC | O_CREAT,
                '>>'  => O_WRONLY |O_APPEND | O_CREAT,
                '+<'  => O_RDWR,
                '+>'  => O_RDWR | O_TRUNC  | O_CREAT,
                '+>>' => O_RDWR | O_APPEND | O_CREAT,
            );
            if (not exists $flags{$mode}) {
                Modern::Open::confess "Unknown open() mode '$mode'";
            }
            no strict 'refs';
            my $return = CORE::sysopen(*{$handle}, $filename, $flags{$mode});
            if ($return or defined wantarray) {
                return $return;
            }
            else {
                Modern::Open::confess "Can't open($_[0],$_[1],$_[2]): $!";
            }
        }
    }
    elsif (@_ == 2) {
        no strict 'refs';
        my $return = CORE::open($handle, $_[1]);
        if ($return or defined wantarray) {
            return $return;
        }
        else {
            Modern::Open::confess "Can't open($_[0],$_[1]): $!";
        }
    }
    else {
        Modern::Open::confess "Not enough arguments for open";
    }
}

#---------------------------------------------------------------------
sub Modern::Open::opendir (*$) {
    my $handle;

    if (defined $_[0]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        $_fh_seq++;
        my $fhn = "Modern::Open::FH::H${_fh_seq}";
        no strict 'refs';
        $handle = $fhn;
        $_[0] = \*{$fhn};
    }

    my $return;
    { no strict 'refs';
        if ($return = CORE::opendir(*{$handle}, $_[1])) {
        }
        elsif (($^O =~ /MSWin32/) and (-d qq{$_[1].})) {
            $return = CORE::opendir(*{$handle}, qq{$_[1].});
        }
    }

    if ($return or defined wantarray) {
        return $return;
    }
    else {
        Modern::Open::confess "Can't opendir($_[0],$_[1]): $!";
    }
}

#---------------------------------------------------------------------
sub Modern::Open::sysopen (*$$;$) {
    my $handle;

    if (defined $_[0]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        $_fh_seq++;
        my $fhn = "Modern::Open::FH::H${_fh_seq}";
        no strict 'refs';
        $handle = $fhn;
        $_[0] = \*{$fhn};
    }

    if (@_ >= 5) {
        Modern::Open::confess "Too many arguments for sysopen";
    }
    elsif (@_ == 4) {
        no strict 'refs';
        my $return = CORE::sysopen(*{$handle}, $_[1], $_[2], $_[3]);
        if ($return or defined wantarray) {
            return $return;
        }
        else {
            Modern::Open::confess "Can't sysopen($_[0],$_[1],$_[2],$_[3]): $!";
        }
    }
    elsif (@_ == 3) {
        no strict 'refs';
        my $return = CORE::sysopen(*{$handle}, $_[1], $_[2]);
        if ($return or defined wantarray) {
            return $return;
        }
        else {
            Modern::Open::confess "Can't sysopen($_[0],$_[1],$_[2]): $!";
        }
    }
    else {
        Modern::Open::confess "Not enough arguments for sysopen";
    }
}

#---------------------------------------------------------------------
sub Modern::Open::pipe (**) {
    my($handle0, $handle1);

    if (defined $_[0]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        $_fh_seq++;
        my $fhn0 = "Modern::Open::FH::P${_fh_seq}r";
        no strict 'refs';
        $handle0 = $fhn0;
        $_[0] = \*{$fhn0};
    }

    if (defined $_[1]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        my $fhn1 = "Modern::Open::FH::P${_fh_seq}w";
        no strict 'refs';
        $handle1 = $fhn1;
        $_[1] = \*{$fhn1};
    }

    no strict 'refs';
    my $return = CORE::pipe(*{$handle0}, *{$handle1});
    if ($return or defined wantarray) {
        return $return;
    }
    else {
        Modern::Open::confess "Can't pipe($_[0],$_[1]): $!";
    }
}

#---------------------------------------------------------------------
sub Modern::Open::socket (*$$$) {
    my $handle;

    if (defined $_[0]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        $_fh_seq++;
        my $fhn = "Modern::Open::FH::H${_fh_seq}";
        no strict 'refs';
        $handle = $fhn;
        $_[0] = \*{$fhn};
    }

    # socket doesn't autodie
    no strict 'refs';
    return CORE::socket(*{$handle}, $_[1], $_[2], $_[3]);
}

#---------------------------------------------------------------------
sub Modern::Open::accept (**) {
    my($handle0, $handle1);

    if (defined $_[0]) {
        Modern::Open::confess "Bare handle no longer supported";
    }
    else {
        $_fh_seq++;
        my $fhn = "Modern::Open::FH::H${_fh_seq}";
        no strict 'refs';
        $handle0 = $fhn;
        $_[0] = \*{$fhn};
    }

    no strict 'refs';
    my $return = CORE::accept(*{$handle0}, *{$_[1]});
    if ($return or defined wantarray) {
        return $return;
    }
    else {
        Modern::Open::confess "Can't accept($_[0],$_[1]): $!";
    }
}

#---------------------------------------------------------------------
sub import {

    # avoid: Can't use string ("main::open") as a symbol ref while "strict refs" in use
    no strict 'refs';
    {
        # avoid: Prototype mismatch: sub main::open (*;$) vs (*$;$)
        local $SIG{__WARN__} = sub {};
        *{caller() . '::open'} = \&Modern::Open::open;
    }
    *{caller() . '::opendir'}  = \&Modern::Open::opendir;
    *{caller() . '::sysopen'}  = \&Modern::Open::sysopen;
    *{caller() . '::pipe'}     = \&Modern::Open::pipe;
    *{caller() . '::socket'}   = \&Modern::Open::socket;
    *{caller() . '::accept'}   = \&Modern::Open::accept;
}

1;

__END__