File Coverage

blib/lib/Lingua/SQI/Num2Word.pm

Criterion	Covered	Total	%
statement	47	48	97.9
branch	23	24	95.8
condition	18	27	66.6
subroutine	8	9	88.8
pod	2	2	100.0
total	98	110	89.0

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-

package Lingua::SQI::Num2Word;
# ABSTRACT: Number to word conversion in Albanian

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Carp;
use Export::Attrs;
use Readonly;

# }}}
# {{{ variable declarations

my Readonly::Scalar $COPY = 'Copyright (c) PetaMem, s.r.o. 2002-present';
our $VERSION = '0.2603300';

# }}}

# {{{ num2sqi_cardinal                 convert number to text

sub num2sqi_cardinal :Export {
    my $positive = shift;

    croak 'You should specify a number from interval [0, 999_999_999]'
        if    !defined $positive
           || $positive !~ m{\A\d+\z}xms
           || $positive < 0
           || $positive > 999_999_999;

    my @ones = qw(zero një dy tre katër pesë gjashtë shtatë tetë nëntë);
    my @teens = qw(
        dhjetë njëmbëdhjetë dymbëdhjetë trembëdhjetë katërmbëdhjetë
        pesëmbëdhjetë gjashtëmbëdhjetë shtatëmbëdhjetë tetëmbëdhjetë nëntëmbëdhjetë
    );
    my @tens = qw(
        _invalid _invalid njëzet tridhjetë dyzet pesëdhjetë
        gjashtëdhjetë shtatëdhjetë tetëdhjetë nëntëdhjetë
    );

    return $ones[$positive]              if ($positive >= 0 && $positive < 10);
    return $teens[$positive - 10]        if ($positive >= 10 && $positive < 20);

    my $out;
    my $remain;

    if ($positive >= 20 && $positive < 100) {                  # 20 .. 99
        my $ten_idx = int($positive / 10);
        $remain     = $positive % 10;

        $out = $tens[$ten_idx];
        $out .= ' e ' . $ones[$remain] if ($remain);
    }
    elsif ($positive >= 100 && $positive < 1000) {             # 100 .. 999
        my $hund_idx = int($positive / 100);
        $remain      = $positive % 100;

        $out  = $ones[$hund_idx] . 'qind';
        $out .= ' e ' . num2sqi_cardinal($remain) if ($remain);
    }
    elsif ($positive >= 1000 && $positive < 1_000_000) {       # 1000 .. 999_999
        my $kilo_idx = int($positive / 1000);
        $remain      = $positive % 1000;

        $out  = num2sqi_cardinal($kilo_idx) . ' mijë';
        $out .= ' e ' . num2sqi_cardinal($remain) if ($remain);
    }
    elsif ($positive >= 1_000_000 && $positive < 1_000_000_000) { # 1_000_000 .. 999_999_999
        my $mega_idx = int($positive / 1_000_000);
        $remain      = $positive % 1_000_000;

        $out  = num2sqi_cardinal($mega_idx);
        $out .= $mega_idx == 1 ? ' milion' : ' milionë';
        $out .= ' e ' . num2sqi_cardinal($remain) if ($remain);
    }

    return $out;
}

# }}}


# {{{ capabilities              declare supported features

sub capabilities {
    return {
        cardinal => 1,
        ordinal  => 0,
    };
}

# }}}
1;

__END__