File Coverage

blib/lib/Import/Into.pm

Criterion	Covered	Total	%
statement	24	26	92.3
branch	11	12	91.6
condition	5	12	41.6
subroutine	6	7	85.7
pod			n/a
total	46	57	80.7

package Import::Into;

use strict;
use warnings FATAL => 'all';
use Module::Runtime;

our $VERSION = '1.002004';

sub _prelude {
  my $target = shift;
  my ($package, $file, $line, $level)
    = ref $target         ? @{$target}{qw(package filename line)}
    : $target =~ /[^0-9]/ ? ($target)
                          : (undef, undef, undef, $target);
  if (defined $level) {
    my ($p, $fn, $ln) = caller($level + 2);
    $package ||= $p;
    $file    ||= $fn;
    $line    ||= $ln;
  }
  qq{package $package;\n}
    . ($file ? "#line $line \"$file\"\n" : '')
}

sub _make_action {
  my ($action, $target) = @_;
  my $version = ref $target && $target->{version};
  my $ver_check = $version ? ', $version' : '';
  eval _prelude($target)
    . qq{sub { Module::Runtime::use_module( shift$ver_check )->$action(\@_) }}
    or die "Failed to build action sub to ${action} for ${target}: $@";
}

sub import::into {
  my ($class, $target, @args) = @_;
  _make_action(import => $target)->($class, @args);
}

sub unimport::out_of {
  my ($class, $target, @args) = @_;
  _make_action(unimport => $target)->($class, @args);
}

1;

__END__