File Coverage

blib/lib/Iterator/Flex/Flatten.pm

Criterion	Covered	Total	%
statement	88	88	100.0
branch	26	28	92.8
condition	8	12	66.6
subroutine	16	16	100.0
pod	1	2	50.0
total	139	146	95.2

package Iterator::Flex::Flatten;

# ABSTRACT: Flatten Iterator Class

use v5.28;
use strict;
use warnings;
use experimental 'signatures';

our $VERSION = '0.34';

use Iterator::Flex::Utils qw( STATE RETURN EXHAUSTION :IterAttrs :IterStates throw_failure);
use Iterator::Flex::Factory 'construct_from_iterable', 'to_iterator';
use Ref::Util 'is_plain_arrayref', 'is_plain_hashref', 'is_blessed_ref';
use parent 'Iterator::Flex::Base';

use namespace::clean;

















































sub new ( $class, $iterable, $pars = {} ) {
    $class->SUPER::new( { src => $iterable }, $pars );
}

## no critic( ExcessComplexity )
sub construct ( $class, $state ) {

    throw_failure( parameter => q{'state' parameter must be a HASH reference} )
      unless Ref::Util::is_hashref( $state );

    my ( $prev, $current, $idx, $iter )
      = @{$state}{qw[ prev current idx iter src ]};

    my $src = @{$state}{qw[ code src ]};

    $src = to_iterator( $src );

    my $self;
    my $iterator_state;

    my $is_exhausted      = $src->can( 'is_exhausted' );
    my $iter_is_exhausted = is_blessed_ref( $iter )
      && $iter->can( 'is_exhausted' );

    my $rewind = !!0;
    my $reset  = !!0;

    return {
        ( +_NAME ) => 'iflatten',

        ( +_SELF ) => \$self,

        ( +STATE ) => \$iterator_state,

        ( +PREV ) => sub {
            return $prev;
        },

        ( +CURRENT ) => sub {
            return $current;
        },

        ( +NEXT ) => sub {
            return $self->signal_exhaustion if $iterator_state == IterState_EXHAUSTED;

            my $value;

          LOOP:
            while ( 1 ) {

                if ( !defined $iter ) {

                    $value = $src->();
                    if ( !defined $value && $src->$is_exhausted ) {
                        $prev    = $current;
                        $current = undef;
                        return $self->signal_exhaustion;
                    }

                    # most likely
                    last LOOP
                      if !ref $value || is_plain_hashref( $value );

                    # handle arrays directly; could use an iterator, but this is
                    # faster
                    if ( is_plain_arrayref( $value ) ) {
                        $iter = $value;
                        $idx  = 0;
                    }
                    else {
                        $iter = construct_from_iterable(
                            $value,
                            {
                                +( EXHAUSTION )   => RETURN,
                                action_on_failure => RETURN,
                            } );
                        last LOOP if !defined $iter;

                        $iter_is_exhausted = $iter->can( 'is_exhausted' );

                        if ( $rewind ) {
                            throw_failure( Unsupported => 'unable to rewind element' )
                              unless $iter->can( 'rewind' );
                            $iter->rewind;
                        }
                        elsif ( $reset ) {
                            throw_failure( Unsupported => 'unable to reset element' )
                              unless $iter->can( 'reset' );
                            $iter->reset;
                        }
                    }
                }

                if ( defined $idx ) {
                    if ( $idx < $iter->@* ) {
                        $value = $iter->[ $idx++ ];
                        last LOOP;
                    }
                    $iter = $idx = undef;
                    next;
                }

                $value = $iter->();
                last LOOP
                  if defined $value || !$iter->$iter_is_exhausted;

                $iter = undef;
            }

            $prev = $current;
            return $current = $value;
        },

        ( +RESET ) => sub {
            $iter   = $idx = $prev = $current = undef;
            $rewind = !!0;
            $reset  = !!1;
        },
        ( +REWIND ) => sub {
            $iter   = $idx = undef;
            $reset  = !!0;
            $rewind = !!1;
        },
        ( +_DEPENDS ) => $src,
    };
}


__PACKAGE__->_add_roles( qw[
      Current::Closure
      Next::ClosedSelf
      Prev::Closure
      Reset::Closure
      Rewind::Closure
      State::Closure
] );

1;

#
# This file is part of Iterator-Flex
#
# This software is Copyright (c) 2018 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

__END__