File Coverage

blib/lib/Jenkins/i18n/Stats.pm

Criterion	Covered	Total	%
statement	29	41	70.7
branch	5	6	83.3
condition			n/a
subroutine	8	11	72.7
pod	5	5	100.0
total	47	63	74.6

package Jenkins::i18n::Stats;

use 5.014004;
use strict;
use warnings;
use Hash::Util qw(lock_keys);
use Carp qw(confess);

our $VERSION = '0.08';

=pod

=head1 NAME

Jenkins::i18n::Stats - class to provide translations processing statistics

=head1 SYNOPSIS

  use Jenkins::i18n::Stats;

=head1 DESCRIPTION

C

=head2 EXPORT

None by default.

=head1 ATTRIBUTES

All attributes are counters.

=over

=item *

files: all the found translation files.

=item *

keys: all the keys loaded from the properties files.

=item *

missing: all keys that are missing after comparing a language to the original
in English,

=item *

unused: all keys that are available in the a language but not in the original
English.

=item *

empty: all keys in the language that are available but doesn't actually have a
translated value.

=item *

same: all keys that have the same values as the original in English. Not
necessarilly an error.

=item *

no_jenkins: all keys that are not related to Jenkins, but coming from Hudson.

=back

=head1 METHODS

=head2 new

Creates a new instance.

=cut

sub new {
    my $class = shift;
    my $self  = {
        files      => 0,
        keys       => 0,
        missing    => 0,
        unused     => 0,
        empty      => 0,
        same       => 0,
        no_jenkins => 0
    };

    bless $self, $class;
    lock_keys( %{$self} );
    return $self;
}

=head2 inc

Increments a counter.

=cut

sub inc {
    my ( $self, $item ) = @_;
    confess "item is a required parameter" unless ($item);
    confess "there is no such counter '$item'"
        unless ( exists( $self->{$item} ) );
    $self->{$item}++;
    return 1;
}

sub _done {
    my $self = shift;
    return (  $self->{keys}
            - $self->{missing}
            - $self->{unused}
            - $self->{empty}
            - $self->{same}
            - $self->{no_jenkins} );
}

=head2 perc_done

Calculates how much of the translation is completed.

Requires no parameters.

Returns a float as the percentage of the translation that is completed.

=cut

sub perc_done {
    my $self = shift;
    return ( ( $self->_done / $self->{keys} ) * 100 );
}

=head2 summary

Returns a summary of all statistics in text format.

The summary is returned as a hash reference.

=cut

sub summary {
    my $self = shift;

    unless ( $self->{keys} == 0 ) {
        my %summary = ( done => $self->_done, pdone => $self->perc_done );
        my @wanted  = qw(missing unused empty same no_jenkins);

        foreach my $wanted (@wanted) {
            $summary{$wanted} = $self->{$wanted};
            $summary{"p$wanted"} = $self->{$wanted} / $self->{keys} * 100;
        }

        return \%summary;

    }

    warn "Not a single key was processed\n";
    return {};
}

=head2 files

Getter for the C attribute.

=cut

sub files {
    my $self = shift;
    return $self->{files};
}

1;
__END__