File Coverage

blib/lib/LINE/Bot/API.pm

Criterion	Covered	Total	%
statement	265	289	91.7
branch	15	24	62.5
condition	7	14	50.0
subroutine	70	74	94.5
pod	42	47	89.3
total	399	448	89.0

package LINE::Bot::API;
use strict;
use warnings;
our $VERSION = '1.19';

use LINE::Bot::API::Builder::SendMessage;
use LINE::Bot::API::Client;
use LINE::Bot::API::Event;
use LINE::Bot::API::Response::Common;
use LINE::Bot::API::Response::Content;
use LINE::Bot::API::Response::Count;
use LINE::Bot::API::Response::FriendDemographics;
use LINE::Bot::API::Response::NumberOfSentMessages;
use LINE::Bot::API::Response::NumberOfMessageDeliveries;
use LINE::Bot::API::Response::Profile;
use LINE::Bot::API::Response::GroupMemberProfile;
use LINE::Bot::API::Response::GroupSummary;
use LINE::Bot::API::Response::RoomMemberProfile;
use LINE::Bot::API::Response::IssueLinkToken;
use LINE::Bot::API::Response::RichMenu;
use LINE::Bot::API::Response::RichMenuList;
use LINE::Bot::API::Response::TargetLimit;
use LINE::Bot::API::Response::TotalUsage;
use LINE::Bot::API::Response::Token;
use LINE::Bot::API::Response::NumberOfFollowers;
use LINE::Bot::API::Response::UserInteractionStatistics;

use constant {
    DEFAULT_MESSAGING_API_ENDPOINT => 'https://api.line.me/v2/bot/',
    DEFAULT_SOCIAL_API_ENDPOINT    => 'https://api.line.me/v2/oauth/',
    DEFAULT_CONTENT_API_ENDPOINT   => 'https://api-data.line.me/v2/bot/',
    DEFAULT_OAUTH2_API_ENDPOINT    => 'https://api.line.me/oauth2/v2.1/',
};
use Furl;
use Carp 'croak';
use URI::Escape;

sub new {
    my($class, %args) = @_;

    my $client = LINE::Bot::API::Client->new(%args);

    bless {
        client               => $client,
        channel_secret       => $args{channel_secret},
        channel_access_token => $args{channel_access_token},
        messaging_api_endpoint => $args{messaging_api_endpoint} // DEFAULT_MESSAGING_API_ENDPOINT,
        social_api_endpoint    => $args{social_api_endpoint} // DEFAULT_SOCIAL_API_ENDPOINT,
        content_api_endpoint => $args{content_api_endpoint} // DEFAULT_CONTENT_API_ENDPOINT,
        oauth_api_endpoint => $args{oauth_api_endpoint} // DEFAULT_OAUTH2_API_ENDPOINT,
    }, $class;
}

sub request {
    my ($self, $method, $path, @payload) = @_;

    return $self->{client}->$method(
        $self->{messaging_api_endpoint} .  $path,
        @payload,
    );
}

sub request_content {
    my ($self, $method, $path, @payload) = @_;

    return $self->{client}->$method(
        $self->{content_api_endpoint} .  $path,
        @payload,
    );
}

sub reply_message {
    my($self, $reply_token, $messages) = @_;

    my $res = $self->request(
        post => 'message/reply',
        +{
            replyToken => $reply_token,
            messages   => $messages,
        }
    );

    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub push_message {
    my($self, $to_id, $messages, $options) = @_;

    my @headers = ();
    if ($options && defined($options->{'retry_key'})) {
        push @headers, 'X-Line-Retry-Key' => $options->{'retry_key'};
    }

    my $res = $self->request(
        post => 'message/push',
        \@headers,
        +{
            to       => $to_id,
            messages => $messages,
        }
    );
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub multicast {
    my($self, $to_ids, $messages, $options) = @_;

    my @headers = ();
    if ($options && defined($options->{'retry_key'})) {
        push @headers, 'X-Line-Retry-Key' => $options->{'retry_key'};
    }

    my $res = $self->request(
        post => 'message/multicast',
        \@headers,
        +{
            to       => $to_ids,
            messages => $messages,
        }
    );
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub broadcast {
    my($self, $messages, $options) = @_;

    my @headers = ();
    if (defined($options->{'retry_key'})) {
        push @headers, 'X-Line-Retry-Key' => $options->{'retry_key'};
    }

    my $res = $self->request(
        post => 'message/broadcast',
        \@headers,
        +{
            messages => $messages,
        }
    );
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub get_message_content {
    my($self, $message_id, %options) = @_;
    my $res = $self->request_content(
        'contents_download' => "message/$message_id/content",
        %options
    );
    LINE::Bot::API::Response::Content->new(%{ $res });
}

sub get_profile {
    my($self, $user_id) = @_;
    my $res = $self->request(get => "profile/$user_id");
    LINE::Bot::API::Response::Profile->new(%{ $res });
}

sub get_group_member_profile {
    my($self, $group_id, $user_id) = @_;
    my $res = $self->request(get => "group/$group_id/member/$user_id");
    LINE::Bot::API::Response::GroupMemberProfile->new(%{ $res });
}

sub get_room_member_profile {
    my($self, $room_id, $user_id) = @_;
    my $res = $self->request(get => "room/$room_id/member/$user_id");
    LINE::Bot::API::Response::RoomMemberProfile->new(%{ $res });
}

sub leave_room {
    my($self, $room_id) = @_;
    my $res = $self->request(post => "room/$room_id/leave", +{});
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub leave_group {
    my($self, $group_id) = @_;
    my $res = $self->request(post => "group/$group_id/leave", +{});
    LINE::Bot::API::Response::Common->new(%{ $res });
}

sub get_friend_demographics {
    my($self) = @_;
    my $res = $self->request(get => "insight/demographic");
    LINE::Bot::API::Response::FriendDemographics->new(%{ $res });
}

sub get_target_limit_for_additional_messages {
    my($self, $date) = @_;
    my $res = $self->request(get => "message/quota");
    LINE::Bot::API::Response::TargetLimit->new(%{ $res });
}

sub get_number_of_messages_sent_this_month {
    my($self, $date) = @_;
    my $res = $self->request(get => "message/quota/consumption");
    LINE::Bot::API::Response::TotalUsage->new(%{ $res });
}

sub get_number_of_sent_reply_messages {
    my($self, $date) = @_;
    my $res = $self->request(get => "message/delivery/reply?date=${date}");
    LINE::Bot::API::Response::NumberOfSentMessages->new(%{ $res });
}

sub get_number_of_sent_push_messages {
    my($self, $date) = @_;
    my $res = $self->request(get => "message/delivery/push?date=${date}", +{});
    LINE::Bot::API::Response::NumberOfSentMessages->new(%{ $res });
}

sub get_number_of_sent_multicast_messages {
    my($self, $date) = @_;
    my $res = $self->request(get => "message/delivery/multicast?date=${date}", +{});
    LINE::Bot::API::Response::NumberOfSentMessages->new(%{ $res });
}

sub get_number_of_send_broadcast_messages {
    my($self, $date) = @_;
    my $res = $self->request(get => "message/delivery/broadcast?date=${date}", +{});
    LINE::Bot::API::Response::NumberOfSentMessages->new(%{ $res });
}

sub get_number_of_message_deliveries {
    my($self, $opts) = @_;
    my $date = $opts->{date} or croak "get_number_of_message_deliveries: Missing a `date` parameter.";

    my $res = $self->request(get => "insight/message/delivery?date=${date}", +{});
    LINE::Bot::API::Response::NumberOfMessageDeliveries->new(%{ $res });
}

sub get_member_in_room_count {
    my ($self, $room_id) = @_;

    my $res = $self->request(get => "room/${room_id}/members/count", +{});
    LINE::Bot::API::Response::Count->new(%{ $res });
}

sub get_member_in_group_count {
    my ($self, $group_id) = @_;

    my $res = $self->request(get => "group/${group_id}/members/count", +{});
    LINE::Bot::API::Response::Count->new(%{ $res });
}

sub get_group_summary {
    my ($self, $group_id) = @_;

    my $res = $self->request(get => "group/${group_id}/summary", +{});
    LINE::Bot::API::Response::GroupSummary->new(%{ $res });
}

sub validate_signature {
    my($self, $json, $signature) = @_;
    LINE::Bot::API::Event->validate_signature($json, $self->{channel_secret}, $signature);
}

sub parse_events_from_json {
    my($self, $json) = @_;
    LINE::Bot::API::Event->parse_events_json($json);
}

sub issue_link_token {
    my($self, $user_id) = @_;
    my $res = $self->request(post => "user/${user_id}/linkToken", +{});
    LINE::Bot::API::Response::IssueLinkToken->new(%{ $res });
}

sub create_rich_menu {
    my ($self, $rich_menu) = @_;
    my $res = $self->request(post => "richmenu", $rich_menu);
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub get_rich_menu {
    my ($self, $rich_menu_id) = @_;
    my $res = $self->request(get => "richmenu/${rich_menu_id}");
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub delete_rich_menu {
    my ($self, $rich_menu_id) = @_;
    my $res = $self->request(delete => "richmenu/${rich_menu_id}");
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub get_rich_menu_list {
    my ($self) = @_;
    my $res = $self->request(get => "richmenu/list");
    LINE::Bot::API::Response::RichMenuList->new(%{ $res });
}

sub set_default_rich_menu {
    my ($self, $rich_menu_id) = @_;
    my $res = $self->request(post => "user/all/richmenu/${rich_menu_id}", +{});
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub get_default_rich_menu_id {
    my ($self) = @_;
    my $res = $self->request(get => "user/all/richmenu");
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub cancel_default_rich_menu {
    my ($self) = @_;
    my $res = $self->request(delete => "user/all/richmenu");
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub link_rich_menu_to_user {
    my ($self, $user_id, $rich_menu_id) = @_;
    my $res = $self->request(post => "user/${user_id}/richmenu/${rich_menu_id}", +{});
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub link_rich_menu_to_multiple_users {
    my ($self, $user_ids, $rich_menu_id) = @_;
    my $res = $self->request(post => "richmenu/bulk/link", +{
        richMenuId => $rich_menu_id,
        userIds => $user_ids,
    });
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub get_rich_menu_id_of_user {
    my ($self, $user_id, $rich_menu_id) = @_;
    my $res = $self->request(get => "user/${user_id}/richmenu");
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub unlink_rich_menu_from_user {
    my ($self, $user_id) = @_;
    my $res = $self->request(delete => "user/${user_id}/richmenu");
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub unlink_rich_menu_from_multiple_users {
    my ($self, $user_ids) = @_;
    my $res = $self->request(post => "richmenu/bulk/unlink", +{
        userIds => $user_ids,
    });
    LINE::Bot::API::Response::RichMenu->new(%{ $res });
}

sub upload_rich_menu_image {
    my ($self, $rich_menu_id, $content_type, $file_path) = @_;

    if (!$content_type) {
        croak 'Need content_type';
    }

    my $res = $self->{client}->post_image(
        $self->{content_api_endpoint} . "richmenu/$rich_menu_id/content",
        [
            'Content-Type' => $content_type,
        ],
        $file_path
    );

    if ($res->{http_status} eq '200') {
        return LINE::Bot::API::Response::Token->new(%{ $res });
    } else {
        return LINE::Bot::API::Response::Error->new(%{ $res });
    }

}

sub download_rich_menu_image {
    my ($self, $rich_menu_id) = @_;

    return $self->{client}->get_content(
        $self->{content_api_endpoint} . "richmenu/$rich_menu_id/content"
    );
}

sub issue_channel_access_token {
    my ($self, $opts) = @_;

    my $res = $self->{client}->post_form(
        $self->{social_api_endpoint} . 'accessToken',
        [
            grant_type    => 'client_credentials',
            client_id     => $opts->{client_id},
            client_secret => $opts->{client_secret},
        ]
    );

    if ($res->{http_status} eq '200') {
        return LINE::Bot::API::Response::Token->new(%{ $res });
    } else {
        return LINE::Bot::API::Response::Error->new(%{ $res });
    }
}

sub issue_channel_access_token_v2_1 {
    my ($self, $opts) = @_;

    my $res = $self->{client}->post_form(
        $self->{oauth_api_endpoint} . 'token',
        undef,
        [
            grant_type              => 'client_credentials',
            client_assertion_type   => 'urn:ietf:params:oauth:client-assertion-type:jwt-bearer',
            client_assertion        => $opts->{jwt},
        ]
    );

    if ($res->{http_status} eq '200') {
        return LINE::Bot::API::Response::Token->new(%{ $res });
    } else {
        return LINE::Bot::API::Response::Error->new(%{ $res });
    }
}

sub get_valid_channel_access_token_v2_1 {
    my ($self, $opts) = @_;

    my $jwt = uri_escape($opts->{jwt});
    my $assertion_type = uri_escape('urn:ietf:params:oauth:client-assertion-type:jwt-bearer');

    my $res = $self->{client}->get(
        $self->{oauth_api_endpoint} . 'tokens/kid' . "?client_assertion_type=$assertion_type&client_assertion=$jwt",
    );

    if ($res->{http_status} eq '200') {
        return LINE::Bot::API::Response::Token->new(%{ $res });
    } else {
        return LINE::Bot::API::Response::Error->new(%{ $res });
    }
}

sub revoke_channel_access_token {
    my ($self, $opts) = @_;

    my $res = $self->{client}->post_form(
        $self->{social_api_endpoint} . 'revoke',
        [
            access_token => $opts->{access_token},
        ]
    );

    if ($res->{http_status} eq '200') {
        return LINE::Bot::API::Response::Common->new(%{ $res });
    } else {
        return LINE::Bot::API::Response::Error->new(%{ $res });
    }
}

sub get_number_of_followers {
    my ($self, $opts) = @_;
    my $date = $opts->{date} or croak "get_number_of_followers: Missing a `date` parameter.";

    my $res = $self->request(get => "insight/followers?date=${date}");
    LINE::Bot::API::Response::NumberOfFollowers->new(%{ $res });
}

sub get_user_interaction_statistics {
    my ($self, $opts) = @_;
    my $requestId = $opts->{requestId} or croak "get_user_interaction_statistics: Missing a `requestId` parameter.";

    my $res = $self->request(get => "insight/message/event?requestId=${requestId}");
    LINE::Bot::API::Response::UserInteractionStatistics->new(%{ $res });
}

1;
__END__