File Coverage

blib/lib/MetaCPAN/Client/ResultSet.pm

Criterion	Covered	Total	%
statement	33	35	94.2
branch	9	14	64.2
condition	10	15	66.6
subroutine	10	11	90.9
pod	4	4	100.0
total	66	79	83.5

use strict;
use warnings;
package MetaCPAN::Client::ResultSet;
# ABSTRACT: A Result Set
$MetaCPAN::Client::ResultSet::VERSION = '2.044000';
use Moo;
use Carp;

use MetaCPAN::Client::Types qw< ArrayRef >;

has index => (
    is       => 'ro',
    isa      => sub {
        croak 'Invalid index' unless
            grep { $_ eq $_[0] } qw
                                   file module permission release mirror package>;
    },
    lazy => 1,
);

# in case we're returning from a scrolled search
has scroller => (
    is        => 'ro',
    isa       => sub {
        use Safe::Isa;
        $_[0]->$_isa('MetaCPAN::Client::Scroll')
            or croak 'scroller must be an MetaCPAN::Client::Scroll object';
    },
    predicate => 'has_scroller',
);

# in case we're returning from a fetch
has items => (
    is      => 'ro',
    isa     => ArrayRef,
    lazy    => 1,
    default => sub {
        my $self = shift;
        return [] unless $self->has_scroller;

        my @items;
        while ( defined( my $result = $self->scroller->next ) ) {
            push @items, $result;
        }
        return \@items;
    },
);

has total => (
    is      => 'ro',
    default => sub {
        my $self = shift;

        return $self->has_scroller ? $self->scroller->total
                                   : scalar @{ $self->items };
    },
);

has 'class' => (
    is      => 'ro',
    lazy    => 1,
    builder => '_build_class',
);

sub BUILDARGS {
    my ( $class, %args ) = @_;

    exists $args{scroller} or exists $args{items}
        or croak 'ResultSet must get either scroller or items';

    exists $args{scroller} and exists $args{items}
        and croak 'ResultSet must get either scroller or items, not both';

    exists $args{index} or exists $args{class}
        or croak 'Must pass either index or target class to ResultSet';

    exists $args{index} and exists $args{class}
        and croak 'Must pass either index or target class to ResultSet, not both';

    return \%args;
}

sub BUILD {
    my ( $self ) = @_;
    $self->class; # vivify and validate
}

sub next {
    my $self   = shift;
    my $result = $self->has_scroller ? $self->scroller->next
                                     : shift @{ $self->items };

    defined $result or return;

    return $self->class->new_from_request( $result->{'_source'} || $result->{'fields'} || $result );
}

sub aggregations {
    my $self = shift;

    return $self->has_scroller ? $self->scroller->aggregations : {};
}

sub _build_class {
    my $self = shift;
    return 'MetaCPAN::Client::' . ucfirst $self->index;
}

1;

__END__