File Coverage

blib/lib/Lingua/NLD/Word2Num.pm

Criterion	Covered	Total	%
statement	24	24	100.0
branch			n/a
condition	2	2	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	36	36	100.0

# For Emacs: -*- mode:cperl; mode:folding; coding:utf-8; -*-

package Lingua::NLD::Word2Num;
# ABSTRACT: Word 2 number conversion in NLD.

# {{{ use block

use 5.10.1;

use strict;
use warnings;

use Perl6::Export::Attrs;
use Parse::RecDescent;

# }}}
# {{{ variable declarations

our $VERSION = 0.0682;
my  $parser  = nld_numerals();

# }}}
# {{{ w2n                                         convert number to text

sub w2n :Export {
    my $input = shift // return;

    $input = lc $input;
    $input =~ s/,//g;
    $input =~ s/ //g;

    return $parser->numeral($input);
}

# }}}
# {{{ nld_numerals                                 create parser for numerals

sub nld_numerals {
    return Parse::RecDescent->new(q{
      numeral:
      numeral: million   { return $item[1]; }                         # root parse. go from maximum to minimum value
        |      millenium { return $item[1]; }
        |      century   { return $item[1]; }
        |      decade    { return $item[1]; }
        |                { return undef; }

      number: 'negentien'  { $return = 19; }                          # try to find a word from 0 to 19
        |     'achtien'    { $return = 18; }
        |     'zeventien'  { $return = 17; }
        |     'zestien'    { $return = 16; }
        |     'vijftien'   { $return = 15; }
        |     'veertien'   { $return = 14; }
        |     'dertien'    { $return = 13; }
        |     'twaalf'     { $return = 12; }
        |     'elf'        { $return = 11; }
        |     'tien'       { $return = 10; }
        |     'negen'      { $return = 9; }
        |     'acht'       { $return = 8; }
        |     'zeven'      { $return = 7; }
        |     'zes'        { $return = 6; }
        |     'vijf'       { $return = 5; }
        |     'vier'       { $return = 4; }
        |     'drie'       { $return = 3; }
        |     'twee'       { $return = 2; }
        |     'een'        { $return = 1; }
        |     'nul'        { $return = 0; }

      tens:   'twintig'  { $return = 20; }                            # try to find a word that representates
        |     'dertig'   { $return = 30; }                            # values 20,30,..,90
        |     'veertig'  { $return = 40; }
        |     'vijftig'  { $return = 50; }
        |     'zestig'   { $return = 60; }
        |     'zeventig' { $return = 70; }
        |     'tachtig'  { $return = 80; }
        |     'negentig' { $return = 90; }

      decade: number(?) 'en' tens(?) number(?)                        # try to find words that represents values
              { $return = 0;                                          # from 0 to 99
                for (@item) {
                  $return += $$_[0] if (ref $_ && defined $$_[0]);
                }
              }
        |     tens(?) number(?)
              { $return = -1;
                for (@item) {
                  if (ref $_ && defined $$_[0]) {
                    $return += $$_[0] if ($return != -1);
                    $return  = $$_[0] if ($return == -1);
                  }
                }
                $return = undef if ($return == -1);
              }

      century: number(?) 'honderd' decade(?)                          # try to find words that represents values
               { $return = 0;                                         # from 100 to 999
                 for (@item) {
                   if (ref $_ && defined $$_[0]) {
                     $return += $$_[0];
                   } elsif ($_ eq "honderd") {
                     $return = ($return>0) ? $return * 100 : 100;
                   }
                 }
                 $return ||= undef;
               }

    millenium: century(?) decade(?) 'duizend' century(?) decade(?)    # try to find words that represents values
               { $return = 0;                                         # from 1.000 to 999.999
                 for (@item) {
                   if (ref $_ && defined $$_[0]) {
                     $return += $$_[0];
                   } elsif ($_ eq "duizend") {
                     $return = ($return>0) ? $return * 1000 : 1000;
                   }
                 }
                 $return ||= undef;
               }

      million: millenium(?) century(?) decade(?)                      # try to find words that represents values
               'miljard'                                              # from 1.000.000 to 999.999.999.999
               millenium(?) century(?) decade(?)
               { $return = 0;
                 for (@item) {
                   if (ref $_ && defined $$_[0]) {
                     $return += $$_[0];
                   } elsif ($_ eq "miljard") {
                     $return = ($return>0) ? $return * 1000000 : 1000000;
                   }
                 }
                 $return ||= undef;
               }
    });
}

# }}}

1;

__END__