File Coverage

blib/lib/Lingua/SOM/Word2Num.pm

Criterion	Covered	Total	%
statement	22	22	100.0
branch			n/a
condition	2	2	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	34	34	100.0

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-
package Lingua::SOM::Word2Num;
# ABSTRACT: Word to number conversion in Somali

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Export::Attrs;
use Parse::RecDescent;

# }}}
# {{{ var block
our $VERSION = '0.2603300';
my $parser   = som_numerals();

# }}}

# {{{ w2n                       convert text to number

sub w2n :Export {
    my $input = shift // return;

    $input =~ s/\s+/ /g;
    $input =~ s/^\s+|\s+$//g;

    return $parser->numeral($input);
}

# }}}
# {{{ som_numerals              create parser for somali numerals

sub som_numerals {
    return Parse::RecDescent->new(q{


      numeral:      mega
                  | kOhOd
                  | { }

      number:       'eber'       {  0 }
                  | /k[oó]w/     {  1 }
                  | /koób/       {  1 }
                  | /l[aá]ba/    {  2 }
                  | /lab[aá]/    {  2 }
                  | /s[aá]ddex/  {  3 }
                  | /[aá]far/    {  4 }
                  | /sh[aá]n/    {  5 }
                  | /l[ií]x/     {  6 }
                  | /toddob[aá]/ {  7 }
                  | /sidd[eé][eé]d/ {  8 }
                  | /saga[aá]l/  {  9 }

      tens:         /laba[aá]tan/    { 20 }
                  | /s[oó]ddon/      { 30 }
                  | /af[aá]rtan/     { 40 }
                  | /k[oó]nton/      { 50 }
                  | /l[ií]xdan/      { 60 }
                  | /toddoba[aá]tan/ { 70 }
                  | /sidde[eé]tan/   { 80 }
                  | /saga[aá]shan/   { 90 }

      deca:         number 'iyo' tens     { $item[1] + $item[3] }
                  | number 'iyo' 'toban'  { $item[1] + 10       }
                  | tens
                  | 'toban'               { 10 }
                  | number

      hecto:        number /boq[oó]l/ 'iyo' deca  { $item[1] * 100 + $item[4] }
                  | number /boq[oó]l/              { $item[1] * 100            }
                  | /boq[oó]l/ 'iyo' deca          { 100 + $item[3]            }
                  | /boq[oó]l/                     { 100                       }

      hOd:        hecto
                | deca

      kilo:       hOd /k[uú]n/ 'iyo' hOd     { $item[1] * 1000 + $item[4] }
                | hOd /k[uú]n/               { $item[1] * 1000            }
                | /k[uú]n/ 'iyo' hOd         { 1000 + $item[3]            }
                | /k[uú]n/                   { 1000                       }

      kOhOd:      kilo
                | hOd

      mega:       hOd /maly[uú]un/ 'iyo' kOhOd  { $item[1] * 1_000_000 + $item[4] }
                | hOd /maly[uú]un/               { $item[1] * 1_000_000 }
                | /maly[uú]un/ 'iyo' kOhOd       { 1_000_000 + $item[3] }
                | /maly[uú]un/                   { 1_000_000 }
    });
}

# }}}

1;

__END__