File Coverage

blib/lib/Mo/utils/Country.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	6	6	100.0
condition	3	3	100.0
subroutine	12	12	100.0
pod	2	2	100.0
total	63	63	100.0

package Mo::utils::Country;

use base qw(Exporter);
use strict;
use warnings;

use Error::Pure qw(err);
use List::Util 1.33 qw(none);
use Locale::Country;
use Readonly;

Readonly::Array our @EXPORT_OK => qw(check_country_3166_1_alpha_2 check_country_3166_1_alpha_3);

our $VERSION = 0.02;

sub check_country_3166_1_alpha_2 {
	my ($self, $key) = @_;

	my $error = "Parameter '%s' doesn't contain valid ISO 3166-1 alpha-2 code.";

	_check_country($self, $key, LOCALE_CODE_ALPHA_2, $error);

	return;
}

sub check_country_3166_1_alpha_3 {
	my ($self, $key) = @_;

	my $error = "Parameter '%s' doesn't contain valid ISO 3166-1 alpha-3 code.";

	_check_country($self, $key, LOCALE_CODE_ALPHA_3, $error);

	return;
}

sub _check_key {
	my ($self, $key) = @_;

	if (! exists $self->{$key} || ! defined $self->{$key}) {
		return 1;
	}

	return 0;
}

sub _check_country {
	my ($self, $key, $codeset, $error) = @_;

	_check_key($self, $key) && return;

	if (none { $_ eq lc($self->{$key}) } all_country_codes($codeset)) {
		my $err = sprintf($error, $key);
		err $err,
			'Codeset', $codeset,
			'Value', $self->{$key},
		;
	}

	return;
}

1;

__END__