File Coverage

blib/lib/Klonk/Env.pm

Criterion	Covered	Total	%
statement	9	68	13.2
branch	0	34	0.0
condition	0	10	0.0
subroutine	3	9	33.3
pod	4	4	100.0
total	16	125	12.8

package Klonk::Env 0.01;
use Klonk::pragma;
use Unicode::UTF8 qw(decode_utf8);

use constant {
    MAX_FORM_BODY_SIZE => 10 * 1024 * 1024,
};

fun _parse_query($query_string) {
    my %param;
    for my $kv (split /&/, $query_string) {
        my ($k, $v) = split /=/, $kv, 2;
        for ($k, $v) {
            defined or next;
            tr/+/ /;
            s/%([[:xdigit:]]{2})/chr hex $1/eg;
            $_ = decode_utf8 $_;
        }
        $param{$k} = $v;
    }
    \%param
}

method new($class: $env) {
    my $qparam = _parse_query $env->{QUERY_STRING};

    my $bparam = {};
    {
        my $verb = $env->{REQUEST_METHOD};
        if ($verb eq 'POST' || $verb eq 'PUT' || $verb eq 'PATCH') {
            my $ctype = $env->{CONTENT_TYPE} // '';
            my $clength = $env->{CONTENT_LENGTH} // 0;
            $clength <= MAX_FORM_BODY_SIZE
                or die "Request size ($clength) exceeds maximum form size";
            if ($ctype eq 'application/x-www-form-urlencoded') {
                my $input = $env->{'psgi.input'};
                my $query = '';
                while ((my $d = $clength - length($query)) > 0) {
                    my $n = $input->read($query, $d, length($query))
                        and next;
                    defined $n
                        and die "Premature end of request body (received ${\length $query} of $clength bytes)";
                    die "Error while reading request body: $!";
                }
                $bparam = _parse_query $query;
            }
        }
    }

    bless {
        %$env,
        'klonk.qparam' => $qparam,
        'klonk.bparam' => $bparam,
    }, $class
}

method DESTROY(@) {}

method vpath($path) {
    $self->{SCRIPT_NAME} . '/' . $path =~ s!^/!!r
}

method qparam($k) {
    $self->{'klonk.qparam'}{$k}
}

method bparam($k) {
    $self->{'klonk.bparam'}{$k}
}

1
__END__