File Coverage

blib/lib/Minima/Router.pm

Criterion	Covered	Total	%
statement	14	14	100.0
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	19	19	100.0

use v5.40;
use experimental 'class';

class Minima::Router;

use Carp;
use Path::Tiny;
use Router::Simple;

field $router = Router::Simple->new;
field %special;
field $prefix = 'Controller';

method match ($env)
{
    $router->match($env) // $special{not_found};
}

method read_file ($file)
{
    $file = path($file);
    croak "Routes file `$file` does not exist.\n"
        unless -e $file->absolute;

    # Parse routes
    for ($file->lines_utf8) {
        # Skip blank or comment lines
        next if /^\s*#|^\s*$/;

        # Extract data
        my ($method, $pattern, $controller, $action) = split;

        # Fix controller prefix
        $controller =~ s/^:+/${prefix}::/;

        # Build destination and options
        my %dest = ( controller => $controller, action => $action );
        my %opt;
        if ($method eq '*') {
            # Do nothing -- don't add a constraint
        } elsif ($method eq 'GET') {
            $opt{method} = [ qw/ GET HEAD / ];
        } elsif ($method eq '_GET') {
            $opt{method} = 'GET';
        } else {
            $opt{method} = $method;
        }

        # Test the nature of the route
        if ($method eq '@') {
            # Special
            $special{$pattern} = \%dest;
        } else {
            # Regular
            $router->connect($pattern, \%dest, \%opt);
        }
    }
}

method _connect
{
    $router->connect(@_);
}

method error_route
{
    $special{server_error}
}

method clear_routes
{
    $router  = Router::Simple->new;
    %special = ( );
}

method set_prefix ($new)
{
    $prefix = $new;
}

__END__