File Coverage

blib/lib/Log/ger/Format/Block.pm

Criterion	Covered	Total	%
statement	32	32	100.0
branch	5	6	83.3
condition	1	3	33.3
subroutine	8	8	100.0
pod	0	2	0.0
total	46	51	90.2

package Log::ger::Format::Block;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-03-11'; # DATE
our $DIST = 'Log-ger-Format-Block'; # DIST
our $VERSION = '0.008'; # VERSION

use strict;
use warnings;

use Sub::Metadata qw(mutate_sub_prototype);

sub meta { +{
    v => 2,
} }

sub get_hooks {
    my %plugin_conf = @_;

    return {
        create_formatter => [
            __PACKAGE__, # key
            50,          # priority
            sub {        # hook
                my %hook_args = @_; # see Log::ger::Manual::Internals/"Arguments passed to hook"

                my $formatter = sub { my $code = shift; $code->(@_) };
                [$formatter];
            }],

        before_install_routines => [
            __PACKAGE__, # key
            50,          # priority
            sub {        # hook
                no strict 'refs';

                my %hook_args = @_; # see Log::ger::Manual::Internals/"Arguments passed to hook"

                for my $r (@{ $hook_args{routines} }) {
                    my ($coderef, $name, $lnum, $type) = @$r;
                    next unless $type =~ /\Alog(ger)?_/;
                    # avoid prototype mismatch warning when redefining
                    if ($hook_args{target_type} eq 'package' ||
                            $hook_args{target_type} eq 'object') {
                        if (defined ${"$hook_args{target_name}\::"}{$name}) {
                            delete ${"$hook_args{target_name}\::"}{$name};
                        }
                    }
                    mutate_sub_prototype($coderef, '&');
                }
                [1];
            }],
    };
}

1;
# ABSTRACT: Use formatting using block instead of sprintf-style

__END__