File Coverage

blib/lib/Iterator/Flex/Role/Wrap/Return.pm

Criterion	Covered	Total	%
statement	23	23	100.0
branch			n/a
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	31	31	100.0

package Iterator::Flex::Role::Wrap::Return;

# ABSTRACT: wrap imported iterator which returns a sentinel on exhaustion

use v5.28;
use strict;
use warnings;

our $VERSION = '0.33';

use Iterator::Flex::Utils qw( :default INPUT_EXHAUSTION );
use Scalar::Util;
use Role::Tiny;
use experimental 'signatures';

use namespace::clean;

around _construct_next => sub ( $orig, $class, $ipar, $gpar ) {

    my $next = $class->$orig( $ipar, $gpar );

    # this will be weakened latter.
    my $wsub;

    my $sentinel = (
        $gpar->{ +INPUT_EXHAUSTION } // do {
            require Iterator::Flex::Failure;
            Iterator::Flex::Failure::parameter->throw(
                q{internal error: input exhaustion policy was not registered} );
        }
    )->[1];

    # undef
    if ( !defined $sentinel ) {
        $wsub = sub {
            my $self = $_[0] // $wsub;
            my $val  = $next->( $self );
            return !defined $val ? $self->signal_exhaustion : $val;
        };
    }

    # reference
    elsif ( ref $sentinel ) {
        my $refaddr_sentinel = refaddr $sentinel;

        $wsub = sub {
            my $self = $_[0] // $wsub;
            my $val  = $next->( $self );
            my $addr = refaddr $val;
            return defined $addr
              && $addr == $refaddr_sentinel ? $self->signal_exhaustion : $val;
        };
    }

    # number
    elsif ( Scalar::Util::looks_like_number( $sentinel ) ) {
        $wsub = sub {
            my $self = $_[0] // $wsub;
            my $val  = $next->( $self );
            return defined $val
              && $val == $sentinel ? $self->signal_exhaustion : $val;
        };
    }

    # string
    else {
        $wsub = sub {
            my $self = $_[0] // $wsub;
            my $val  = $next->( $_[0] );
            return defined $val
              && $val eq $sentinel ? $self->signal_exhaustion : $val;
        };
    }

    # create a second reference to $wsub, before we weaken it,
    # otherwise it will lose its contents, as it would be the only
    # reference.

    my $sub = $wsub;
    Scalar::Util::weaken( $wsub );
    return $sub;
};

requires 'signal_exhaustion';

1;

#
# This file is part of Iterator-Flex
#
# This software is Copyright (c) 2018 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

__END__