File Coverage

blib/lib/JMAP/Tester/UA/Async.pm

Criterion	Covered	Total	%
statement	17	61	27.8
branch	0	12	0.0
condition	0	9	0.0
subroutine	6	12	50.0
pod	0	5	0.0
total	23	99	23.2

use v5.20.0;
use warnings;

package JMAP::Tester::UA::Async 0.109;

use Moo;
with 'JMAP::Tester::Role::UA';

use experimental 'signatures';

use Future;

has http_client => (
  is   => 'ro',
  required => 1,
);

sub set_cookie ($self, $arg) {
  for (qw(api_uri name value)) {
    Carp::confess("can't set_cookie without $_") unless $arg->{$_};
  }

  my $uri = URI->new($arg->{api_uri});

  $self->http_client->{cookie_jar}->set_cookie(
    1,
    $arg->{name},
    $arg->{value},
    '/',
    $arg->{domain} // $uri->host,
    $uri->port,
    0,
    ($uri->port == 443 ? 1 : 0),
    86400,
    0,
    $arg->{rest} || {},
  );
}

sub scan_cookies ($self, $callback) {
  return $self->http_client->{cookie_jar}->scan($callback);
}

has _default_headers => (
  is => 'ro',
  default => sub {
    {
      'Content-Type' => 'application/json',
    }
  },
);

sub get_default_header ($self, $name) {
  return scalar $self->_default_headers->{$name};
}

sub set_default_header ($self, $name, $value) {
  if (defined $value) {
    $self->_default_headers->{$name} = $value;
  } else {
    delete $self->_default_headers->{$name};
  }

  return;
}

sub request ($self, $tester, $req, $log_type, $log_extra = undef) {
  my $dh = $self->_default_headers;
  for my $h (keys %$dh) {
    $req->header($h => $dh->{$h}) unless defined $req->header($h);
  }

  my $logger = $tester->_logger;

  my $log_method = "log_" . ($log_type // 'jmap') . '_request';

  return $self->http_client->do_request(
    request => $req,
    on_ready => sub {
      # This fires just before the request is written to the socket, just
      # like how LWP::UserAgent logs the request before actually sending
      # it
      my $log_method = "log_" . ($log_type // 'jmap') . '_request';

      if ($logger->can($log_method)) {
        $tester->_logger->$log_method(
          $tester,
          {
            ($log_extra ? %$log_extra : ()),
            http_request => $req,
          }
        );
      }

      return Future->done;
    },
  );
}

no Moo;
1;

__END__