File Coverage

blib/lib/Lingua/SQI/Word2Num.pm

Criterion	Covered	Total	%
statement	22	22	100.0
branch			n/a
condition	2	2	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	34	34	100.0

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-
package Lingua::SQI::Word2Num;
# ABSTRACT: Word to number conversion in Albanian

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Export::Attrs;
use Parse::RecDescent;

# }}}
# {{{ var block
our $VERSION = '0.2603300';
my $parser   = sqi_numerals();

# }}}

# {{{ w2n                       convert text to number

sub w2n :Export {
    my $input = shift // return;

    $input =~ s{\A\s+}{}xms;
    $input =~ s{\s+\z}{}xms;

    return $parser->numeral($input);
}

# }}}
# {{{ sqi_numerals              create parser for Albanian numerals

sub sqi_numerals {
    return Parse::RecDescent->new(q{


      numeral:      mega
                  | kOhOd
                  | { }

      number:       'njëmbëdhjetë'        { 11 }
                  | 'dymbëdhjetë'         { 12 }
                  | 'trembëdhjetë'        { 13 }
                  | 'katërmbëdhjetë'      { 14 }
                  | 'pesëmbëdhjetë'       { 15 }
                  | 'gjashtëmbëdhjetë'    { 16 }
                  | 'shtatëmbëdhjetë'     { 17 }
                  | 'tetëmbëdhjetë'       { 18 }
                  | 'nëntëmbëdhjetë'      { 19 }
                  | 'zero'                {  0 }
                  | 'një'                 {  1 }
                  | 'dy'                  {  2 }
                  | /tre|tri/             {  3 }
                  | 'katër'               {  4 }
                  | 'pesë'                {  5 }
                  | 'gjashtë'             {  6 }
                  | 'shtatë'              {  7 }
                  | 'tetë'               {  8 }
                  | 'nëntë'               {  9 }
                  | 'dhjetë'              { 10 }

      tens:         'njëzet'              { 20 }
                  | 'tridhjetë'           { 30 }
                  | 'dyzet'               { 40 }
                  | 'pesëdhjetë'          { 50 }
                  | 'gjashtëdhjetë'       { 60 }
                  | 'shtatëdhjetë'        { 70 }
                  | 'tetëdhjetë'          { 80 }
                  | 'nëntëdhjetë'         { 90 }

      deca:         tens 'e' number       { $item[1] + $item[3] }
                  | tens
                  | number

      hecto:        number 'qind' 'e' deca  { $item[1] * 100 + $item[4] }
                  | number 'qind'            { $item[1] * 100            }
                  | /njëqind/                { 100                       }

      hOd:        hecto
                | deca

      kilo:       hOd 'mijë' 'e' hOd     { $item[1] * 1000 + $item[4] }
                | hOd 'mijë'             { $item[1] * 1000            }

      kOhOd:      kilo
                | hOd

      mega:       hOd /milionë?/ 'e' kOhOd { $item[1] * 1_000_000 + $item[4] }
                | hOd /milionë?/           { $item[1] * 1_000_000 }
    });
}

# }}}

1;

__END__