File Coverage

blib/lib/Keyword/Pluggable.pm

Criterion	Covered	Total	%
statement	47	52	90.3
branch	13	20	65.0
condition	11	15	73.3
subroutine	11	11	100.0
pod	2	2	100.0
total	84	100	84.0

package Keyword::Pluggable;

use v5.14.0;
use warnings;
our %kw;

use Carp qw(croak);

use XSLoader;
BEGIN {
	our $VERSION = '1.05';
	XSLoader::load __PACKAGE__, $VERSION;
}

my %modes = (
	'statement'  => MODE_STATEMENT,
	'expression' => MODE_EXPRESSION,
	'dynamic'    => MODE_DYNAMIC,
);

sub define {
	my %p = @_;
	my ($kw, $sub, $expression, $global, $package) = @p{qw(keyword code expression global package)};
	$kw =~ /^\p{XIDS}\p{XIDC}*\z/ or croak "'$kw' doesn't look like an identifier";
	defined($sub) or croak "'code' is not defined";
	$expression //= 'statement';
	my $sub_is_code = (ref($sub) and
	                   (UNIVERSAL::isa($sub, 'CODE') or
	                    $sub->isa('CODE')));
	$sub_is_code or $expression ne 'dynamic' or croak("expression=dynamic requires a coderef");

	my $xsub = $sub_is_code ? $sub : sub { substr ${$_[0]}, 0, 0, $sub };

	my $entry = [ $xsub,
	              ($modes{$expression} //
	               ($expression? MODE_EXPRESSION: MODE_STATEMENT)) ];

	if ( defined $package) {
		no strict 'refs';
		my $keywords = \%{$package . '::/keywords' };
		$keywords->{$kw} = $entry;
	} elsif ( $global ) {
		define_global($kw, $entry);
	} else {
		my %keywords = %{$^H{+HINTK_KEYWORDS} // {}};
		$keywords{$kw} = $entry;
		$^H{+HINTK_KEYWORDS} = \%keywords;
	}
}

sub undefine {
	my %p = @_;
	my ($kw, $global, $package) = @p{qw(keyword global package)};
	$kw =~ /^\p{XIDS}\p{XIDC}*\z/ or croak "'$kw' doesn't look like an identifier";

	if ( defined $package ) {
		no strict 'refs';
		my $keywords = \%{$package . '::/keywords' };
		delete $keywords->{$kw};
	} elsif ( $global ) {
		undefine_global($kw);
	} else {
		my %keywords = %{$^H{+HINTK_KEYWORDS} // {}};
		delete $keywords{$kw};
		$^H{+HINTK_KEYWORDS} = \%keywords;
	}
}

END { cleanup() }

'ok'

__END__