File Coverage

blib/lib/MCP/Run/Bash.pm

Criterion	Covered	Total	%
statement	63	66	95.4
branch	11	12	91.6
condition	3	6	50.0
subroutine	7	7	100.0
pod	1	1	100.0
total	85	92	92.3

package MCP::Run::Bash;
our $VERSION = '0.004';
use Mojo::Base 'MCP::Run', -signatures;

# ABSTRACT: MCP server that executes commands via bash


use IPC::Open3;
use IO::Select;
use Symbol 'gensym';
use POSIX   ':sys_wait_h';

sub execute ($self, $command, $working_directory, $timeout) {
  my $full_command = $command;
  if (defined $working_directory && length $working_directory) {
    my $escaped = $working_directory;
    $escaped =~ s/'/'\\''/g;
    $full_command = "cd '$escaped' && $command";
  }

  my ($stdout, $stderr) = ('', '');
  my ($exit_code, $error);

  eval {
    my $err = gensym;
    my $pid = open3(my $in, my $out, $err, 'bash', '-c', $full_command);
    close $in;

    my $select = IO::Select->new($out, $err);
    my $timed_out = 0;

    local $SIG{ALRM} = sub { $timed_out = 1; die "alarm\n" };
    alarm($timeout);

    eval {
      while (my @ready = $select->can_read) {
        for my $fh (@ready) {
          my $buf;
          my $bytes = sysread($fh, $buf, 4096);
          if (!$bytes) {
            $select->remove($fh);
            next;
          }
          if ($fh == $out) { $stdout .= $buf }
          else             { $stderr .= $buf }
        }
      }
    };

    alarm(0);

    if ($timed_out) {
      kill 'TERM', $pid;
      waitpid($pid, 0);
      $exit_code = 124;
      $error     = "Command timed out after ${timeout}s";
    }
    else {
      waitpid($pid, 0);
      $exit_code = $? >> 8;
    }

    close $out;
    close $err;
  };

  if ($@ && !defined $exit_code) {
    $exit_code = 1;
    $error     = "$@";
    chomp $error;
  }

  chomp $stdout;
  chomp $stderr;

  return { exit_code => $exit_code, stdout => $stdout, stderr => $stderr, (defined $error ? (error => $error) : ()) };
}



1;

__END__