File Coverage

blib/lib/MARC/Field008/Print.pm

Criterion	Covered	Total	%
statement	45	152	29.6
branch	5	44	11.3
condition	0	3	0.0
subroutine	10	14	71.4
pod	2	2	100.0
total	62	215	28.8

package MARC::Field008::Print;

use strict;
use warnings;

use Check::Term::Color qw(check_term_color);
use Class::Utils qw(set_params);
use English;
use Error::Pure qw(err);
use MARC::Field008::L10N 0;
use Mo::utils 0.06 qw(check_bool);
use Mo::utils::Language 0.05 qw(check_language_639_1);

our $VERSION = 0.01;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Language.
	$self->{'lang'} = undef;

	# Use with ANSI sequences.
	$self->{'mode_ansi'} = undef;

	# Use description.
	$self->{'mode_desc'} = 1;

	# Output separator.
	$self->{'output_separator'} = "\n";

	# Process parameters.
	set_params($self, @params);

	# Check 'lang'.
	check_language_639_1($self, 'lang');

	# Check 'mode_ansi'.
	check_bool($self, 'mode_ansi');

	# Check 'mode_desc'.
	check_bool($self, 'mode_desc');

	# Set 'mode_ansi' from env variables.
	if (! defined $self->{'mode_ansi'}) {
		$self->{'mode_ansi'} = check_term_color();
	}

	# Check routine for ANSI colors output.
	if ($self->{'mode_ansi'}) {
		eval {
			require Term::ANSIColor;
		};
		if ($EVAL_ERROR) {
			err "Cannot load 'Term::ANSIColor' module.";
		}
	}

	$self->{'_l'} = MARC::Field008::L10N->get_handle(defined $self->{'lang'} ? $self->{'lang'} : ());

	return $self;
}

sub print {
	my ($self, $field008_obj) = @_;

	my @ret;
	# TODO Print some nice date.
	push @ret, $self->_key('Date entered on file').$field008_obj->date_entered_on_file;
	push @ret, $self->_key('Type of date/Publication status').
		$self->_print($field008_obj, 'type_of_date');
	push @ret, $self->_key('Date 1').$field008_obj->date1;
	push @ret, $self->_key('Date 2').$field008_obj->date2;
	# TODO Translate?
	push @ret, $self->_key('Place of publication, production, or execution').
		$field008_obj->place_of_publication;
	# TODO Translate?
	push @ret, $self->_key('Material').$field008_obj->material_type;
	my $material = $field008_obj->material;
	if ($field008_obj->material_type eq 'book') {
		push @ret, $self->_key('Illustrations').
			$self->_print_multi($material, 'illustrations', 'book');
		push @ret, $self->_key('Target audience').
			$self->_print($material, 'target_audience');
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item');
		push @ret, $self->_key('Nature of contents').
			$self->_print_multi($material, 'nature_of_content');
		push @ret, $self->_key('Government publication').
			$self->_print($material, 'government_publication');
		push @ret, $self->_key('Conference publication').
			$self->_print($material, 'conference_publication');
		push @ret, $self->_key('Festschrift').
			$self->_print($material, 'festschrift', 'book');
		push @ret, $self->_key('Index').
			$self->_print($material, 'index');
		push @ret, $self->_key('Literary form').
			$self->_print($material, 'literary_form', 'book');
		push @ret, $self->_key('Biography').
			$self->_print($material, 'biography', 'book');
	} elsif ($field008_obj->material_type eq 'computer_file') {
		push @ret, $self->_key('Target audience').
			$self->_print($material, 'target_audience');
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item', 'computer_file');
		push @ret, $self->_key('Type of computer file').
			$self->_print($material, 'type_of_computer_file', 'computer_file');
		push @ret, $self->_key('Government publication').
			$self->_print($material, 'government_publication');
	} elsif ($field008_obj->material_type eq 'continuing_resource') {
		push @ret, $self->_key('Frequency').
			$self->_print($material, 'frequency', 'continuing_resource');
		push @ret, $self->_key('Regularity').
			$self->_print($material, 'regularity', 'continuing_resource');
		push @ret, $self->_key('Type of continuing resource').
			$self->_print($material, 'type_of_continuing_resource',
			'continuing_resource');
		push @ret, $self->_key('Form of original item').
			$self->_print($material, 'form_of_original_item',
			'continuing_resource');
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item');
		push @ret, $self->_key('Nature of entire work').
			$self->_print($material, 'nature_of_entire_work',
			'continuing_resource');
		push @ret, $self->_key('Nature of contents').
			$self->_print_multi($material, 'nature_of_content');
		push @ret, $self->_key('Government publication').
			$self->_print($material, 'government_publication');
		push @ret, $self->_key('Conference publication').
			$self->_print($material, 'conference_publication');
		push @ret, $self->_key('Original alphabet or script of title').
			$self->_print($material, 'original_alphabet_or_script_of_title',
			'continuing_resource');
		push @ret, $self->_key('Entry convention').
			$self->_print($material, 'entry_convention',
			'continuing_resource');
	} elsif ($field008_obj->material_type eq 'map') {
		push @ret, $self->_key('Relief').
			$self->_print_multi($material, 'relief', 'map');
		push @ret, $self->_key('Projection').
			$self->_print($material, 'projection', 'map');
		push @ret, $self->_key('Type of cartographic material').
			$self->_print($material, 'type_of_cartographic_material', 'map');
		push @ret, $self->_key('Government publication').
			$self->_print($material, 'government_publication');
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item');
		push @ret, $self->_key('Index').
			$self->_print($material, 'index');
		push @ret, $self->_key('Special format characteristics').
			$self->_print_multi($material, 'special_format_characteristics', 'map');
	} elsif ($field008_obj->material_type eq 'mixed_material') {
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item');
	} elsif ($field008_obj->material_type eq 'music') {
		push @ret, $self->_key('Form of composition').
			$self->_print($material, 'form_of_composition', 'music');
		push @ret, $self->_key('Format of music').
			$self->_print($material, 'format_of_music', 'music');
		push @ret, $self->_key('Music parts').
			$self->_print($material, 'music_parts', 'music');
		push @ret, $self->_key('Target audience').
			$self->_print($material, 'target_audience');
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item');
		push @ret, $self->_key('Accompanying matter').
			$self->_print_multi($material, 'accompanying_matter', 'music');
		push @ret, $self->_key('Literary text for sound recordings').
			$self->_print_multi($material, 'literary_text_for_sound_recordings',
			'music');
		push @ret, $self->_key('Transposition and arrangement').
			$self->_print($material, 'transposition_and_arrangement',
			'music');

	# visual_material
	} else {
		# XXX For time from 001 to 999 is language key 001.
		my $lang_key;
		if ($material->running_time_for_motion_pictures_and_videorecordings ne '000'
			&& $material->running_time_for_motion_pictures_and_videorecordings =~ m/^\d+$/ms) {

			$lang_key = '001';
		}
		# TODO Value.
		push @ret, $self->_key('Running time for motion pictures and videorecordings').
			$self->_print($material, 'running_time_for_motion_pictures_and_videorecordings',
			'visual_material', $lang_key);
		push @ret, $self->_key('Target audience').
			$self->_print($material, 'target_audience');
		push @ret, $self->_key('Government publication').
			$self->_print($material, 'government_publication');
		push @ret, $self->_key('Form of item').
			$self->_print($material, 'form_of_item');
		push @ret, $self->_key('Type of visual material').
			$self->_print($material, 'type_of_visual_material', 'visual_material');
		push @ret, $self->_key('Technique').
			$self->_print($material, 'technique', 'visual_material');
	}
	# TODO Translate?
	push @ret, $self->_key('Language').$field008_obj->language;
	push @ret, $self->_key('Modified record').
		$self->_print($field008_obj, 'modified_record');
	push @ret, $self->_key('Cataloging source').
		$self->_print($field008_obj, 'cataloging_source');

	return wantarray ? @ret : (join $self->{'output_separator'}, @ret);
}

sub _key {
	my ($self, $key) = @_;

	my $ret;
	my $value = $self->{'_l'}->maketext($key);
	if ($self->{'mode_ansi'}) {
		$ret = Term::ANSIColor::color('cyan').$value.Term::ANSIColor::color('reset');
	} else {
		$ret = $value;
	}
	$ret .= ': ';

	return $ret;
}

sub _print {
	my ($self, $obj, $method_name, $prefix, $lang_key) = @_;

	my $ret_value = $obj->$method_name;
	my $ret;
	if ($self->{'mode_desc'}) {
		if (! defined $lang_key) {
			my $ret_value_fixed = $ret_value;
			$ret_value_fixed =~ s/\ /_/msg;
			$lang_key = $method_name.'.'.$ret_value_fixed;
			if (defined $prefix) {
				$lang_key = $prefix.'.'.$lang_key;
			}
		}
		$ret = $self->{'_l'}->maketext($lang_key);
	} else {
		$ret = $ret_value;
	}

	return $ret;
}

sub _print_multi {
	my ($self, $obj, $method_name, $prefix) = @_;

	my $ret_value = $obj->$method_name;
	my @ret_values = split m//ms, $ret_value;
	my @ret;
	my $not_coded = 0;
	foreach my $process_ret_value (@ret_values) {
		if ($process_ret_value eq ' ') {
			next;
		}
		if ($process_ret_value eq '|') {
			if (! $not_coded) {
				$not_coded = 1;
			} else {
				next;
			}
		}
		if ($self->{'mode_desc'}) {
			my $ret_value_fixed = $process_ret_value;
			$ret_value_fixed =~ s/\ /_/msg;
			my $lang_key = $method_name.'.'.$ret_value_fixed;
			if (defined $prefix) {
				$lang_key = $prefix.'.'.$lang_key;
			}
			push @ret, $self->{'_l'}->maketext($lang_key);
		} else {
			push @ret, $process_ret_value;
		}
	}

	return wantarray ? @ret : (join ', ', @ret);
}

1;

__END__