File Coverage

blib/lib/LINE/Bot/Audience.pm

Criterion	Covered	Total	%
statement	93	93	100.0
branch			n/a
condition	12	14	85.7
subroutine	26	26	100.0
pod	0	11	0.0
total	131	144	90.9

package LINE::Bot::Audience;
use strict;
use warnings;

use LINE::Bot::API::Client;
use LINE::Bot::API::Response::Common;
use LINE::Bot::API::Response::AudienceMultipleData;
use LINE::Bot::API::Response::AudienceData;
use LINE::Bot::API::Response::AudienceGroupForUploadingUserId;
use LINE::Bot::API::Response::AudienceGroupForClickRetargeting;
use LINE::Bot::API::Response::AudienceGroupForImpressionRetargeting;
use LINE::Bot::API::Response::AudienceAuthorityLevel;

use constant {
    DEFAULT_MESSAGING_API_ENDPOINT => 'https://api.line.me/v2/bot/',
};
use Furl;
use Carp 'croak';
use URI;
use URI::QueryParam;

sub new {
    my($class, %args) = @_;

    my $client = LINE::Bot::API::Client->new(%args);
    bless {
        client               => $client,
        channel_secret       => $args{channel_secret},
        channel_access_token => $args{channel_access_token},
        messaging_api_endpoint => $args{messaging_api_endpoint} // DEFAULT_MESSAGING_API_ENDPOINT,
    }, $class;
}

sub request {
    my ($self, $method, $path, @payload) = @_;

    return $self->{client}->$method(
        $self->{messaging_api_endpoint} .  $path,
        @payload,
    );
}

sub rename_audience {
    my ($self, $opts) = @_;

    my $res = $self->request(post => 'audienceGroup/'. $opts->{audience_group_id} . '/updateDescription', +{
        'description' => $opts->{description},
    });

    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub create_audience_for_uploading {
    my ($self, $opts) = @_;

    my $res = $self->request(post => 'audienceGroup/upload', +{
        'description' => $opts->{description},
        'isIfaAudience' => $opts->{isIfaAudience},
        'uploadDescription' => $opts->{uploadDescription},
        'audiences' => $opts->{audiences},
    });
    LINE::Bot::API::Response::AudienceGroupForUploadingUserId->new(%{ $res });
}

sub create_audience_for_click_based_retartgeting {
    my ($self, $opts) = @_;

    my $res = $self->request(post => 'audienceGroup/click', +{
        'description' => $opts->{description},
        'requestId' => $opts->{requestId},
        'clickUrl' => $opts->{clickUrl},
    });
    LINE::Bot::API::Response::AudienceGroupForClickRetargeting->new(%{ $res });
}

sub create_audience_for_impression_based_retargeting {
    my ($self, $opts) = @_;

    my $res = $self->request(post => 'audienceGroup/imp', +{
        'description' => $opts->{description},
        'requestId' => $opts->{requestId},
    });
    LINE::Bot::API::Response::AudienceGroupForImpressionRetargeting->new(%{ $res });
}

sub get_audience_data {
    my ($self, $opts) = @_;

    my $res = $self->request(get => 'audienceGroup/' . $opts->{audienceGroupId}, +{});
    LINE::Bot::API::Response::AudienceData->new(%{ $res });
}

sub update_authority_level {
    my ($self, $opts) = @_;

    my $res = $self->request(put => 'audienceGroup/authorityLevel', +{
        'authorityLevel' => $opts->{authorityLevel},
    });
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub delete_audience {
    my ($self, $ops) = @_;

    my $res = $self->request(delete => 'audienceGroup/' . $ops->{audienceGroupId}, +{});
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub get_authority_level {
    my ($self) = @_;

    my $res = $self->request(get => 'audienceGroup/authorityLevel', +{});
    LINE::Bot::API::Response::AudienceAuthorityLevel->new(%{ $res });
}

sub get_data_for_multiple_audience {
    my ($self, $opts) = @_;

    my $uri = URI->new('audienceGroup/list');
    $uri->query_param(page => $opts->{page} // 1);
    $uri->query_param(description => $opts->{description} // '');
    $uri->query_param(status => $opts->{status} // '');
    $uri->query_param(size => $opts->{size} // 20);
    $uri->query_param(includesExternalPublicGroups => $opts->{includesExternalPublicGroups} // '');
    $uri->query_param(createRoute => $opts->{createRoute} // '');

    my $res = $self->request(get => $uri->as_string);
    LINE::Bot::API::Response::AudienceMultipleData->new(%{ $res });
}

1;
__END__