File Coverage

blib/lib/Iterator/Flex/Cat.pm

Criterion	Covered	Total	%
statement	54	57	94.7
branch	7	12	58.3
condition	2	3	66.6
subroutine	17	19	89.4
pod	1	1	100.0
total	81	92	88.0

package Iterator::Flex::Cat;

# ABSTRACT: An iterator which concatenates a set of iterators

use v5.28;
use strict;
use warnings;
use experimental qw( signatures declared_refs refaliasing );

our $VERSION = '0.34';

use Iterator::Flex::Utils
  qw( RETURN STATE EXHAUSTION :IterAttrs :IterStates can_meth throw_failure );
use Iterator::Flex::Factory 'to_iterator';
use parent 'Iterator::Flex::Base';
use List::Util 'all';

use namespace::clean;





































sub new ( $class, @args ) {
    my $pars = Ref::Util::is_hashref( $args[-1] ) ? pop @args : {};

    @args
      or throw_failure( parameter => 'not enough parameters' );

    $class->SUPER::new( {
            depends                => \@args,
            current_iterator_index => undef,
        },
        $pars,
    );
}

sub construct ( $class, $state ) {
    throw_failure( parameter => q{state must be a HASH reference} )
      unless Ref::Util::is_hashref( $state );

    $state->{value} //= [];

    my ( \@depends, $current_iterator, $prev, $current, $next, undef )
      = @{$state}{ 'depends', 'current_iterator', 'prev', 'current', 'next', 'thaw' };

    # transform into iterators if required.
    my @iterators
      = map { to_iterator( $_, { ( +EXHAUSTION ) => RETURN } ) } @depends;

    # -- not sure if this is just cargo-culted
    # my $value;
    # $value = $current
    #   if $thaw;

    my $self;
    my $iterator_state;
    my $iter;
    my $is_exhausted;

    my sub init {
        $current_iterator //= 0;
        if ( $current_iterator >= @iterators ) {
            $iterator_state = IterState_EXHAUSTED;
        }
        else {
            $iter         = $iterators[$current_iterator];
            $is_exhausted = $iter->can( 'is_exhausted' );
        }
    }

    init();

    my %params = (

        ( +_SELF ) => \$self,

        ( +STATE ) => \$iterator_state,

        ( +NEXT ) => sub {
            return $self->signal_exhaustion if $iterator_state == IterState_EXHAUSTED;

            while ( 1 ) {
                my $value = $iter->();
                if ( defined $value || !$iter->$is_exhausted ) {
                    $prev    = $current;
                    $current = $value;
                    return $current;
                }

                last if ++$current_iterator >= @iterators;
                $iter         = $iterators[$current_iterator];
                $is_exhausted = $iter->can( 'is_exhausted' );
            }

            # if we haven't returned, we've exhausted things
            $current_iterator = undef;
            $prev             = $current;
            return $current = $self->signal_exhaustion;
        },

        ( +PREV ) => sub {
            return $prev;
        },

        ( +CURRENT ) => sub {
            return $self->signal_exhaustion if $iterator_state eq IterState_EXHAUSTED;
            return $current;
        },

        ( +_ROLES ) => [],

        ( +_DEPENDS ) => \@iterators,
    );

    # can only freeze if the iterators support a current method
    if ( all { defined can_meth( $_, 'current' ) } @iterators ) {
        $params{ +FREEZE } = sub {
            return [
                $class,
                {
                    current_iterator => $current_iterator,
                    prev             => $prev,
                    current          => $current,
                    next             => $next,
                } ];
        };
        push $params{ +_ROLES }->@*, 'Freeze';
    }

    if ( all { defined can_meth( $_, 'reset' ) } @iterators ) {
        $params{ +RESET } = sub {
            $prev = $current = $current_iterator = undef;
            init();
        };
        push $params{ +_ROLES }->@*, 'Reset::Closure';
    }

    if ( all { defined can_meth( $_, 'rewind' ) } @iterators ) {
        $params{ +REWIND } = sub {
            $current_iterator = undef;
            init();
        };
        push $params{ +_ROLES }->@*, 'Rewind::Closure';
    }

    $params{ +_NAME } = 'icat';
    return \%params;
}


__PACKAGE__->_add_roles( qw[
      State::Closure
      Next::ClosedSelf
      Current::Closure
      Prev::Closure
] );

1;

#
# This file is part of Iterator-Flex
#
# This software is Copyright (c) 2018 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

__END__