File Coverage

blib/lib/Lingua/KAZ/Word2Num.pm

Criterion	Covered	Total	%
statement	23	38	60.5
branch	0	6	0.0
condition	2	4	50.0
subroutine	9	11	81.8
pod	4	4	100.0
total	38	63	60.3

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-
package Lingua::KAZ::Word2Num;
# ABSTRACT: Word to number conversion in Kazakh

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Export::Attrs;
use Parse::RecDescent;

# }}}
# {{{ var block
our $VERSION = '0.2603300';
my $parser   = kaz_numerals();

# }}}

# {{{ w2n                       convert text to number

sub w2n :Export {
    my $input = shift // return;

    return $parser->numeral($input);
}

# }}}
# {{{ kaz_numerals              create parser for kazakh numerals

sub kaz_numerals {
    return Parse::RecDescent->new(q{


      numeral:      mega
                  | kOhOd
                  | { }

      number:       'нөл'     {  0 }
                  | 'бір'     {  1 }
                  | 'екі'     {  2 }
                  | 'үш'      {  3 }
                  | 'төрт'    {  4 }
                  | 'бес'     {  5 }
                  | 'алты'    {  6 }
                  | 'жеті'    {  7 }
                  | 'сегіз'   {  8 }
                  | 'тоғыз'   {  9 }

      tens:         'он'        { 10 }
                  | 'жиырма'    { 20 }
                  | 'отыз'      { 30 }
                  | 'қырық'     { 40 }
                  | 'елу'       { 50 }
                  | 'алпыс'     { 60 }
                  | 'жетпіс'    { 70 }
                  | 'сексен'    { 80 }
                  | 'тоқсан'    { 90 }

      deca:         tens number          { $item[1] + $item[2] }
                  | tens
                  | number

      hecto:        number 'жүз' deca    { $item[1] * 100 + $item[3] }
                  | number 'жүз'         { $item[1] * 100            }
                  | 'жүз' deca           { 100 + $item[2]            }
                  | 'жүз'               { 100                       }

      hOd:        hecto
                | deca

      kilo:       hOd 'мың' hOd    { $item[1] * 1000 + $item[3] }
                | hOd 'мың'        { $item[1] * 1000            }
                | 'мың' hOd        { 1000 + $item[2]            }
                | 'мың'            { 1000                       }

      kOhOd:      kilo
                | hOd

      mega:       hOd 'миллион' kOhOd { $item[1] * 1_000_000 + $item[3] }
                | hOd 'миллион'       { $item[1] * 1_000_000 }
    });
}

# }}}

# {{{ capabilities              declare supported features

sub capabilities {
    return {
        w2n => 1,
    };
}

# }}}
# {{{ ordinal2cardinal            convert ordinal text to cardinal text

sub ordinal2cardinal :Export {
    my $input = shift // return;

    # Known cardinal words (from parser vocabulary).
    state $cardinals = { map { $_ => 1 } qw(
        нөл бір екі үш төрт бес алты жеті сегіз тоғыз
        он жиырма отыз қырық елу алпыс жетпіс сексен тоқсан
        жүз мың миллион
    )};

    # Kazakh ordinal suffixes (Cyrillic, 2-way vowel harmony).
    # After vowel-final stem:     -ншы  (back) -нші  (front)
    # After consonant-final stem: -ыншы (back) -інші (front)
    my @harmony = (
        [ 'ншы', 'ыншы' ],
        [ 'нші', 'інші' ],
    );

    for my $pair (@harmony) {
        my ($short, $long) = @{$pair};

        for my $suffix ($long, $short) {
            next unless $input =~ /\Q$suffix\E\z/xms;
            my $candidate = $input =~ s/\Q$suffix\E\z//xmsr;
            next unless length $candidate;

            my ($last_word) = $candidate =~ /(\S+)\z/xms;
            return $candidate if exists $cardinals->{$last_word};
        }
    }

    return;  # not an ordinal
}

# }}}

1;

__END__