File Coverage

blib/lib/Lingua/UIG/Word2Num.pm

Criterion	Covered	Total	%
statement	22	22	100.0
branch			n/a
condition	2	2	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	34	34	100.0

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-
package Lingua::UIG::Word2Num;
# ABSTRACT: Word to number conversion in Uyghur

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Export::Attrs;
use Parse::RecDescent;

# }}}
# {{{ var block
our $VERSION = '0.2603300';
my $parser   = uig_numerals();

# }}}

# {{{ w2n                       convert text to number

sub w2n :Export {
    my $input = shift // return;

    $input =~ s/\s+/ /g;
    $input =~ s/^\s+|\s+$//g;

    return $parser->numeral($input);
}

# }}}
# {{{ uig_numerals              create parser for uyghur numerals

sub uig_numerals {
    return Parse::RecDescent->new(q{


      numeral:      mega
                  | kOhOd
                  | { }

      number:       /نۆل/      {  0 }
                  | /بىر/      {  1 }
                  | /ئىككى/    {  2 }
                  | /ئۈچ/      {  3 }
                  | /تۆت/      {  4 }
                  | /بەش/      {  5 }
                  | /ئالتە/    {  6 }
                  | /يەتتە/    {  7 }
                  | /سەككىز/   {  8 }
                  | /توققۇز/   {  9 }

      tens:         /ئون/      { 10 }
                  | /يىگىرمە/  { 20 }
                  | /ئوتتۇز/   { 30 }
                  | /قىرىق/    { 40 }
                  | /ئەللىك/   { 50 }
                  | /ئاتمىش/   { 60 }
                  | /يەتمىش/   { 70 }
                  | /سەكسەن/   { 80 }
                  | /توقسان/   { 90 }

      deca:         tens number          { $item[1] + $item[2] }
                  | tens
                  | number

      hecto:        number /يۈز/ deca    { $item[1] * 100 + $item[3] }
                  | number /يۈز/         { $item[1] * 100            }
                  | /يۈز/ deca           { 100 + $item[2]            }
                  | /يۈز/               { 100                       }

      hOd:        hecto
                | deca

      kilo:       hOd /مىڭ/ hOd    { $item[1] * 1000 + $item[3] }
                | hOd /مىڭ/        { $item[1] * 1000            }
                | /مىڭ/ hOd        { 1000 + $item[2]            }
                | /مىڭ/            { 1000                       }

      kOhOd:      kilo
                | hOd

      mega:       hOd /مىليون/ kOhOd { $item[1] * 1_000_000 + $item[3] }
                | hOd /مىليون/       { $item[1] * 1_000_000 }
    });
}

# }}}

1;

__END__