File Coverage

blib/lib/Lingua/YID/Num2Word.pm

Criterion	Covered	Total	%
statement	51	66	77.2
branch	21	48	43.7
condition	14	33	42.4
subroutine	9	11	81.8
pod	3	3	100.0
total	98	161	60.8

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-

package Lingua::YID::Num2Word;
# ABSTRACT: Number to word conversion in Yiddish

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Carp;
use Export::Attrs;
use Readonly;

# }}}
# {{{ variable declarations

my Readonly::Scalar $COPY = 'Copyright (c) PetaMem, s.r.o. 2002-present';
our $VERSION = '0.2603300';

# }}}

# {{{ num2yid_cardinal                 convert number to text

sub num2yid_cardinal :Export {
    my $positive = shift;

    croak 'You should specify a number from interval [0, 999_999_999]'
        if    !defined $positive
           || $positive !~ m{\A\d+\z}xms
           || $positive < 0
           || $positive > 999_999_999;

    my @tokens1 = qw(נול אײנס צװײ דרײַ פֿיר פֿינף זעקס זיבן אכט נײַן צען עלף צוועלף);
    my @tokens2 = qw(צוואַנציק דרײַסיק פערציק פופציק זעכציק זיבעציק אַכציק נײַנציק הונדערט);

    return $tokens1[$positive]               if ($positive >= 0 && $positive < 13); # 0 .. 12
    return 'פערצן'                            if ($positive == 14);                  # YIVO: fertsn
    return 'פופצן'                            if ($positive == 15);                  # YIVO: fuftsn
    return 'זעכצן'                            if ($positive == 16);                  # YIVO: zekhtsn
    return 'זיבעצן'                           if ($positive == 17);                  # YIVO: zibetsn
    return 'אַכצן'                            if ($positive == 18);                  # YIVO: akhtsn
    return 'נײַנצן'                           if ($positive == 19);                  # YIVO: nayntsn
    return $tokens1[$positive-10] . 'צן'      if ($positive == 13);                  # draytsn

    my $out;          # string for return value construction
    my $one_idx;      # index for tokens1 array
    my $remain;       # remainder

    if ($positive > 19 && $positive < 101) {              # 20 .. 100
        $one_idx = int ($positive / 10);
        $remain  = $positive % 10;

        $out  = "$tokens1[$remain] און " if ($remain);
        $out .= $tokens2[$one_idx - 2];
    }
    elsif ($positive > 100 && $positive < 1000) {       # 101 .. 999
        $one_idx = int ($positive / 100);
        $remain  = $positive % 100;

        $out  = "$tokens1[$one_idx] הונדערט";
        $out .= $remain ? ' ' . num2yid_cardinal($remain) : '';
    }
    elsif ($positive > 999 && $positive < 1_000_000) {  # 1000 .. 999_999
        $one_idx = int ($positive / 1000);
        $remain  = $positive % 1000;

        $out  = num2yid_cardinal($one_idx) . ' טויזנט';
        $out .= $remain ? ' ' . num2yid_cardinal($remain) : '';
    }
    elsif (   $positive > 999_999
           && $positive < 1_000_000_000) {                 # 1_000_000 .. 999_999_999
        $one_idx = int ($positive / 1000000);
        $remain  = $positive % 1000000;

        $out  = num2yid_cardinal($one_idx) . ' מיליאָן';
        $out .= $remain ? ' ' . num2yid_cardinal($remain) : '';
    }

    return $out;
}

# }}}

# {{{ num2yid_ordinal                  convert number to ordinal text

sub num2yid_ordinal :Export {
    my $number = shift;

    croak 'You should specify a number from interval [1, 999_999_999]'
        if    !defined $number
           || $number !~ m{\A\d+\z}xms
           || $number < 1
           || $number > 999_999_999;

    # Fully irregular forms (masculine nominative with -er suffix)
    return 'ערשטער'   if $number == 1;   # ershter
    return 'צווייטער' if $number == 2;   # tsveyter
    return 'דריטער'   if $number == 3;   # driter

    # Stem irregulars
    return 'זיבעטער'  if $number == 7;   # zibeter
    return 'אַכטער'   if $number == 8;   # akhter

    my $cardinal = num2yid_cardinal($number);

    # Numbers 4-19 get suffix "טער", 20+ get "סטער"
    my $suffix = $number < 20 ? 'טער' : 'סטער';

    return $cardinal . $suffix;
}

# }}}

# {{{ capabilities              declare supported features

sub capabilities {
    return {
        cardinal => 1,
        ordinal  => 1,
    };
}

# }}}
1;

__END__