File Coverage

blib/lib/Lingua/JBO/Numbers.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	14	16	87.5
condition	5	6	83.3
subroutine	8	8	100.0
pod	2	2	100.0
total	65	68	95.5

package Lingua::JBO::Numbers;

use 5.008_001;
use strict;
use warnings;
use Readonly;
use Regexp::Common qw( number );

use base qw( Exporter );
our @EXPORT_OK = qw( num2jbo num2jbo_ordinal );
our %EXPORT_TAGS = ( all => \@EXPORT_OK );

our $VERSION = '0.03';

Readonly my $EMPTY_STR      => q{};
Readonly my $ORDINAL_SUFFIX => q{moi};

Readonly my @NAMES => qw< no pa re ci vo mu xa ze bi so >;
Readonly my %WORDS => (
    '.' => "pi",
    ',' => "ki'o",
    '-' => "ni'u",
    '+' => "ma'u",
    inf => "ci'i",
    NaN => "na namcu",
);

sub num2jbo {
    my ($number) = @_;
    my @names;

    return unless defined $number;
    return $WORDS{NaN} if $number eq 'NaN';

    if ($number =~ m/^ ( [-+] )? inf $/ix) {
        # infinity
        push @names, $1 ? $WORDS{$1} : (), $WORDS{inf};
    }
    elsif ($number =~ m/^ $RE{num}{real}{-keep} $/x) {
        my ($sign, $int, $frac) = ($2, $4, $6);

        # sign and integer
        push @names, (
            $WORDS{$sign} || (),
            map { $NAMES[$_] } split $EMPTY_STR, defined $int ? $int : $EMPTY_STR,
        );

        # fraction
        if (defined $frac && $frac ne $EMPTY_STR) {
            push @names, (
                $WORDS{'.'},
                map { $NAMES[$_] } split $EMPTY_STR, $frac,
            );
        }
    }
    else {
        return;
    }

    return join $EMPTY_STR, @names;
}

sub num2jbo_ordinal {
    my ($number) = @_;
    my $name = num2jbo($number);

    return unless defined $name;
    return $name . $ORDINAL_SUFFIX;
}

1;

__END__