File Coverage

blib/lib/Markapl/FromHTML.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Markapl::FromHTML;

use warnings;
use strict;
use 5.008;
use Rubyish;
use HTML::PullParser;
# use Data::Dump qw(pp);

our $VERSION = '0.03';

my $indent_offset = 4;

def load($html) {
    $self->{html} = $html;
    $self;
}

def dump {
    return $_ if (defined($_ = $self->{markapl}));
    return $self->convert;
}

def convert {
    return "" unless $self->{html};

    my $p = HTML::PullParser->new(
        doc => $self->{html},
        start => '"S", tagname, @attr',
        text  => '"T", text',
        end   => '"E", tagname',
    );

    my $current_tag = "";
    my @stack = ();
    my $indent = 0;
    while(my $token = $p->get_token) {
        # warn $token->[0],"\n";;
        if ($token->[0] eq 'S') {
            push @stack, { tag => $token->[1], attr => [@$token[2..$#$token]]};
            $indent += 1;
        }
        elsif ($token->[0] eq 'T') {
            unless($token->[1] =~ /^\s*$/s ) {
                push @stack, { text => $token->[1] }
            }
        }
        elsif ($token->[0] eq 'E') {
            # pp $token;
            my @content;
            my $content = pop @stack;
            while (!$content->{tag} || $content->{tag} ne $token->[1]) {
                push @content, $content;
                $content = pop @stack;
            }

            my $start_tag = $content;

            my $indent_str = " " x ($indent * $indent_offset);
            my $indent_str2 = " " x ( ($indent + 1) * $indent_offset);

            my $attr = "";
            my @attr = @{$start_tag->{attr}};
            if (@attr) {
                while (my ($k, $v) = splice(@attr, 0, 2)) {
                    $attr .= qq{ $k => "$v"};
                }
                $attr = "($attr )";
            }

            if (@content == 1) {
                my $content_text = $content[0]->{code};
                if (!$content_text && $content[0]->{text}) {
                    $content_text = "\"$content[0]->{text}\""
                }
                $content_text ||= '';
                push @stack, {
                    code => "\n${indent_str}$start_tag->{tag}${attr} {\n${indent_str2}$content_text\n${indent_str}};\n"
                };
            }
            else {
                for (@content) {
                    if ($_->{text}) {
                        $_->{code} = "outs \"$_->{text}\";";
                        $_->{text} = undef;
                    }
                }
                my $content_code = join "\n", map { $_->{code}||"" } reverse @content;
                # pp $start_tag->{tag}, $start_tag->{indent};
                push @stack, {
                    code => "\n${indent_str}$start_tag->{tag}${attr} {\n${indent_str2}$content_code\n${indent_str}};\n"
                };
            }

            $indent -= 1;
        }
    }

    my $ret = join "\n", "sub {", (map { $_->{code} || $_->{text} } @stack), "\n}\n";

    # Squeeze empty lines.
    $ret =~ s/\n\s*\n/\n/g;
    $ret =~ s/\{\n\s+\}(;?)\n/{}$1\n/g;

    # Re-org all text only blocks to a single line.
    $ret =~ s/\{\n\s+(".+")\n\s+\}(;?)\n/{ $1 }$2\n/g;

    return $ret;
}

1;
__END__