File Coverage

blib/lib/Lingua/RU/Numeral.pm

Criterion	Covered	Total	%
statement	267	267	100.0
branch	220	220	100.0
condition	73	76	96.0
subroutine	14	14	100.0
pod	3	3	100.0
total	577	580	99.4

package Lingua::RU::Numeral;

use 5.010;
use strict;
use warnings;
use utf8;
# use open qw(:std :utf8);

require Exporter;

our @ISA = qw(Exporter);

our %EXPORT_TAGS = ( 'all' => [ qw(
	num2cardinal
	case_endings
	spelled_out_number
) ] );

our @EXPORT_OK = ( @{ $EXPORT_TAGS{'all'} } );

our @EXPORT = qw( );

our $VERSION = '0.071';

########################
#  num2cardinal INPUT  #
########################
# SCALAR:
#~~~~~~~~
# 0.  $number -- число для обработки, e.g: 1234567890

#~~~~~~~~~~~
# HASH keys:
#~~~~~~~~~~~
# 1. 'case' key -- падеж:          числительное: Количественное     | Порядковое
#	(default)	n = nominative    - Именительный: есть кто? что?     | какой?
#					g = genitive      - Родительный:  нет кого? чего?    | какого?
#					d = dative        - Дательный:    рад кому? чему?    | какому?
#					a = accusative    - Винительный:  вижу кого? что?    | какой?
#					i = instrumental  - Творительный: оплачу кем? чем?   | каким?
#					p = prepositional - Предложный:   думаю о ком? о чём?| о каком?

# 2. 'gender' key -- род:
#	(default)	m = masculine (Мужской)
#					f = feminine  (Женский)
#					n = neuter    (Средний)

# 3. 'multi' key  -- единственное(undef|0|'singular') или множественное число (>0|'plural'). By default, 'singular'
# 4. 'object' key -- inanimate(неодушевлённый) или animate(одушевлённый) предмет. By default, 'inanimate'
# 5. 'prolog' key -- Preposition (prologue) of numeral
# 6. 'epilog' key -- Epilogue of numeral
# 7. 'alt' key
# 8. 'ucfirst' key

sub case_endings {
	$! = 22, return unless defined wantarray;
	my( $number, %cfg ) = @_;
	return unless defined $number;

	my( $i, $ns, @s ) = &num2cardinal( $number, %cfg );

	splice @s, $i, $ns - $i + 1, $number;

	return join(' ', @s);
}


sub spelled_out_number {
	$! = 22, return unless defined wantarray;
	my( $number, %cfg ) = @_;
	return unless defined $number;

	my( $i, $ns, @s ) = &num2cardinal( $number, %cfg );

	$s[$i] = '('.$s[$i];
	$s[$ns] = $s[$ns].')';
	splice @s, $i, 0, $number;

	return join(' ', @s);
}


sub _num_check {
	for( $_[0] ) {
		s/\D+//g;
		s/^0+/0/;
		s/^0(?!0)//;
	}
}


sub num2cardinal {
	$! = 22, return unless defined wantarray;
	my( $number, %cfg ) = @_;
	return unless defined $number;

	&_num_check( $number );

	# extreme index for:
	use constant VXN  => 5;	# numbers from 5 to <1000
	use constant TMMT => 6;	# тысячи | миллионы | миллиарды | триллионы

	my $gender = $cfg{'gender'} || 'masculine';
	$gender = $gender=~/^\s*(m|f|n)/i ? @{{'m'=>'masculine', 'f'=>'feminine', 'n'=>'neuter'}}{lc $1} : 'masculine';

	my $case = $cfg{'case'} || 'nominative';
	$case = $case=~/^\s*([ngdaip])/i ? $1 : 'n';

	my $multi = $cfg{'multi'} || 'singular';
	$multi = $multi=~/^\s*[p1-9]/i ? 'plural' : 'singular';

	my $object = $cfg{'object'} || 'inanimate';
	$object = $object=~/^\s*[a1-9]/i ? 'animate' : 'inanimate';

	# Preposition (prologue) of numeral
	my $prolog = &_ref_prolog( \%cfg, \$case );

	# Epilogue of numeral
	my $epilog = &_ref_epilog( $case, $multi, \%cfg, \$object, \$gender );

	unless( $number ) {
		my $oy = exists( $cfg{'alt'}{0} ) ? 'у' : 'о';
		my $zero = ($case =~/^a/i && $object =~/^animate/i ) ?
			"н${oy}ля" :
			@{{'n'=>"н${oy}ль", 'g'=>"н${oy}ля", 'd'=>"н${oy}лю", 'a'=>"н${oy}ль", 'i'=>"н${oy}лём", 'p'=>"н${oy}ле"}}{ $case };

		# Add the numeral
		 my @s = ( $zero );

		# Add the prolog to numeral
		my $ii = &_add_prolog( $prolog, \@s );
		my $ns = $#s;

		# Add the epilog to numeral
		if( exists $epilog->{'root'} ) {
			my $j = 0;
			for my $root ( @{ $epilog->{'root'} } ) {
				push @s, $root.$epilog->{'ends'}[ $j++ ][0];
			}
		}

		$s[$ii] = ucfirst $s[$ii] if exists $cfg{'ucfirst'};

		return wantarray ? ( $ii, $ns, @s )  : join(' ', @s);
	}

	return "$number > 999_999_999_999_999 !" if length( $number ) > 15;

	# To get cardinal form DB (БД словоформ числительных)
	my( $bsw, $plural, $Power ) = &_cardinal_form_db( $case, $multi, $object, $gender, \%cfg );

	my @Dcml = @{ $bsw->{'dcml'} };
	my @Cent = @{ $bsw->{'cent'} };

	my @tmEnd;	# for ends --- для окончаний 'тысяч','миллион','миллиард','триллион'
	my @words;	# for ends --- для искомой структуры слов числительных
	my @s;	# Resulting string --- Результирующая строка
	my $ns;	# size of numeral string

	while( length( $number ) && $number ) {
		if( $number =~/^.$/ ) { # 0..9

			push @s, ( $multi =~/^plural/i && $number == 1 ) ?
				$plural->{1} :
				$bsw->{ $gender }{ ($case =~/^a/i && $object =~/^animate/i) ? 'animate' : 'unit'}[ $number ];

			# Add epilog to numeral
			if( exists $epilog->{'root'} ) {

				my $j = 0;
				for my $root ( @{ $epilog->{'root'} } ) {
					push @s, $root.$epilog->{'ends'}[ $j++ ][ $number < 5 ? $number : VXN ];
				}
				$ns = $j;

				$epilog = {};	# epilog END
			}

			last;
		}

		my $i = int length( $number ) / 3;

		if( $i < 2 ) { # $number = 10 .. 99_999
			# Женский род, (т.к. может быть 'тысяч')
			@words = @{ $bsw->{'feminine'}{'unit'} };
			@tmEnd = @{ $bsw->{'eT'} }; # окончания для 'тысяч'
		}
		else { # Для >=100_000, 'миллион','миллиард','триллион'
			# Мужской род
			@words = @{ $bsw->{'masculine'}{'unit'} };
			@tmEnd = @{ $bsw->{'eMT'} }; # окончания
		}

		if( length( $number )%3 == 0 ) { # Сотни: 100 .. 999, 100_xxx .. 999_xxx, 100_xxx_xxx .. 999_xxx_xxx, etc.
			$number =~s/^\d//;
			push @s, $Cent[$&] if $&;
		}
		elsif( length( $number )%3 == 2 ) { # Десятки: 10 .. 99, 10_xxx .. 99_xxx, 10_xxx_xxx .. 99_xxx_xxx, etc.
			if( $number =~/^1/ ) { # 10... 19...
				$number =~s/^\d\d//;
				push @s, $words[$&];

				push @s, $Power->[$i].$tmEnd[0] if length $Power->[$i];
			}
			else { # 00, 20... 99...
				$number =~s/^\d//;
				push @s, $Dcml[$&] if $&;
			}
		}
		else { # length( $number )%3 == 1  # Единицы: 0..., 1,..., 9...
			$number =~s/^\d//;
			my $d = $&;
			if( $d ) {
				push @s, ( $multi =~/^plural/i && $d == 1 ) ? $plural->{1} : $words[$d];
			}

			if( $s[-1] !~/^(?:м|трил)/ ) { # ещё не добавлено миллион | миллиард | триллион
				my $w = ( $multi =~/^plural/i && $d == 1 ) ?
								$plural->{ $i < 2 ? 'eT' : 'eMT'} :
								$tmEnd[ $d < 5 ? $d : 0 ];

				push @s, $Power->[$i].$w;
			}

			last if $number =~/^0+$/;
		}
	}

	# Add prolog to numeral
	my $ii = &_add_prolog( $prolog, \@s );
	$ns = ( defined $ns ) ? $#s - $ns : $#s;

	$s[$ii] = ucfirst $s[$ii] if exists $cfg{'ucfirst'};

	# Add epilog to numeral
	if( exists $epilog->{'root'} ) {

		# Choice between
		my $k = $s[-1] =~/^(?:ты|ми|трил)/ ?
				TMMT :	# тысяча | миллион | миллиард | триллион
				VXN;	# other

		my $j = 0;
		for my $root ( @{ $epilog->{'root'} } ) {
			push @s, $root.$epilog->{'ends'}[ $j++ ][ $k ];
		}

	}

	return wantarray ? ( $ii, $ns, @s )  : join(' ', @s);
}


sub _cardinal_form_db {
	my( $case, $multi, $object, $gender, $cfg ) = @_;

	# База словоформ числительных (singular -- единственно число, default)
	my %bsw = (
		'n' => { # nominative (Именительный падеж) кто? что?, default
			'masculine' => { # Мужской род, default
				'unit' => [ # 0..19
					'','один','два','три','четыре','пять','шесть','семь','восемь','девять','десять',
'одиннадцать','двенадцать','тринадцать','четырнадцать','пятнадцать','шестнадцать','семнадцать','восемнадцать','девятнадцать'
				],
			},
			'feminine' => { # Женский род
				'unit' => [ # 0..19
					'','одна','две' # остальные как для Мужского рода
				],
			},
			'neuter' => { # Средний род
				'unit' => [ # 0..19
					'','одно' # остальные как для Мужского рода
				],
			},
			'dcml' => [ # 20, 30,...,90
				'','','двадцать','тридцать','сорок','пятьдесят','шестьдесят','семьдесят','восемьдесят','девяносто'
			],
			'cent' => [ # 100..900
				'','сто','двести','триста','четыреста','пятьсот','шестьсот','семьсот','восемьсот','девятьсот'
			],
			'eT' => [ # окончания для 'тысяч' (0й - для 10..19; десятков: 10,20,...,90 и сотен: 100,200,...,900)
				'','а', ('и') x 3 # , ('') x 5
			],
			'eMT' => [ # окончания для 'миллион','миллиард','триллион' (0й - для 10..19; десятков: 10,20,...,90 и сотен: 100,200,...,900)
				'ов','', ('а') x 3 # , ('ов') x 5
			],
		}, #--------------------------------------------
		'g' => { # genitive (Родительный падеж): кого? чего?
			'masculine' => { # Мужской род, default
				'unit' => [ # 0..19
					'','одного','двух','трёх','четырёх','пяти','шести','семи','восьми','девяти','десяти',
'одиннадцати','двенадцати','тринадцати','четырнадцати','пятнадцати','шестнадцати','семнадцати','восемнадцати','девятнадцати'
				],
			},
			'feminine' => { # Женский род
				'unit' => [ # 0..19
					'','одной' # остальные как для Мужского рода
				],
			},
			'neuter' => { # Средний род
				'unit' => [ # 0..19
					'' # всё как для Мужского рода
				],
			},
			'dcml' => [ # 20, 30,...,90
				'','','двадцати','тридцати','сорока','пятидесяти','шестидесяти','семидесяти','восьмидесяти','девяноста'
			],
			'cent' => [ # 100..900
				'','ста','двухсот','трёхсот','четырёхсот','пятисот','шестисот','семисот','восьмисот','девятисот'
			],
			'eT' => [ # окончания для 'тысяч'
				'','и', ('') x 3 # 8
			],
			'eMT' => [ # окончания для 'миллион','миллиард','триллион'
				'ов','а', ('ов') x 3 # 8
			],
		}, #--------------------------------------------
		'd' => { # dative (Дательный падеж): кому? чему?
			'masculine' => { # Мужской род, default
				'unit' => [ # 0..19
					'','одному','двум','трём','четырём','пяти','шести','семи','восьми','девяти','десяти',
'одиннадцати','двенадцати','тринадцати','четырнадцати','пятнадцати','шестнадцати','семнадцати','восемнадцати','девятнадцати'
				],
			},
			'feminine' => { # Женский род
				'unit' => [ # 0..19
					'','одной' # остальные как для Мужского рода
				],
			},
			'neuter' => { # Средний род
				'unit' => [ # 0..19
					'' # всё как для Мужского рода
				],
			},
			'dcml' => [ # 20, 30,...,90 : как Родительный падеж
				'','','двадцати','тридцати','сорока','пятидесяти','шестидесяти','семидесяти','восьмидесяти','девяноста'
			],
			'cent' => [ # 100..900
				'','ста','двумстам','трёхстам','четырёхстам','пятистам','шестистам','семистам','восьмистам','девятистам'
			],
			'eT' => [ # окончания для 'тысяч'
				'ам','е', ('ам') x 3 # 8
			],
			'eMT' => [ # окончания для 'миллион','миллиард','триллион'
				'ам','у', ('ам') x 3 # 8
			],
		}, #--------------------------------------------
		'a' => { # accusative (Винительный падеж): animate (одушевлённый объект): кого? | inanimate (неодушевлённый объект): что?
			'masculine' => { # Мужской род, inanimate default
				'unit' => [ # 0..19 : неодушевлённый объект, как Именительный падеж
					'','один','два','три','четыре','пять','шесть','семь','восемь','девять','десять',
'одиннадцать','двенадцать','тринадцать','четырнадцать','пятнадцать','шестнадцать','семнадцать','восемнадцать','девятнадцать'
				],
				'animate' => [ # 0..19 : одушевлённый объект, как Родительный падеж (0..4), Именительный падеж (5..19)
					'','одного','двух','трёх','четырёх',  'пять','шесть','семь','восемь','девять','десять',
'одиннадцать','двенадцать','тринадцать','четырнадцать','пятнадцать','шестнадцать','семнадцать','восемнадцать','девятнадцать'
				],
			},
			'feminine' => { # Женский род
				'unit' => [ # 0..19 : неодушевлённый объект
					'','одну','две' # остальные как для Мужского рода
				],
				'animate' => [ # 0..19 : одушевлённый объект
					'','одну' # остальные как для одушевлённого Мужского рода
				],
			},
			'neuter' => { # Средний род
				'unit' => [ # 0..19 : неодушевлённый объект
					'','одно' # остальные как для Мужского рода
				],
				'animate' => [ # 0..19 : одушевлённый объект
					'','одно','два' # остальные как для одушевлённого Мужского рода
				],
			},
			'dcml' => [ # 20, 30,...,90
				'','','двадцать','тридцать','сорок','пятьдесят','шестьдесят','семьдесят','восемьдесят','девяносто'
			],
			'cent' => [ # 100..900
				'','сто','двести','триста','четыреста','пятьсот','шестьсот','семьсот','восемьсот','девятьсот'
			],
			'eT' => [ # окончания для 'тысяч' (0й - для 10..19 и десятков: 10,20,...,90)
				'','у', ('и') x 3 # , ('') x 5
			],
			'eMT' => [ # окончания для 'миллион','миллиард','триллион' (0й - для 10..19 и десятков: 10,20,...,90)
				'ов','', ('а') x 3 # , ('ов') x 5
			],
		}, #--------------------------------------------
		'i' => { # instrumental (Творительный падеж) : кем? чем?
			'masculine' => { # Мужской род, default
				'unit' => [ # 0..19
					'','одним','двумя','тремя','четырьмя','пятью','шестью','семью','восемью','девятью','десятью', # or 'восьмью'  (see p.22)
'одиннадцатью','двенадцатью','тринадцатью','четырнадцатью','пятнадцатью','шестнадцатью','семнадцатью','восемнадцатью','девятнадцатью'
				],
			},
			'feminine' => { # Женский род
				'unit' => [ # 0..19
					'','одной' # остальные как для Мужского рода
				],
				'if1' => 'одною', # альтернативная форма
			},
			'dcml' => [ # 20, 30,...,90
'','','двадцатью','тридцатью','сорока','пятьюдесятью','шестьюдесятью','семьюдесятью','восемьюдесятью','девяноста' # or 'восьмьюдесятью' (see p.22)
			],
			'cent' => [ # 100..900
'','ста','двумястами','тремястами','четырьмястами','пятьюстами','шестьюстами','семьюстами','восемьюстами','девятьюстами' # or 'восьмьюстами' (see p.22)
			],
			'eT' => [ # окончания для 'тысяч'
				'ами','ей', ('ами') x 3
#				'ами','ью', ('ами') x 3 # разговорная форма (see 'i.T'=>'C')
#				'ами','ею', ('ами') x 3 # устаревшая форма (see 'i.T'=>'O')
			],
			'i.T' => { # формы окончания для 1 'тысяч'
				'C' => 'ью', # разговорная (colloquial form)
				'O' => 'ею', # устаревшая (obsolete form)
			},
			'eMT' => [ # окончания для 'миллион','миллиард','триллион'
				'ами','ом', ('ами') x 3 # 8
			],
			'i.8' => {	# разговорные формы (see p.22)
				'unit' => 'восьмью',
				'dcml' => 'восьмьюдесятью',
				'cent' => 'восьмьюстами',
			},
		}, #--------------------------------------------
		'p' => { # prepositional (Предложный падеж) : о ком? о чём?
			'masculine' => { # Мужской род, default
				'unit' => [ # 0..19
					'','одном','двух','трёх','четырёх','пяти','шести','семи','восьми','девяти','десяти',
'одиннадцати','двенадцати','тринадцати','четырнадцати','пятнадцати','шестнадцати','семнадцати','восемнадцати','девятнадцати'
				],
			},
			'feminine' => { # Женский род
				'unit' => [ # 0..19
					'','одной' # остальные как для Мужского рода
				],
			},
			'dcml' => [ # 20, 30,...,90
				'','','двадцати','тридцати','сорока','пятидесяти','шестидесяти','семидесяти','восьмидесяти','девяноста'
			],
			'cent' => [ # 100..900
				'','ста','двухстах','трёхстах','четырёхстах','пятистах','шестистах','семистах','восьмистах','девятистах'
			],
			'eT' => [ # окончания для 'тысяч'
				'ах','е', ('ах') x 3 # 8
			],
			'eMT' => [ # окончания для 'миллион','миллиард','триллион'
				'ах','е', ('ах') x 3 # 8
			],
		},
	);

	my %plural = ( # множественное число
		'n' => { # nominative (Именительный падеж)
			1 => 'одни',
			'eT'  => 'и', # окончание для 'тысяч'
			'eMT' => 'ы', # окончания для 'миллион','миллиард','триллион'
		},
		'g' => { # genitive (Родительный падеж)
			1 => 'одних',
			'eT'  => '',
			'eMT' => 'ов',
		},
		'd' => { # dative (Дательный падеж)
			1 => 'одним',
			'eT'  => 'ам',
			'eMT' => 'ам',
		},
		'a' => { # accusative (Винительный падеж):
			1 => 'одни', # inanimate(неодушевлённый) объект. For animate(одушевлённый) -- see below
			'eT'  => 'и',
			'eMT' => 'ы',
		},
		'i' => {# instrumental (Творительный падеж)
			1 => 'одними',
			'eT'  => 'ами',
			'eMT' => 'ами',
		},
		'p' => { # prepositional (Предложный падеж)
			1 => 'одних',
			'eT'  => 'ах',
			'eMT' => 'ах',
		},
	);

	# Дозаполняем необходимые структуры, кроме 'masculine'
	my %gg = ('masculine' => undef );
	for my $g ('feminine', $gender ) {
		next if exists $gg{ $g };
		$gg{ $g } = undef;

		for(0..19) {
			# если НЕ определено
			$bsw{ $case }{ $g }{'unit'}[$_] //= $bsw{ $case }{'masculine'}{'unit'}[$_];

			$bsw{'a'}{ $g }{'animate'}[$_] //= $bsw{'a'}{'masculine'}{'animate'}[$_]
				if $case =~/^a/i && $object =~/^animate/i; # for accusative(Винительный падеж) + одушевлённый объект
		}

	}

	# Настраиваем альтернативные | разговорные | устаревшие формы, если заданы
	if( $case =~/^i/ and exists $cfg->{'alt'} ) {

		my $k = 'i.T';	# разговорная|устаревшая форма окончания для 'тысяч'
		if( defined( $cfg->{'alt'}{ $k } ) and $cfg->{'alt'}{ $k } =~/^(C|O)/i ) {
			$bsw{'i'}{'eT'}[1] = $bsw{'i'}{ $k }{uc $1};
		}

		$k = 'i.8';
		if( exists $cfg->{'alt'}{ $k } ) {
			for('dcml','cent') {	# 'восьмьюдесятью', 'восьмьюстами',
				$bsw{'i'}{$_}[8] = $bsw{'i'}{ $k }{$_};
			}

			my %gg;
			for my $g ('masculine','feminine', $gender ) {
				next if exists $gg{ $g };
				$gg{ $g } = undef;

				$bsw{'i'}{ $g }{'unit'}[8] = $bsw{'i'}{ $k }{'unit'};# 'восьмью'
			}
		}

		$bsw{'i'}{'feminine'}{'unit'}[1] = $bsw{'i'}{'feminine'}{'if1'} if exists $cfg->{'alt'}{'if1'};
	}

	# Корректируем окончания для accusative(Винительный падеж) + одушевлённый объект + множественное число
	if( $case =~/^a/i && $object =~/^animate/i && $multi =~/^plural/i ) {
		$plural{'a'}{1} = 'одних';
		$plural{'a'}{'eT'} = '';
		$plural{'a'}{'eMT'} = 'ов';
	}

	return( \%{ $bsw{ $case } }, \%{ $plural{ $case } }, ['','тысяч','миллион','миллиард','триллион'] );
}


# Add prolog to numeral, e.g. ['с','со=ст',...]
sub _add_prolog {
	my( $prolog, $s ) = @_;
	return 0 if ! @$prolog or (~~@$prolog < 2 and ( ! defined( $prolog->[0] ) or ! length( $prolog->[0] ) ) );

	# get element 0 in order (e.g. 'с') for any numeral
	my $p = ( !defined( $prolog->[0] ) or ! length( $prolog->[0] ) or $prolog->[0] =~/=/ ) ?
		undef :
		shift @$prolog;

	# get remaining elements
	my $i = 0;
	for( @$prolog ) {	# ['со=ст',...]
		next unless $_;

		my( $k, $m ) = split '=';
		next unless $k && $m;

		if( $s->[0] =~/^$m/ ) {
			unshift @$s, $k;
			undef $p;
			$i = 1;
			last;
		}
	}

	if( defined $p ) {
		unshift @$s, $p;
		$i = 1;
	}

	return $i;
}


sub _ref_prolog {
	my( $cfg, $case ) = @_;
	my $prolog = $cfg->{'prolog'} // return [ ];

	if( ref($prolog) eq 'ARRAY') {
		return ~~@$prolog ? [ @$prolog ] : [ ];
	}
	elsif( ref($prolog) eq 'HASH') {
		my @p;
		for my $k (sort keys %$prolog ) {
			my $v = $prolog->{$k};
			$k =~s/^\s+|\s+$//g;
			next unless length $k or $v;

			if( length $v ) {
				push @p, "$k=$v";
			}
			else {
				unshift @p, $k;
			}
		}
		return ~~@p ? \@p : [ ];
	}
	elsif( ref(\$prolog) eq 'SCALAR') {
		$prolog =~s/^\s+|\s+$//g;

		# genitive - Родительный: кого? чего?
		if( $prolog =~/^(?:
				безо?|
				в(?:близи|виду|доль|замен|круг|место|не|низу|нутр[иь]|переди?|роде|овнутрь|озле|округ|следствие|ыше)|
				для|до|
				из(?:о?|\-за|нутри|\-подо?)|
				каса(?:ем|тельн)о|кроме|кругом|
				мимо|
				на(?:кануне|место|подобие|против|супротив|счет)|ниже|
				о(?:бок|бочь|коло|крест|круг|причь|то?|тносительно)|
				по(?:близости|верх|дле|зад[иь]|мимо|перек|се?реди(?:не)?|середь|сле|средством)|
				пр(?:евыше|отив)|путем|
				ради|
				с(?:верху?|выше|ередь|зади|илами|наружи|низу|переди|ред[иь]|упротив)|
				у
			)$/ix
		) {
			$$case = 'g'; # genitive
			return [ $prolog ];
		}

		# dative - Дательный: кому? чему?
		if( $prolog =~ /^(?:
				вдогон(?:ку|очку)?|вослед|вразрез|вслед|
				ко?|
				напере(?:кор|рез)|
				подобно|противно|
				соо(?:браз|тветствен)но|соразмерно
			)$/ix
		) {
			$$case = 'd'; # dative
			return [ $prolog ];
		}
		elsif( $prolog =~ /^благодаря$/i ) {
			$$case = 'd' if $$case !~/^[d]/;
			return [ $prolog ];
		}

		# accusative - Винительный: кого? что?
		if( $prolog =~ /^(?:
				(?:вы?|ис)ключая|про|сквозь|спустя|че?рез
			)$/ix
		) {
			$$case = 'a'; # accusative
			return [ $prolog ];
		}

		# instrumental - Творительный: кем? чем?
		if( $prolog =~ /^(?:
				кончая|надо?|начиная|передо?|по\-[зн]ад?
			)$/ix
		) {
			$$case = 'i'; # instrumental
			return [ $prolog ];
		}

		# prepositional - Предложный: о ком? о чём?
		if( $prolog =~ /^при$/i ) {
			$$case = 'p'; # prepositional
			return [ $prolog ];
		}

		# genitive (Родительный) || dative (Дательный, by default)
		if( $prolog =~ /^согласно$/i ) {
			$$case = 'd' if $$case !~/^[gd]/;
			return [ $prolog ];
		}

		# genitive (Родительный, by default) || instrumental (Творительный)
		if( $prolog =~ /^(?:про)?меж(?:ду)?$/i ) {
			$$case = 'g' if $$case !~/^[gi]/;
			return [ $prolog ];
		}

		# accusative (Винительный) || instrumental (Творительный, by default)
		if( $prolog =~ /^(?:за|подо?)$/i ) {
			$$case = 'i' if $$case !~/^[ai]/;
			return [ $prolog ];
		}

		# accusative (Винительный) || prepositional (Предложный)
		if( $prolog =~/^[вВB][ОоOo]?$/ ) {
			$prolog =~tr/BOo/ВОо/;
			$$case = 'a' if $$case !~/^[ap]/;
			return [ $prolog ];
		}
		elsif( $prolog =~ /^[oOоО][бБ]?[oOоО]?$/ ) {
			$$case = 'p' if $$case !~/^[ap]/;
			return ['о','об=од'];
		}
		elsif( $prolog =~ /^на$/i ) {
			$$case = 'a' if $$case !~/^[ap]/;
			return [ $prolog ];
		}

		# accusative (Винительный) || genitive (Родительный) || instrumental (Творительный, by default)
		if( $prolog =~/^[cCсС][ОоOo]?$/ ) {
			$$case = 'i' if $$case !~/^[agi]/;
			return ['с','со=ст'];
		}

		# accusative (Винительный) || dative (Дательный, by default) || prepositional (Предложный)
		if( $prolog =~ /^по$/i ) {
			$$case = 'd' if $$case !~/^[adp]/;
			return [ $prolog ];
		}

	}

	return [ ];
}


sub _ref_epilog {
	my( $case, $multi, $cfg, $object, $gender ) = @_;
	my $epilog = $cfg->{'epilog'} or return {};

	if( ref(\$epilog) eq 'SCALAR') {
		my %eRef;

		if( $epilog =~/^(?:RU[BR]|643|810|₽|(?i:рубль|ruble))$/ ) { # Российский рубль
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'рубл',
					'ends' => {
							'n' => ['ей','ь', ('я') x 3, ('ей') x 2 ],	# nominative - Именительный
							'g' => ['ей','я', ('ей') x 5 ],	# genitive - Родительный
							'd' => ['ям','ю', ('ям') x 4, 'ей' ],	# dative - Дательный
							'a' => ['ей','ь', ('я') x 3, ('ей') x 2 ],	# accusative - Винительный
							'i' => ['ей','ём', ('ями') x 4, 'ей' ],	# instrumental - Творительный
							'p' => ['ей','е', ('ях') x 4, 'ей' ],	# prepositional - Предложный
					},
					'plural' => {'n'=>'и', 'g'=>'ей', 'd'=>'ям', 'a'=>'и', 'i'=>'ями', 'p'=>'ях'},
				);

		}
		elsif( $epilog =~/^(?:BY[BRN]|Br|933|974)$/) { # Белорусский рубль
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => ['белорусск','рубл'],
					'ends' => {
							'n' => [['их','ий', ('их') x 5 ], ['ей','ь', ('я') x 3, ('ей') x 2 ]],	# nominative - Именительный
							'g' => [['их','ого', ('их') x 5 ], ['ей','я', ('ей') x 5 ]],	# genitive - Родительный
							'd' => [['им','ому', ('им') x 4, 'их'], ['ям','ю', ('ям') x 4, 'ей' ]],	# dative - Дательный
							'a' => [['их','ий', ('их') x 5 ], ['ей','ь', ('я') x 3, ('ей') x 2 ]],	# accusative - Винительный
							'i' => [['их','им', ('ими') x 4, 'их'], ['ей','ём', ('ями') x 4, 'ей']],	# instrumental - Творительный
							'p' => [['их','ом', ('их') x 5], ['ей','е', ('ях') x 4, 'ей']],	# prepositional - Предложный
					},
					'plural' => {'n'=>['ие','и'], 'g'=>['их','ей'], 'd'=>['им','ям'], 'a'=>['ие','и'], 'i'=>['ими','ями'], 'p'=>['их','ях']},
				);

		}
		elsif( $epilog =~/^(?:ru[br]|\-643|\-810|by[brn]|\-933|\-974|(?i:копейка|kopek))$/) { # Российская | Белорусская копейка
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'feminine',
					'root' => 'копе',
					'ends' => {
							'n' => ['ек','йка', ('йки') x 3, ('ек') x 2 ],
							'g' => ['ек','йки', ('ек') x 5 ],
							'd' => ['ек','йке', ('йкам') x 4, 'ек' ],
							'a' => ['ек','йку', ('йки') x 3, ('ек') x 2 ],
							'i' => ['ек','йкой', ('йками') x 4, 'ек' ],
							'p' => ['ек','йке', ('йках') x 4, 'ек' ],
					},
					'plural' => {'n'=>'йки', 'g'=>'ек', 'd'=>'йкам', 'a'=>'йки', 'i'=>'йками', 'p'=>'йках'},
				);

		}
		elsif( $epilog =~/^(?:USD|840|(?:US)?\$|(?i:доллар|dollar))$/) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'доллар',
					'ends' => {
							'n' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'g' => ['ов','а', ('ов') x 5 ],
							'd' => ['ам','у', ('ам') x 4, 'ов' ],
							'a' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'i' => ['ов','ом', ('ами') x 4, 'ов' ],
							'p' => ['ов','е', ('ах') x 4, 'ов' ],
					},
					'plural' => {'n'=>'ы', 'g'=>'ов', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:usd|\-840|(?i:цент|cent))$/) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'цент',
					'ends' => {
							'n' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'g' => ['ов','а', ('ов') x 5 ],
							'd' => ['ам','у', ('ам') x 4, 'ов' ],
							'a' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'i' => ['ов','ом', ('ами') x 4, 'ов' ],
							'p' => ['ов','е', ('ах') x 4, 'ов' ],
					},
					'plural' => {'n'=>'ы', 'g'=>'ов', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:CNY|RMB|156|(?i:юань|yuan))$/) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'юан',
					'ends' => {
							'n' => ['ей','ь', ('я') x 3, ('ей') x 2 ],
							'g' => ['ей','я', ('ей') x 5 ],
							'd' => ['ям','ю', ('ям') x 5 ],
							'a' => ['ей','ь', ('я') x 3, ('ей') x 2 ],
							'i' => ['ей','ем', ('ями') x 4, 'ей' ],
							'p' => ['ях','е', ('ях') x 4, 'ей' ],
					},
					'plural' => {'n'=>'и', 'g'=>'ей', 'd'=>'ям', 'a'=>'и', 'i'=>'ями', 'p'=>'ях'},
				);

		}
		elsif( $epilog =~/^(?:cny|rmb|-156|(?i:фынь))$/) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'фын',
					'ends' => {
							'n' => ['ей','ь', ('я') x 3, ('ей') x 2 ],
							'g' => ['ей','я', ('ей') x 5 ],
							'd' => ['ям','ю', ('ям') x 5 ],
							'a' => ['ей','ь', ('я') x 3, ('ей') x 2 ],
							'i' => ['ей','ем', ('ями') x 4, 'ей' ],
							'p' => ['ях','е', ('ях') x 4, 'ей' ],
					},
					'plural' => {'n'=>'и', 'g'=>'ей', 'd'=>'ям', 'a'=>'и', 'i'=>'ями', 'p'=>'ях'},
				);

		}
		elsif( $epilog =~/^(?:year|год|лет)$/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => '',
					'ends' => {
							'n' => ['лет','год', ('года') x 3, ('лет') x 2 ],
							'g' => ['лет','года', ('лет') x 5 ],
							'd' => ['лет','году', ('годам') x 4, 'лет' ],
							'a' => ['лет','год', ('года') x 3, ('лет') x 2 ],
							'i' => ['лет','годом', ('годами') x 4, 'лет' ],
							'p' => ['лет','годе', ('годах') x 4, 'лет' ],
					},
					'plural' => {'n'=>'годы', 'g'=>'лет', 'd'=>'годам', 'a'=>'годы', 'i'=>'годами', 'p'=>'годах'},
				);

		}
		elsif( $epilog =~/^(?:month|месяц)$/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'месяц',
					'ends' => {
							'n' => ['ев','', ('а') x 3, ('ев') x 2 ],
							'g' => ['ев','а', ('ев') x 5 ],
							'd' => ['ам','у', ('ам') x 5 ],
							'a' => ['ев','', ('а') x 3, ('ев') x 2 ],
							'i' => ['ев','ем', ('ами') x 4, 'ев'],
							'p' => ['ев','е', ('ах') x 4, 'ев'],
					},
					'plural' => {'n'=>'ы', 'g'=>'ев', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:day|день)$/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'д',
					'ends' => {
							'n' => ['ней','ень', ('ня') x 3, ('ней') x 2 ],
							'g' => ['ней','ня', ('ней') x 5 ],
							'd' => ['ням','ню', ('ням') x 5 ],
							'a' => ['ней','ень', ('ня') x 3, ('ней') x 2 ],
							'i' => ['ней','нём', ('нями') x 4, 'ней'],
							'p' => ['ней','не', ('нях') x 4, 'ней'],
					},
					'plural' => {'n'=>'ни', 'g'=>'ней', 'd'=>'ням', 'a'=>'ни', 'i'=>'нями', 'p'=>'нях'},
				);

		}
		elsif( $epilog =~/^(?:hour|час)$/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'час',
					'ends' => {
							'n' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'g' => ['ов','а', ('ов') x 5 ],
							'd' => ['ам','у', ('ам') x 5 ],
							'a' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'i' => ['ов','ом', ('ами') x 4, 'ов'],
							'p' => ['ов','е', ('ах') x 4, 'ов'],
					},
					'plural' => {'n'=>'ы', 'g'=>'ов', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:min|мин)/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'feminine',
					'root' => 'минут',
					'ends' => {
							'n' => ['','а', ('ы') x 3, ('') x 2 ],
							'g' => ['','ы', ('') x 5 ],
							'd' => ['','е', ('ам') x 4, ''],
							'a' => ['','у', ('ы') x 3, ('') x 2 ],
							'i' => ['','ой', ('ами') x 4, ''],
							'p' => ['','е', ('ах') x 4, ''],
					},
					'plural' => {'n'=>'ы', 'g'=>'', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:sec|сек)/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'feminine',
					'root' => 'секунд',
					'ends' => {
							'n' => ['','а', ('ы') x 3, ('') x 2 ],
							'g' => ['','ы', ('') x 5 ],
							'd' => ['','е', ('ам') x 4, ''],
							'a' => ['','у', ('ы') x 3, ('') x 2 ],
							'i' => ['','ой', ('ами') x 4, ''],
							'p' => ['','е', ('ах') x 4, ''],
					},
					'plural' => {'n'=>'ы', 'g'=>'', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:meter|метр)$/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'masculine',
					'root' => 'метр',
					'ends' => {
							'n' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'g' => ['ов','а', ('ов') x 5 ],
							'd' => ['ов','у', ('ам') x 4, 'ов'],
							'a' => ['ов','', ('а') x 3, ('ов') x 2 ],
							'i' => ['ов','ом', ('ами') x 4, 'ов'],
							'p' => ['ов','е', ('ах') x 4, 'ов'],
					},
					'plural' => {'n'=>'ы', 'g'=>'ов', 'd'=>'ам', 'a'=>'ы', 'i'=>'ами', 'p'=>'ах'},
				);

		}
		elsif( $epilog =~/^(?:stamp|печат)/i) {
			%eRef = (
					'object' => 'inanimate',
					'gender' => 'feminine',
					'root' => 'печат',
					'ends' => {
							'n' => ['ей','ь', ('и') x 3, ('ей') x 2 ],
							'g' => ['ей','и', ('ей') x 5 ],
							'd' => ['ей','и', ('ям') x 4, 'ей'],
							'a' => ['ей','ь', ('и') x 3, ('ей') x 2 ],
							'i' => ['ей','ью', ('ями') x 4, 'ей'],
							'p' => ['ей','и', ('ях') x 4, 'ей'],
					},
					'plural' => {'n'=>'и', 'g'=>'ей', 'd'=>'ям', 'a'=>'и', 'i'=>'ями', 'p'=>'ях'},
				);

		}

		if( %eRef ) {
			$$object = $eRef{'object'};
			$$gender = $eRef{'gender'};

			# To fix for plural '1' only
			if( $multi =~/^plural/i ) {
				if( ref( \$eRef{'plural'}{ $case } ) eq 'SCALAR') {
					$eRef{'ends'}{ $case }[1] = $eRef{'plural'}{ $case };
				}
				else { # if( ref( $eRef{'plural'}{ $case } ) eq 'ARRAY') # a lot of words in the epilogue
					my $i = 0;
					for( @{ $eRef{'plural'}{ $case } } ) {
						$eRef{'ends'}{ $case }[ $i++ ][1] = $_;
					}
				}
			}

			$epilog = {};

			if( ref( \$eRef{'root'} ) eq 'SCALAR') {
				$epilog->{'root'} = [ $eRef{'root'} ];
				$epilog->{'ends'}[0] = $eRef{'ends'}{ $case };
			}
			else { # if( ref( $eRef{'root'} ) eq 'ARRAY') # a lot of words in the epilogue
				$epilog->{'root'} = $eRef{'root'};
				$epilog->{'ends'} = $eRef{'ends'}{ $case };
			}
		}
		else {
			$epilog = {};
		}

	}
	elsif( ref($epilog) eq 'HASH' and exists $epilog->{'root'} and exists $epilog->{'ends'} ) {
		if( defined $epilog->{'object'} ) {
			$$object = $epilog->{'object'}=~/^\s*[a1-9]/i ? 'animate' : 'inanimate';
		}

		$$gender = @{{'m'=>'masculine', 'f'=>'feminine', 'n'=>'neuter'}}{lc $1}
			if defined( $epilog->{'gender'} ) && $epilog->{'gender'} =~/^\s*(m|f|n)/i;

	}
	else {
		$epilog = {};
	}

	return $epilog;
}

1;

__END__