File Coverage

blib/lib/Minima/View/HTML.pm

Criterion	Covered	Total	%
statement	23	23	100.0
branch			n/a
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	31	31	100.0

use v5.40;
use experimental 'class';

class Minima::View::HTML :isa(Minima::View);

use Carp;
use Path::Tiny;
use Template;
use Template::Constants qw/ :debug /;
use utf8;

field $app                  :param;
field @include;
field $template;
field @before_template;
field @after_template;
field $default_data         = {};

field %settings = (
    block_indexing => 1,    # block robots with a
    name_as_class => 1,     # include template name in @classes
    theme_color => '',      # hex color for the
);

field %content = (
    title => undef,
    description => undef,
    header_scripts => [],   # scripts to be loaded in
    header_css => [],       # CSS to be loaded in
    body_open => [],        # used right after the opening of
    body_close => [],       # used right before the closing of
    scripts => [],          # scripts to be embedded directly in
    classes => [],          # classes added to  or
);

ADJUST {
    my $config = $app->config;

    $content{title} = $config->{default_title} // '';

    $settings{block_indexing} = $config->{block_indexing} // 1;
    $settings{name_as_class} = $config->{name_as_class} // 1;
    $settings{theme_color} = $config->{theme_color} // '';

    if (exists $config->{templates_dir}) {
        if (ref $config->{templates_dir} eq ref []) {
            $self->add_directory($_)
                for reverse @{ $config->{templates_dir} };
        }
    } else {
        $self->add_directory('js');
        $self->add_directory('templates');
    }
}

method add_directory        ($d) { unshift @include, $app->path($d) }
method clear_directories         { @include = () }
method set_template         ($t) { $template = $self->_ext($t) }
method add_before_template  ($p) { push @before_template, $self->_ext($p) }
method add_after_template   ($p) { push @after_template, $self->_ext($p) }
method set_default_data     ($d) { $default_data = $d }

method set_block_indexing   ($n = 1) { $settings{block_indexing} = $n }
method set_name_as_class    ($n = 1) { $settings{name_as_class} = $n }
method set_theme_color      ($c) { $settings{theme_color} = $c }

method set_title ($t, $d = undef)
{
    $content{title} = $t;
    $content{description} = $d;
}

method set_compound_title ($t, $d = undef)
{
    $self->set_title(
        ( $content{title} ? "$content{title} • $t" : $t ),
        $d
    );
}

method set_description      ($d) { $content{description} = $d }
method add_header_script    ($s) { push @{$content{header_scripts}}, $s }
method add_header_css       ($c) { push @{$content{header_css}}, $c }
method add_script           ($s) { push @{$content{scripts}}, $s }
method add_class            ($c) { push @{$content{classes}}, $c }

method add_body_open ($p)
{
    push @{$content{body_open}}, $self->_ext($p)
}

method add_body_close ($p)
{
    push @{$content{body_close}}, $self->_ext($p)
}

method prepare_response ($response)
{
    $response->content_type('text/html; charset=utf-8');
}

method render ($data = {})
{
    croak "No template set." unless $template;

    # Merge default data
    $data = { %$default_data, %$data };

    # Build vars to send to template
    my %vars = ( %content, settings => \%settings );
    $data->{view} = \%vars;

    # Format CSS classes
    my @classes = @{ $content{classes} };
    if ($settings{name_as_class}) {
        my $clean_name = $template;
        $clean_name =~ s/\.\w+$//;
        $clean_name =~ tr/./-/;
        push @classes, $clean_name;
    }
    $vars{classes} = "@classes";

    # If any var is undef, replace with empty string
    $vars{$_} //= '' for keys %vars;

    # Setup Template Toolkit:
    # Create a default and overwrite with user configuration.
    my %tt_default = (
        INCLUDE_PATH => \@include,
        OUTLINE_TAG => '%%',
        ANYCASE => 1,
        ENCODING => 'utf8',
    );
    my $tt_app_config = $app->config->{tt} // {};
    my %tt_config = ( %tt_default, %$tt_app_config );
    my $tt = Template->new(\%tt_config);

    # Render
    my ( $body, $r );

    for my $t (@before_template, $template, @after_template) {
        $r = $tt->process($t, $data, \$body);
        croak "Failed to load template `$t` (include path: `@include`): ",
              $tt->error, "\n" unless $r;
    }

    utf8::encode($body);
    $body;
}

method _ext ($file)
{
    my $ext = $app->config->{template_ext} // 'ht';
    $file = "$file.$ext" unless $file =~ /\.\w+$/;
    $file;
}

__END__