File Coverage

blib/lib/Minima/Setup.pm

Criterion	Covered	Total	%
statement	55	55	100.0
branch	18	18	100.0
condition	3	3	100.0
subroutine	10	10	100.0
pod	3	3	100.0
total	89	89	100.0

use v5.40;

package Minima::Setup;

use Carp;
use Minima::App;
use Path::Tiny;
use Plack::Test;
use YAML::XS 'LoadFile';

our $config = {};
our $app;
our $base;

sub import
{
    shift; # discard package name

    # If we were called from a .psgi, save
    # its parent as the base directory
    my $caller = path( (caller)[1] );
    if ($caller->basename =~ /\.psgi$/) {
        $base = $caller->absolute->parent;
    } else {
        $base = path('.')->absolute;
    }

    prepare(@_);
}

sub prepare ($file = undef)
{
    my $default_prefix = $base->child('etc/config');
    my @files = map { "$default_prefix.$_" } qw/ yaml yml pl /;

    if ($file) {
        my $file_abs = path($file)->absolute;

        croak "Config file `$file` does not exist.\n"
            unless -e $file_abs;

        $file = $file_abs;
    }
    unshift @files, $file;

    my $adjective;

    for (my $i = 0; $i < @files; $i++) {

        my $f = $files[$i];
        next unless defined $f && -e $f;

        $adjective = $i ? 'default ' : '';

        if ($f =~ /\.ya?ml$/) {
            try {
                $config = LoadFile $f;
            } catch ($e) {
                croak "Failed to parse ${adjective}config file "
                    . "`$f`:\n$e\n";
            }
        } else {
            $config = do $f;
            croak "Failed to parse ${adjective}config file "
                . "`$f`: $@\n" if $@;
        }

        last;
    }

    croak "Config is not a hash reference.\n"
        unless ref $config eq ref {};

    # If the loaded config does not set base_dir,
    # set it to the saved .psgi directory
    $config->{base_dir} = $base->stringify
        unless defined $config->{base_dir};

    # Initialize app
    $app = Minima::App->new(
        configuration => $config,
    );
}

sub init ($env)
{
    $app->set_env($env);
    $app->run;
}

sub test
{
    Plack::Test->create(\&init);
}

1;

__END__