File Coverage

blib/lib/JMAP/Tester/Response/Sentence.pm

Criterion	Covered	Total	%
statement	46	50	92.0
branch	5	6	83.3
condition			n/a
subroutine	11	12	91.6
pod	6	7	85.7
total	68	75	90.6

use v5.20.0;
package JMAP::Tester::Response::Sentence 0.110;
# ABSTRACT: a single triple within a JMAP response

use Moo;

use experimental 'signatures';

use namespace::clean;

#pod =head1 OVERVIEW
#pod
#pod These objects represent sentences in the JMAP response.  That is, if your
#pod response is:
#pod
#pod   [
#pod     [ "messages", { ... }, "a" ],      # 1
#pod     [ "smellUpdates", { ... }, "b" ],  # 2
#pod     [ "smells",       { ... }, "b" ],  # 3
#pod   ]
#pod
#pod ...then #1, #2, and #3 are each a single sentence.
#pod
#pod The first item in the triple is accessed with the C method.  The second
#pod is accessed with the C method.  The third, with the C
#pod method.
#pod
#pod =cut

has name      => (is => 'ro', required => 1);
has arguments => (is => 'ro', required => 1);
has client_id => (is => 'ro', required => 1);

has sentence_broker => (is => 'ro', required => 1);

sub _strip_json_types ($self, $whatever) {
  $self->sentence_broker->strip_json_types($whatever);
}

#pod =method as_triple
#pod
#pod =method as_stripped_triple
#pod
#pod C returns the underlying JSON data of the sentence, which may
#pod include objects used to convey type information for booleans, strings, and
#pod numbers.
#pod
#pod For unblessed data, use C.
#pod
#pod These return a three-element arrayref.
#pod
#pod =cut

sub as_triple ($self) { [ $self->name, $self->arguments, $self->client_id ] }

sub as_stripped_triple ($self) {
  $self->sentence_broker->strip_json_types($self->as_triple);
}

#pod =method as_pair
#pod
#pod =method as_stripped_pair
#pod
#pod C returns the same thing as C, but without the
#pod C.  That means it returns a two-element arrayref.
#pod
#pod C returns the same minus JSON type information.
#pod
#pod =cut

sub as_pair ($self) { [ $self->name, $self->arguments ] }

sub as_stripped_pair ($self) {
  $self->sentence_broker->strip_json_types($self->as_pair);
}

#pod =method as_set
#pod
#pod This method returns a L object for the
#pod current sentence.  That's a specialized Sentence for C-style JMAP
#pod method responses.
#pod
#pod =cut

sub as_set ($self) {
  unless ($self->name =~ m{/set$}) {
    return $self->sentence_broker->response->abort(
      sprintf(qq{tried to call ->as_set on sentence named "%s"}, $self->name)
    );
  }

  require JMAP::Tester::Response::Sentence::Set;
  return JMAP::Tester::Response::Sentence::Set->new({
    name         => $self->name,
    arguments    => $self->arguments,
    client_id    => $self->client_id,

    sentence_broker => $self->sentence_broker,
  });
}

#pod =method assert_named
#pod
#pod   $sentence->assert_named("theName")
#pod
#pod This method aborts unless the sentence's name is the given name.  Otherwise, it
#pod returns the sentence.
#pod
#pod =cut

sub assert_named ($self, $name) {
  Carp::confess("no name given") unless defined $name;

  return $self if $self->name eq $name;

  $self->sentence_broker->response->abort(
    sprintf qq{expected sentence named "%s" but got "%s"}, $name, $self->name
  );
}

sub TO_JSON ($self) {
  return [ $self->name, $self->arguments, $self->client_id ];
}

1;

__END__