File Coverage

blib/lib/Minima/Router.pm

Criterion	Covered	Total	%
statement	14	14	100.0
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	19	19	100.0

use v5.40;
use experimental 'class';

class Minima::Router;

use Carp;
use Path::Tiny;
use Router::Simple;

field $router = Router::Simple->new;
field %special;
field $prefix = 'Controller';

method match ($env)
{
    my $match = $router->match($env);
    return $match if defined $match;

    $self->not_found_route;
}

method read_file ($file)
{
    $file = path($file);
    croak "Routes file `$file` does not exist.\n"
        unless -e $file->absolute;

    # Parse routes
    for ($file->lines_utf8) {
        # Skip blank or comment lines
        next if /^\s*#|^\s*$/;

        # Extract data
        $_ = trim $_;
        my ($method, $pattern, $controller, $action) = split;

        # Build destination and options
        my %dest = $self->_build_destination($controller, $action);
        my %opt  = $self->_build_options($method);

        # Test the nature of the route
        if ($method eq '@') {
            # Special
            $special{$pattern} = \%dest;
        } else {
            # Regular
            $router->connect($pattern, \%dest, \%opt);
        }
    }
}

method _build_command ($command, $action)
{
    state %redirects = (
        redirect           => 302,
        r                  => 302,
        redirect_permanent => 301,
        rp                 => 301,
    );

    # Remove initial `@`
    $command = substr($command, 1);

    croak "Unknown route command `$command`.\n"
        unless exists $redirects{$command};

    (
        redirect        => $action,
        redirect_status => $redirects{$command}
    )
}

method _build_destination ($controller, $action)
{
    if (defined $controller) {
        # Check if it is a command
        return $self->_build_command($controller, $action)
            if $controller =~ /^@/;

        # Fix controller prefix
        $controller =~ s/^:+/${prefix}::/;
    }

    ( controller => $controller, action => $action )
}

method _build_options ($method)
{
    return () if ($method eq '*'); # Don't add a constraint
    return ( method => [ qw/ GET HEAD / ] ) if $method eq 'GET';
    return ( method => 'GET' ) if $method eq '_GET';
    return ( method => $method );
}

method _connect
{
    $router->connect(@_);
}

method clear_routes
{
    $router  = Router::Simple->new;
    %special = ( );
}

method set_prefix ($new)
{
    $prefix = $new;
}

method not_found_route  { $special{not_found} }
method error_route      { $special{server_error} }

__END__