File Coverage

blib/lib/Lingua/NLD/Word2Num.pm

Criterion	Covered	Total	%
statement	26	33	78.7
branch	0	10	0.0
condition	2	4	50.0
subroutine	9	10	90.0
pod	3	3	100.0
total	40	60	66.6

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8; -*-

package Lingua::NLD::Word2Num;
# ABSTRACT: Word to number conversion in Dutch

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Export::Attrs;
use Parse::RecDescent;

# }}}
# {{{ variable declarations
our $VERSION = '0.2603300';
my  $parser  = nld_numerals();

# }}}
# {{{ w2n                                         convert text to number

sub w2n :Export {
    my $input = shift // return;

    $input = lc $input;
    $input =~ s/,//g;
    $input =~ s/ //g;

    return $parser->numeral($input);
}

# }}}
# {{{ nld_numerals                                 create parser for numerals

sub nld_numerals {
    return Parse::RecDescent->new(q{
      numeral:
      numeral: million   { return $item[1]; }                         # root parse. go from maximum to minimum value
        |      millenium { return $item[1]; }
        |      century   { return $item[1]; }
        |      decade    { return $item[1]; }
        |                { return undef; }

      number: 'negentien'  { $return = 19; }                          # try to find a word from 0 to 19
        |     'achtien'    { $return = 18; }
        |     'zeventien'  { $return = 17; }
        |     'zestien'    { $return = 16; }
        |     'vijftien'   { $return = 15; }
        |     'veertien'   { $return = 14; }
        |     'dertien'    { $return = 13; }
        |     'twaalf'     { $return = 12; }
        |     'elf'        { $return = 11; }
        |     'tien'       { $return = 10; }
        |     'negen'      { $return = 9; }
        |     'acht'       { $return = 8; }
        |     'zeven'      { $return = 7; }
        |     'zes'        { $return = 6; }
        |     'vijf'       { $return = 5; }
        |     'vier'       { $return = 4; }
        |     'drie'       { $return = 3; }
        |     'twee'       { $return = 2; }
        |     /(een|één)/        { $return = 1; }
        |     'nul'        { $return = 0; }

      tens:   'twintig'  { $return = 20; }                            # try to find a word that represents
        |     'dertig'   { $return = 30; }                            # values 20,30,..,90
        |     'veertig'  { $return = 40; }
        |     'vijftig'  { $return = 50; }
        |     'zestig'   { $return = 60; }
        |     'zeventig' { $return = 70; }
        |     'tachtig'  { $return = 80; }
        |     'negentig' { $return = 90; }

      decade: number(?) 'en' tens(?) number(?)                        # try to find words that represents values
              { $return = 0;                                          # from 0 to 99
                for (@item) {
                  $return += $$_[0] if (ref $_ && defined $$_[0]);
                }
              }
        |     tens(?) number(?)
              { $return = -1;
                for (@item) {
                  if (ref $_ && defined $$_[0]) {
                    $return += $$_[0] if ($return != -1);
                    $return  = $$_[0] if ($return == -1);
                  }
                }
                $return = undef if ($return == -1);
              }

      century: number(?) 'honderd' decade(?)                          # try to find words that represents values
               { $return = 0;                                         # from 100 to 999
                 for (@item) {
                   if (ref $_ && defined $$_[0]) {
                     $return += $$_[0];
                   } elsif ($_ eq "honderd") {
                     $return = ($return>0) ? $return * 100 : 100;
                   }
                 }
                 $return ||= undef;
               }

    millenium: century(?) decade(?) 'duizend' century(?) decade(?)    # try to find words that represents values
               { $return = 0;                                         # from 1.000 to 999.999
                 for (@item) {
                   if (ref $_ && defined $$_[0]) {
                     $return += $$_[0];
                   } elsif ($_ eq "duizend") {
                     $return = ($return>0) ? $return * 1000 : 1000;
                   }
                 }
                 $return ||= undef;
               }

      million: millenium(?) century(?) decade(?)                      # try to find words that represents values
               'miljoen'                                              # from 1.000.000 to 999.999.999.999
               millenium(?) century(?) decade(?)
               { $return = 0;
                 for (@item) {
                   if (ref $_ && defined $$_[0]) {
                     $return += $$_[0];
                   } elsif ($_ eq "miljoen") {
                     $return = ($return>0) ? $return * 1000000 : 1000000;
                   }
                 }
                 $return ||= undef;
               }
    });
}

# }}}
# {{{ ordinal2cardinal          convert ordinal text to cardinal text

sub ordinal2cardinal :Export {
    my $input = shift // return;

    # Inverse of Dutch ordinal morphology: restore cardinal from ordinal text.
    # Irregulars (standalone or as final element of compound)
    $input =~ s{eerste\z}{een}xms     and return $input;
    $input =~ s{tweede\z}{twee}xms    and return $input;
    $input =~ s{derde\z}{drie}xms     and return $input;

    # Regular: strip -ste (20+ and compounds ending in tens/honderd/duizend)
    $input =~ s{ste\z}{}xms           and return $input;

    # Regular: strip -de (4-19)
    $input =~ s{de\z}{}xms            and return $input;

    return;  # not an ordinal
}

# }}}

1;

__END__