File Coverage

blib/lib/Log/Dispatch/TextTable.pm

Criterion	Covered	Total	%
statement	45	46	97.8
branch	7	8	87.5
condition	1	2	50.0
subroutine	13	14	92.8
pod	7	7	100.0
total	73	77	94.8

use strict;
use warnings;
package Log::Dispatch::TextTable;
{
  $Log::Dispatch::TextTable::VERSION = '0.032';
}
use parent qw(Log::Dispatch::Output);
# ABSTRACT: log events to a textual table

use Log::Dispatch 2.0 ();
use Text::Table;


sub new {
  my ($class, %arg) = @_;

  # when done, by default, print out the passed-in table
  $arg{send_to} ||= sub { print $_[0] };

  # construct the column list, using the default if no columns were given
  my @columns = $arg{columns} ? @{ $arg{columns} } : qw(time level message);
  my @header  = map { $_, \q{ | } } @columns;
  $#header--; # drop the final |-divider

  my $table = Text::Table->new(@header);

  my $self = {
    columns  => \@columns,
    table    => $table,
    send_to  => $arg{send_to},
    flush_if => $arg{flush_if},
  };

  bless $self => $class;

  # this is our duty as a well-behaved Log::Dispatch plugin
  $self->_basic_init(%arg);

  return $self;
}


sub log_message {
  my ($self, %p) = @_;
  $p{time} = localtime unless exists $p{time};

  $self->table->add(
    @p{ @{ $self->{columns} } }
  );

  $self->flush(\%p) if $self->should_flush;
}


sub table { return $_[0]->{table} }


sub entry_count {
  my ($self) = @_;
  $self->table->body_height;
}


sub flush {
  my ($self) = @_;
  $self->transmit;
  $self->table->clear;
}


sub should_flush {
  my ($self, $p) = @_;

  return unless (ref $self->{flush_if} eq 'CODE');

  return $self->{flush_if}->($self, $p);
}


sub transmit {
  my ($self) = @_;
  $self->{send_to}->($self->table);
}

sub DESTROY {
  my ($self) = @_;
  $self->transmit;
}


1;

__END__