File Coverage

blib/lib/Linux/Event/Scheduler.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch	10	16	62.5
condition			n/a
subroutine	11	11	100.0
pod	6	6	100.0
total	84	90	93.3

package Linux::Event::Scheduler;
use v5.36;
use strict;
use warnings;

our $VERSION = '0.012';

use Carp qw(croak);
use Linux::Event::XS ();

sub new ($class, %args) {
  my $clock = delete $args{clock};
  croak "clock is required" if !$clock;
  croak "unknown args: " . join(", ", sort keys %args) if %args;

  for my $m (qw(now_ns deadline_in_ns)) {
    croak "clock missing method '$m'" if !$clock->can($m);
  }

  return bless {
    clock => $clock,
    heap  => Linux::Event::XS::timer_heap_new(),
  }, $class;
}

sub at_ns ($self, $deadline_ns, $cb) {
  croak "deadline_ns is required" if !defined $deadline_ns;
  croak "callback is required"    if !defined $cb;
  croak "callback must be a coderef" if ref($cb) ne 'CODE';

  return Linux::Event::XS::timer_heap_at_ns(
    $self->{heap},
    int($deadline_ns),
    $cb,
  );
}

sub after_ns ($self, $delta_ns, $cb) {
  croak "delta_ns is required" if !defined $delta_ns;
  $delta_ns = int($delta_ns);
  my $deadline = $self->{clock}->deadline_in_ns($delta_ns);
  return $self->at_ns($deadline, $cb);
}

sub cancel ($self, $id) {
  return 0 if !defined $id;
  return Linux::Event::XS::timer_heap_cancel($self->{heap}, int($id));
}

sub next_deadline_ns ($self) {
  return Linux::Event::XS::timer_heap_next_deadline_ns($self->{heap});
}

sub pop_expired ($self) {
  my $now = $self->{clock}->now_ns;
  return Linux::Event::XS::timer_heap_pop_expired($self->{heap}, int($now));
}

1;

__END__