File Coverage

blib/lib/Linux/Inotify.pm

Criterion	Covered	Total	%
statement	98	113	86.7
branch	3	22	13.6
condition			n/a
subroutine	31	33	93.9
pod	0	5	0.0
total	132	173	76.3

package Linux::Inotify;

use strict;
use warnings;
use Carp;
use POSIX;
use Config;

# ABSTRACT: Classes for supporting inotify in Linux Kernel >= 2.6.13
our $VERSION = '0.06'; # VERSION


use constant ACCESS        => 0x00000001;
use constant MODIFY        => 0x00000002;
use constant ATTRIB        => 0x00000004;
use constant CLOSE_WRITE   => 0x00000008;
use constant CLOSE_NOWRITE => 0x00000010;
use constant OPEN          => 0x00000020;
use constant MOVED_FROM    => 0x00000040;
use constant MOVED_TO      => 0x00000080;
use constant CREATE        => 0x00000100;
use constant DELETE        => 0x00000200;
use constant DELETE_SELF   => 0x00000400;
use constant UNMOUNT       => 0x00002000;
use constant Q_OVERFLOW    => 0x00004000;
use constant IGNORED       => 0x00008000;
use constant ISDIR         => 0x40000000;
use constant ONESHOT       => 0x80000000;
use constant CLOSE         => 0x00000018;
use constant MOVE          => 0x000000c0;
use constant ALL_EVENTS    => 0x00000fff;

sub _arch_config {
   my ($arch) = ($Config{archname} =~ m{([^-]+)-});
   return (253,254,255)      if $arch eq 'x86_64';
   return (26, 27, 28, 0)    if $arch eq 'aarch64';
   return (151, 152, 156)    if $arch =~ /^sparc(_64|)\z/;
   return (444, 445, 446)    if $arch eq 'alpha';
   return (291, 292, 293)    if $arch =~ /^i[3456]86\z/;
   return (1277, 1278, 1279) if $arch eq 'ia64';
   return (275, 276, 277)    if $arch =~ /^powerpc(|64)\z/;
   return (284, 285, 296)    if $arch eq 's390';
   die "do not know syscalls for inotify on $arch";
}

sub syscall_init;
sub syscall_add_watch;
sub syscall_rm_watch;

if(my($init, $add, $remove, @init_args) = _arch_config()) {
   if(@init_args) {
       *syscall_init = sub { syscall $init, 0 };
   } else {
       *syscall_init = sub { syscall $init };
   }
   *syscall_add_watch = sub { syscall $add,    @_ };
   *syscall_rm_watch  = sub { syscall $remove, @_ };
}

sub new {
   my $class = shift;
   my $fd = syscall_init();
   croak "Linux::Inotify::init() failed: $!" if $fd == -1;
   return bless { fd => $fd }, $class;
}

sub add_watch {
   my $self = shift;
   require Linux::Inotify::Watch;
   my $watch = Linux::Inotify::Watch->new($self, @_);
   $self->{wd}->{$watch->{wd}} = $watch;
   return $watch;
}

sub find {
   my $self = shift;
   my $wd = shift;
   return $self->{wd}->{$wd};
}

sub close {
   my $self = shift;
   for my $watch (values %{$self->{wd}}) {
      $watch->remove;
   }
   my $ret = POSIX::close($self->{fd});
   croak "Linux::Inotify::close() failed: $!" unless defined $ret;
}

sub read {
   my $self = shift;
   my $bytes = POSIX::read($self->{fd}, my $raw_events, 65536);
   croak "Linux::Inotify::read: read only $bytes bytes: $!" if $bytes < 16;
   my @all_events;
   do {
      require Linux::Inotify::Event;
      my $event = Linux::Inotify::Event->new($self, $raw_events);
      push @all_events, $event;
      $raw_events = substr($raw_events, 16 + $event->{len});
   } while(length $raw_events >= 16);
   return @all_events;
}

1;

__END__