File Coverage

blib/lib/Iterator/Flex/Zip.pm

Criterion	Covered	Total	%
statement	152	157	96.8
branch	54	72	75.0
condition	9	23	39.1
subroutine	21	21	100.0
pod	1	2	50.0
total	237	275	86.1

package Iterator::Flex::Zip;

# ABSTRACT: Zip Iterator Class

use v5.28;
use strict;
use warnings;
use experimental 'signatures', 'declared_refs';

our $VERSION = '0.33';

use Iterator::Flex::Factory 'to_iterator';
use Iterator::Flex::Utils qw[ THROW STATE EXHAUSTION :IterAttrs :IterStates throw_failure ];
use Ref::Util 'is_ref', 'is_hashref', 'is_blessed_ref';
use List::Util 'first';

use parent 'Iterator::Flex::Base';

use constant { map { $_ => lc } qw( ON_EXHAUSTION TRUNCATE THROW INSERT ) };

use namespace::clean;








































































sub new ( $class, @args ) {
    my $pars = is_hashref( $args[-1] ) ? pop @args : {};

    throw_failure( parameter => 'not enough parameters' )
      unless @args;

    my @iterators;
    my @keys;

    # distinguish between ( key => iterator, key =>iterator ) and ( iterator, iterator );
    if ( is_ref( $args[0] ) ) {
        @iterators = @args;
    }
    else {
        throw_failure( parameter => 'expected an even number of arguments' )
          if @args % 2;

        while ( @args ) {
            push @keys,      shift @args;
            push @iterators, shift @args;
        }
    }

    ## no critic (AmbiguousNames)
    my ( @set, @insert );

    my %attr = (
        keys    => \@keys,
        depends => \@iterators,
        set     => \@set,
        insert  => \@insert,
        value   => [],
    );

    if ( defined( my $on_exhaustion = delete $pars->{ +ON_EXHAUSTION } ) ) {

        if ( is_hashref( $on_exhaustion ) ) {
            my @ekeys = keys $on_exhaustion->%*;

            my %idx;
            @idx{ 0 .. $#iterators } = 0 .. $#iterators;
            @idx{@keys} = 0 .. $#iterators
              if @keys;

            my @iset = @idx{@ekeys};

            throw_failure( parameter => ON_EXHAUSTION . ' illegal iterator label or index' )
              if defined first { !defined } @iset;

            @set[@iset]    = ( !!1 ) x @iset;
            @insert[@iset] = $on_exhaustion->@{@ekeys};

            $attr{set}              = \@set;
            $attr{insert}           = \@insert;
            $attr{ +ON_EXHAUSTION } = INSERT;
        }
        elsif ( is_ref( $on_exhaustion ) or !first { $on_exhaustion eq $_ } TRUNCATE, THROW ) {
            throw_failure( parameter => ON_EXHAUSTION . ": unexpected value: $on_exhaustion" );
        }
        else {
            $attr{ +ON_EXHAUSTION } = $on_exhaustion;
        }
    }
    else {
        $attr{ +ON_EXHAUSTION } = TRUNCATE;
    }

    $class->SUPER::new( \%attr, $pars );
}


## no critic (ExcessComplexity)
sub construct ( $class, $state ) {
    throw_failure( parameter => q{state must be a HASH reference} )
      unless is_hashref( $state );

    $state->{value} //= [];

    ## no critic (AmbiguousNames)
    my ( \@depends, \@keys, \@value, \@insert, \@set, $on_exhaustion, $thaw )
      = @{$state}{qw[ depends keys value insert set on_exhaustion thaw ]};

    # transform into iterators if required.

    my @iterators
      = map { to_iterator( $_, { ( +EXHAUSTION ) => THROW } ) } @depends;

    throw_failure( parameter => q{number of keys not equal to number of iterators} )
      if @keys && @keys != @iterators;

    @value = map { $_->current } @iterators
      if $thaw;

    my $self;
    my $iterator_state;
    my %params = (

        ( +_NAME ) => 'izip',

        ( +_SELF ) => \$self,

        ( +STATE ) => \$iterator_state,


        ( +CURRENT ) => sub {
            return undef                    if !@value;
            return $self->signal_exhaustion if $iterator_state eq IterState_EXHAUSTED;
            if ( @keys ) {
                my %value;
                @value{@keys} = @value;
                return \%value;
            }
            else {
                return [@value];
            }
        },

        ( +RESET )    => sub { @value = () },
        ( +REWIND )   => sub { },
        ( +_DEPENDS ) => \@iterators,
    );

    if ( $on_exhaustion eq TRUNCATE ) {

        $params{ +NEXT } = sub {
            return $self->signal_exhaustion if $iterator_state == IterState_EXHAUSTED;

            my @nvalue;

            eval {
                @nvalue = map { $_->() } @iterators;
                1;
            } or do {
                die $@
                  unless is_blessed_ref( $@ )
                  && $@->isa( 'Iterator::Flex::Failure::Exhausted' );
                return $self->signal_exhaustion;
            };

            @value = @nvalue;

            if ( @keys ) {
                my %value;
                @value{@keys} = @value;
                return \%value;
            }
            else {
                return [@value];
            }
        };
    }

    elsif ( $on_exhaustion eq THROW ) {

        $params{ +NEXT } = sub {
            return $self->signal_exhaustion if $iterator_state == IterState_EXHAUSTED;

            my @nvalue;

            my $idx = -1;
            eval {
                ## no critic (ComplexMappings)
                @nvalue = map { $idx++; $_->() } @iterators;
                1;
            } or do {
                die $@
                  unless is_blessed_ref( $@ )
                  && $@->isa( 'Iterator::Flex::Failure::Exhausted' );

                # if all of the iterators have been exhausted,
                # then we're ok. Otherwise, find out which ones
                # are

                my @exhausted = ( $idx );
                while ( ++$idx < @iterators ) {
                    if ( !eval { $iterators[$idx]->(); 1 } ) {
                        die $@
                          unless is_blessed_ref( $@ )
                          && $@->isa( 'Iterator::Flex::Failure::Exhausted' );
                        push @exhausted, $idx;
                    }
                }
                return $self->signal_exhaustion
                  if @exhausted == @iterators;

                @exhausted = @keys[@exhausted]
                  if @keys;

                throw_failure( Truncated => \@exhausted );
            };

            @value = @nvalue;

            if ( @keys ) {
                my %value;
                @value{@keys} = @value;
                return \%value;
            }
            else {
                return [@value];
            }
        };
    }

    elsif ( $on_exhaustion eq INSERT ) {

        my @exhausted  = ( !!0 ) x @iterators;
        my $nexhausted = 0;

        $params{ +NEXT } = sub {
            return $self->signal_exhaustion
              if $iterator_state == IterState_EXHAUSTED
              || $nexhausted == @iterators;

            my @nvalue;

            for my $idx ( 0 .. $#iterators ) {

                my $value;

                if ( $exhausted[$idx] ) {
                    $value = $insert[$idx];
                }
                else {
                    eval { $value = $iterators[$idx]->(); 1 } or do {
                        die $@
                          unless is_blessed_ref( $@ )
                          && $@->isa( 'Iterator::Flex::Failure::Exhausted' );

                        # if insert value not provided for this iterator,
                        # abort
                        return $self->signal_exhaustion if !$set[$idx];

                        $nexhausted++;
                        $exhausted[$idx] = !!1;
                        $value = $insert[$idx];
                    }
                }

                push @nvalue, $value;
            }

            @value = @nvalue;

            if ( @keys ) {
                my %value;
                @value{@keys} = @value;
                return \%value;
            }
            else {
                return [@value];
            }
        };
    }


    return \%params;
}

__PACKAGE__->_add_roles( qw[
      State::Closure
      Next::ClosedSelf
      Current::Closure
      Reset::Closure
      Rewind::Closure
] );

1;

#
# This file is part of Iterator-Flex
#
# This software is Copyright (c) 2018 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

__END__