File Coverage

blib/lib/Lingua/FAS/Num2Word.pm

Criterion	Covered	Total	%
statement	27	49	55.1
branch	2	26	7.6
condition	3	9	33.3
subroutine	8	9	88.8
pod	2	2	100.0
total	42	95	44.2

# For Emacs: -*- mode:cperl; eval: (folding-mode 1); coding:utf-8 -*-

package Lingua::FAS::Num2Word;
# ABSTRACT: Number to word conversion in Persian

use 5.16.0;
use utf8;
use warnings;

# {{{ use block

use Carp;
use Export::Attrs;
use Readonly;

# }}}
# {{{ variable declarations

my Readonly::Scalar $COPY = 'Copyright (c) PetaMem, s.r.o. 2002-present';
our $VERSION = '0.2603300';

# }}}

# {{{ num2fas_cardinal                 convert number to text

sub num2fas_cardinal :Export {
    my $positive = shift;

    croak 'You should specify a number from interval [0, 999_999_999]'
        if    !defined $positive
           || $positive !~ m{\A\d+\z}xms
           || $positive < 0
           || $positive > 999_999_999;

    my @ones = ('صفر', 'یک', 'دو', 'سه', 'چهار', 'پنج', 'شش', 'هفت', 'هشت', 'نه');
    my @teens = ('ده', 'یازده', 'دوازده', 'سیزده', 'چهارده', 'پانزده',
                 'شانزده', 'هفده', 'هجده', 'نوزده');
    my @tens = ('بیست', 'سی', 'چهل', 'پنجاه', 'شصت', 'هفتاد', 'هشتاد', 'نود');
    my @hundreds = ('صد', 'دویست', 'سیصد', 'چهارصد', 'پانصد',
                    'ششصد', 'هفتصد', 'هشتصد', 'نهصد');

    # 0 .. 9
    return $ones[$positive] if $positive < 10;

    # 10 .. 19
    return $teens[$positive - 10] if $positive < 20;

    # 20 .. 99
    if ($positive < 100) {
        my $ten_idx = int($positive / 10) - 2;
        my $remain  = $positive % 10;

        return $tens[$ten_idx] if $remain == 0;
        return $tens[$ten_idx] . ' و ' . $ones[$remain];
    }

    my $out;
    my $remain;

    # 100 .. 999
    if ($positive < 1000) {
        my $hun_idx = int($positive / 100) - 1;
        $remain     = $positive % 100;

        $out  = $hundreds[$hun_idx];
        $out .= $remain ? ' و ' . num2fas_cardinal($remain) : '';
    }
    # 1000 .. 999_999
    elsif ($positive < 1_000_000) {
        my $tho_idx = int($positive / 1000);
        $remain     = $positive % 1000;

        $out  = $tho_idx == 1 ? 'هزار' : num2fas_cardinal($tho_idx) . ' هزار';
        $out .= $remain ? ' و ' . num2fas_cardinal($remain) : '';
    }
    # 1_000_000 .. 999_999_999
    elsif ($positive < 1_000_000_000) {
        my $mil_idx = int($positive / 1_000_000);
        $remain     = $positive % 1_000_000;

        $out  = $mil_idx == 1 ? 'یک میلیون' : num2fas_cardinal($mil_idx) . ' میلیون';
        $out .= $remain ? ' و ' . num2fas_cardinal($remain) : '';
    }

    return $out;
}

# }}}


# {{{ capabilities              declare supported features

sub capabilities {
    return {
        cardinal => 1,
        ordinal  => 0,
    };
}

# }}}
1;

__END__