File Coverage

blib/lib/Locale/TextDomain/OO/Lexicon/Hash.pm

Criterion	Covered	Total	%
statement	49	49	100.0
branch	10	16	62.5
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	70	76	92.1

package Locale::TextDomain::OO::Lexicon::Hash; ## no critic (TidyCode)

use strict;
use warnings;
use Carp qw(confess);
use Locale::TextDomain::OO::Singleton::Lexicon;
use Locale::TextDomain::OO::Util::ExtractHeader;
use Locale::TextDomain::OO::Util::JoinSplitLexiconKeys;
use Moo;
use MooX::StrictConstructor;
use namespace::autoclean;

our $VERSION = '1.031';

with qw(
    Locale::TextDomain::OO::Role::Logger
);

sub lexicon_ref {
    my ($self, $hash_lexicon) = @_;

    ref $hash_lexicon eq 'HASH'
        or confess 'The given lexicon should be a hash reference';
    my $instance = Locale::TextDomain::OO::Singleton::Lexicon->instance;
    $self->logger and $instance->logger( $self->logger );
    my $lexicon = $instance->data;
    my $key_util = Locale::TextDomain::OO::Util::JoinSplitLexiconKeys->instance;
    while ( my ($lexicon_key, $lexicon_value) = each %{$hash_lexicon} ) {
        my $header = $lexicon_value->[0];
        my $header_msgstr = $header->{msgstr}
            or confess 'msgstr of header not found';
        $lexicon_value->[0] = Locale::TextDomain::OO::Util::ExtractHeader
            ->instance
            ->extract_header_msgstr($header_msgstr);
        my $nplurals = $lexicon_value->[0]->{nplurals};
        VALUE:
        for my $value ( @{$lexicon_value} ) {
            # move to lexicon
            my $msg_key = $key_util->join_message_key({
                msgctxt      => delete $value->{msgctxt},
                msgid        => my $msgid        = delete $value->{msgid},
                msgid_plural => my $msgid_plural = delete $value->{msgid_plural},
            });
            $lexicon->{$lexicon_key}->{$msg_key} = $value;
            # structure faults
            exists $value->{msgstr_plural}
                or next VALUE;
            my $plural_count = @{ $value->{msgstr_plural} };
            $plural_count <= $nplurals or confess sprintf
                'Count of msgstr_plural=%s but nplurals=%s for msgid="%s" msgid_plural="%s"',
                $plural_count,
                $nplurals,
                ( defined $msgid        ? $msgid        : q{} ),
                ( defined $msgid_plural ? $msgid_plural : q{} );
        }
        $self->logger
            and $self->logger->(
                qq{Lexicon "$lexicon_key" loaded from hash.},
                {
                    object => $self,
                    type   => 'debug',
                    event  => 'lexicon,load',
                },
            );
    }

    return $self;
}

1;

__END__