File Coverage

blib/lib/Mail/SPF/Request.pm

Criterion	Covered	Total	%
statement	79	91	86.8
branch	35	44	79.5
condition	14	26	53.8
subroutine	14	16	87.5
pod	5	6	83.3
total	147	183	80.3

#
# Mail::SPF::Request
# SPF request class.
#
# (C) 2005-2012 Julian Mehnle
#     2005      Shevek
# $Id: Request.pm 57 2012-01-30 08:15:31Z julian $
#
##############################################################################

package Mail::SPF::Request;

=head1 NAME

Mail::SPF::Request - SPF request class

=head1 VERSION

version 3.20250505

=cut

use warnings;
use strict;

use base 'Mail::SPF::Base';

use NetAddr::IP;

use Mail::SPF::Util;

use constant TRUE   => (0 == 0);
use constant FALSE  => not TRUE;

use constant versions_for_scope => {
    helo    => [1   ],
    mfrom   => [1, 2],
    pra     => [   2]
};

use constant scopes_by_version => {
    1       => ['helo', 'mfrom'       ],
    2       => [        'mfrom', 'pra']
};

use constant default_localpart => 'postmaster';

# Interface:
##############################################################################

=head1 SYNOPSIS

    use Mail::SPF;

    my $request = Mail::SPF::Request->new(
        versions    => [1, 2],              # optional
        scope       => 'mfrom',             # or 'helo', 'pra'
        identity    => '[e-mail]',
        ip_address  => '192.168.0.1',
        helo_identity                       # optional,
                    => 'mta.example.com'    #   for %{h} macro expansion
    );

    my @versions    = $request->versions;
    my $scope       = $request->scope;
    my $authority_domain
                    = $request->authority_domain;
    my $identity    = $request->identity;   # 'localpart@domain' or 'domain'
    my $domain      = $request->domain;
    my $localpart   = $request->localpart;
    my $ip_address  = $request->ip_address;     # IPv4 or IPv6 address
    my $ip_address_v6                           # native IPv6 address or
                    = $request->ip_address_v6;  #   IPv4-mapped IPv6 address
    my $helo_identity                           # additional HELO identity
                    = $request->helo_identity;  #   for non-HELO scopes

    my $record      = $request->record;
        # the record selected during processing of the request, may be undef

    $request->state(field => 'value');
    my $value = $request->state('field');

=cut

# Implementation:
##############################################################################

=head1 DESCRIPTION

An object of class B represents an SPF request.

=head2 Constructors

The following constructors are provided:

=over

=item B: returns I

Creates a new SPF request object.  The request is considered the
I for any subsequent sub-requests (see the L
constructor).

%options is a list of key/value pairs representing any of the following
options:

=over

=item B

A reference to an I of Is listing the versions of SPF records
that may be used for the SPF check.  Only those record versions that cover the
desired scope will actually be used.  At least one applicable version must be
specified.  For a single record version, a simple scalar may be specified
instead of an array-ref.  Defaults to all versions that cover the desired scope
(see below); defaults to B<[1, 2]> for the default scope of B<'mfrom'>.

The following versions are supported:

=over

=item B<1>

Use C records.

=item B<2>

Use C records.

=back

I:  A value of B<1> (or B<[1]>) means that only C records
should be used for the SPF check.  If at the same time a scope of B<'pra'> is
specified, a I exception will be thrown as C
records do not cover the PRA scope.

=item B

A string denoting the authorization scope of the identity that should be
checked.  Defaults to B<'mfrom'>.  The following scope values are supported:

=over

=item B<'helo'>

The given identity is the C parameter of an SMTP transaction (RFC 2821)
and should be checked against SPF records that cover the C scope
(C).  See the SPFv1 specification (RFC 4408) for the formal definition
of the C scope.

=item B<'mfrom'>

The given identity is the C parameter of an SMTP transaction (RFC
2821), and should be checked against SPF records that cover the C scope
(C and C).  See the SPFv1 specification (RFC 4408) for
the formal definition of the C scope.

I:  In the case of an empty C SMTP transaction parameter (C<<
MAIL FROM:<> >>), the identity checked will be postmaster@helo name as specified
in RFC 7208.

=item B<'pra'>

The given identity is the "Purported Responsible Address" of an internet
message (RFC 2822) and should be checked against SPF records that cover the
C scope (C).  See the PRA specification (RFC 4407) for the
formal definition of the PRA scope.

=back

=item B

A string denoting the domain name that should be queried for sender policy
records.  Defaults to the domain of the C option.  There is usually
no need to specify the C option.

=item B

I.  A string denoting the sender identity whose authorization should
be checked.  This is a domain name for the C scope, and an e-mail address
for the C and C scopes.

I:  An empty identity should not be passed, in the case of an empty
C SMTP transaction parameter (C< >>),
the identity checked will be postmaster@helo name as specified
in RFC 7208.

=item B

I for checks with the C, C, and C scopes.  Either a
string or a I object denoting the IP address of the host claiming
the identity that is being checked.  Can be either an IPv4 or an IPv6 address.
An IPv4-mapped IPv6 address (e.g. '::ffff:192.168.0.1') is treated as an IPv4
address.

=item B

A string denoting the C SMTP transaction parameter in the case that the
main identity is of a scope other than C.  This identity is then used
merely for the expansion of C<%{h}> macros during the policy evaluation of the
main identity.  Defaults to B, which will be expanded to B<'unknown'>.
If the main identity is of the C scope, this option is unused.

=back

=cut

sub new {
    my ($self, %options) = @_;

    # Create new object:
    $self = $self->SUPER::new(%options);
    # If the request object already has a state hash, clone its contents:
    $self->{state} = { %{$self->{state}} }
        if ref($self->{state}) eq 'HASH';

    # Scope:
    $self->{scope} ||= 'mfrom';
    my $versions_for_scope = $self->versions_for_scope->{$self->{scope}}
        or throw Mail::SPF::EInvalidScope("Invalid scope '$self->{scope}'");

    # Versions:
    if (not defined($self->{versions})) {
        # No versions specified, use all versions relevant to scope:
        $self->{versions} = $versions_for_scope;
    }
    else {
        if (not ref($self->{versions})) {
            # Single version specified as scalar:
            $self->{versions} = [$self->{versions}];
        }
        elsif (ref($self->{versions}) ne 'ARRAY') {
            # Something other than scalar or array-ref specified:
            throw Mail::SPF::EInvalidOptionValue(
                "'versions' option must be string or array-ref");
        }

        # All requested record versions must be supported:
        my @unsupported_versions = grep(
            (not defined($self->scopes_by_version->{$_})),
            @{$self->{versions}}
        );
        not @unsupported_versions
            or throw Mail::SPF::EInvalidOptionValue(
                'Unsupported record version(s) ' .
                join(', ', map("'$_'", @unsupported_versions)));

        # Use only those record versions that are relevant to the requested scope:
        my %versions_for_scope;
           @versions_for_scope{@$versions_for_scope} = ();
        my @versions = grep(exists($versions_for_scope{$_}), @{$self->{versions}});

        # Require at least one relevant record version that covers the scope:
        @versions
            or throw Mail::SPF::EInvalidScope(
                "Invalid scope '$self->{scope}' for record version(s) " .
                join(', ', @{$self->{versions}}));

        $self->{versions} = \@versions;
    }

    # Identity:
    defined($self->{identity})
        or throw Mail::SPF::EOptionRequired("Missing required 'identity' option");
    if(not length($self->{identity}) and (defined $self->{helo_identity})) {
      # if identity is <>, try with postmaster@helo as specified in RFC 7208 section 2.4
      $self->{identity} = 'postmaster@' . $self->{helo_identity};
    } elsif(not length($self->{identity})) {
      throw Mail::SPF::EInvalidOptionValue("'identity' option must not be empty without specifying HELO");
    }

    # Extract domain and localpart from identity:
    if (
        ($self->{scope} eq 'mfrom' or $self->{scope} eq 'pra') and
        $self->{identity} =~ /^(.*)@(.*?)$/
    ) {
        $self->{domain}    = $2;
        $self->{localpart} = $1;
    }
    else {
        $self->{domain}    = $self->{identity};
    }
    $self->{domain} =~ s/^(.*?)\.?$/\L$1/;
        # Lower-case domain and remove eventual trailing dot.
    $self->{localpart} = $self->default_localpart
        if not defined($self->{localpart}) or not length($self->{localpart});

    # HELO identity:
    if ($self->{scope} eq 'helo') {
        $self->{helo_identity} ||= $self->{identity};
    }

    # IP address:
    throw Mail::SPF::EOptionRequired("Missing required 'ip_address' option")
        if  grep($self->{scope} eq $_, qw(helo mfrom pra))
        and not defined($self->{ip_address});

    # Ensure ip_address is a NetAddr::IP object:
    if (not UNIVERSAL::isa($self->{ip_address}, 'NetAddr::IP')) {
        my $ip_address = NetAddr::IP->new($self->{ip_address})
            or throw Mail::SPF::EInvalidOptionValue("Invalid IP address '$self->{ip_address}'");
        $self->{ip_address} = $ip_address;
    }

    # Convert IPv4 address to IPv4-mapped IPv6 address:
    if (Mail::SPF::Util->ipv6_address_is_ipv4_mapped($self->{ip_address})) {
        $self->{ip_address_v6} = $self->{ip_address};  # Accept as IPv6 address as-is.
        $self->{ip_address} = Mail::SPF::Util->ipv6_address_to_ipv4($self->{ip_address});
    }
    elsif ($self->{ip_address}->version == 4) {
        $self->{ip_address_v6} = Mail::SPF::Util->ipv4_address_to_ipv6($self->{ip_address});
    }
    elsif ($self->{ip_address}->version == 6) {
        $self->{ip_address_v6} = $self->{ip_address};
    }
    else {
        throw Mail::SPF::EInvalidOptionValue(
            "Unexpected IP address version '" . $self->{ip_address}->version . "'");
    }

    return $self;
}

=item B: returns I

Must be invoked on an existing request object.  Creates a new sub-request
object by cloning the invoked request, which is then considered the new
request's I.  Any specified options (see the L
constructor) override the parameters of the super-request.  There is usually no
need to specify any options I the C option.

=cut

sub new_sub_request {
    my ($super_request, %options) = @_;
    UNIVERSAL::isa($super_request, __PACKAGE__)
        or throw Mail::SPF::EInstanceMethod;
    my $self = $super_request->new(%options);
    $self->{super_request} = $super_request;
    $self->{root_request}  = $super_request->root_request;
    return $self;
}

=back

=head2 Instance methods

The following instance methods are provided:

=over

=item B: returns I

Returns the root of the request's chain of super-requests.  Specifically,
returns the request itself if it has no super-requests.

=cut

sub root_request {
    my ($self) = @_;
    # Read-only!
    return $self->{root_request} || $self;
}

=item B: returns I

Returns the super-request of the request, or B if there is none.

=cut

# Make read-only accessor:
__PACKAGE__->make_accessor('super_request', TRUE);

=item B: returns I of I

Returns a list of the SPF record versions that are used for request.  See the
description of the L constructor's C option.

=cut

sub versions {
    my ($self) = @_;
    # Read-only!
    return @{$self->{versions}};
}

=item B: returns I

Returns the scope of the request.  See the description of the L
constructor's C option.

=item B: returns I

Returns the authority domain of the request.  See the description of the
L constructor's C option.

=cut

sub authority_domain {
    my ($self) = @_;
    return $self->{authority_domain} || $self->{domain};
}

=item B: returns I

Returns the identity of the request.  See the description of the L
constructor's C option.

=item B: returns I

Returns the identity domain of the request.  See the description of the
L constructor's C option.

=item B: returns I

Returns the identity localpart of the request.  See the description of the
L constructor's C option.

=item B: returns I

Returns the IP address of the request as a I object.  See the
description of the L constructor's C option.

=item B: returns I

Like the C method, however, an IPv4 address is returned as an
IPv4-mapped IPv6 address (e.g. '::ffff:192.168.0.1') to facilitate uniform
processing.

=item B: returns I

Returns the C SMTP transaction parameter of the request.  See the
description of the L constructor's C option.

=cut

# Make read-only accessors:
__PACKAGE__->make_accessor($_, TRUE)
    foreach qw(
        scope identity domain localpart
        ip_address ip_address_v6 helo_identity
    );

=item B: returns I

Returns the SPF record selected during the processing of the request, or
B if there is none.

=cut

# Make read/write accessor:
__PACKAGE__->make_accessor('record', FALSE);

=item B: returns anything

=item B: returns anything

Provides an interface for storing temporary state information with the request
object.  This is primarily meant to be used internally by I
and other Mail::SPF classes.

If C<$value> is specified, stores it in a state field named C<$field>.  Returns
the current (new) value of the state field named C<$field>.  This method may be
used as an lvalue.

=cut

sub state :lvalue {
    my ($self, $field, @value) = @_;
    defined($field)
        or throw Mail::SPF::EOptionRequired('Field name required');
    $self->{state}->{$field} = $value[0]
        if @value;
    $self->{state}->{$field};
}

=back

=head1 SEE ALSO

L, L

L

For availability, support, and license information, see the README file
included with Mail::SPF.

=head1 AUTHORS

Julian Mehnle , Shevek

=cut

TRUE;