File Coverage

/root/.cpan/build/Imager-1.018-0/blib/lib/Imager/Color/Float.pm

Criterion	Covered	Total	%
statement	66	68	97.0
branch	39	42	92.8
condition	3	3	100.0
subroutine	10	11	90.9
pod	4	4	100.0
total	122	128	95.3

package Imager::Color::Float;
use 5.006;
use Imager;
use strict;
use Scalar::Util ();

our $VERSION = "1.008";

# It's just a front end to the XS creation functions.

sub _rgb_alpha {
  my ($alpha) = @_;
  if ($alpha =~ /^(.*)%\z/) {
    return $1 / 100;
  }
  else {
    return $alpha;
  }
}

my $rgb_key = qr/rgba?/;
my $rgb_samp = qr/(\d+(?:\.\d*)?)/;
my $rgb_pc = qr/(\d+(?:\.\d*)?)%/;
my $rgb_sep = qr/ *[, ] */;
my $rgb_rgb = qr/$rgb_samp $rgb_sep $rgb_samp $rgb_sep $rgb_samp/x;
my $rgb_rgb_pc = qr/$rgb_pc $rgb_sep $rgb_pc $rgb_sep $rgb_pc/x;
my $rgb_alpha_sep = qr/ *[\/,] */;
my $rgb_alpha = qr/((?:\.\d+|\d+(?:\.\d*)?)%?)/;

# Parse color spec into an a set of 4 colors

sub _pspec {
  if (@_ == 1 && Scalar::Util::blessed($_[0])) {
    if ($_[0]->isa("Imager::Color::Float")) {
      return $_[0]->rgba;
    } elsif ($_[0]->isa("Imager::Color")) {
      return $_[0]->as_float->rgba;
    }
  }
  return (@_,1) if @_ == 3;
  return (@_    ) if @_ == 4;
  if ($_[0] =~
      /^\#?([\da-f][\da-f])([\da-f][\da-f])([\da-f][\da-f])([\da-f][\da-f])/i) {
    return (hex($1)/255,hex($2)/255,hex($3)/255,hex($4)/255);
  }
  if ($_[0] =~ /^\#?([\da-f][\da-f])([\da-f][\da-f])([\da-f][\da-f])/i) {
    return (hex($1)/255,hex($2)/255,hex($3)/255,1);
  }
  if (@_ == 1) {
    # CSS Color 4 says that color values are rounded to +Inf
    if ($_[0] =~ /\A$rgb_key\( *$rgb_rgb *\)\z/) {
      return ( $1 / 255, $2 / 255, $3 / 255, 1.0 );
    }
    elsif ($_[0] =~ /\A$rgb_key\( *$rgb_rgb_pc *\)\z/) {
      return ( $1 / 100, $2 / 100, $3 / 100, 1.0 );
    }
    elsif ($_[0] =~ /\A$rgb_key\( *$rgb_rgb$rgb_alpha_sep$rgb_alpha *\)\z/) {
      return ( $1 / 255, $2 / 255, $3 / 255, _rgb_alpha($4) );
    }
    elsif ($_[0] =~ /\A$rgb_key\( *$rgb_rgb_pc$rgb_alpha_sep$rgb_alpha *\)\z/) {
      return ( $1 / 100, $2 / 100, $3 / 100, _rgb_alpha($4) );
    }
  }

  return ();
}

sub new {
  shift; # get rid of class name.
  my @arg = _pspec(@_);
  return @arg ? new_internal($arg[0],$arg[1],$arg[2],$arg[3]) : ();
}

sub set {
  my $self = shift;
  my @arg = _pspec(@_);
  return @arg ? set_internal($self, $arg[0],$arg[1],$arg[2],$arg[3]) : ();
}

sub CLONE_SKIP { 1 }

sub as_8bit {
  my ($self) = @_;

  my @out;
  for my $s ($self->rgba) {
    my $result = 0+sprintf("%.f", $s * 255);
    $result = $result < 0 ? 0 :
      $result > 255 ? 255 :
      $result;
    push @out, $result;
  }

  return Imager::Color->new(@out);
}

sub as_css_rgb {
  my ($self) = @_;

  my (@rgb) = $self->rgba;
  my $alpha = pop @rgb;
  # check if they're all representable as byte type samples
  my $can_byte = 1;
  for my $s (@rgb) {
    if (abs(sprintf("%.0f", $s * 255) - $s*255) > 0.0001) {
      $can_byte = 0;
      last;
    }
  }

  if ($alpha == 1.0) {
    if ($can_byte) {
      return sprintf("rgb(%.0f, %.0f, %.0f)", map { 255 * $_ } @rgb);
    }
    else {
      # avoid outputting 2 decimals unless the precision is needed
      my ($rpc, $gpc, $bpc) = map { 0 + sprintf("%.2f", 100 * $_) } @rgb;
      return "rgb($rpc% $gpc% $bpc%)";
    }
  }
  else {
    my $apf = 0+sprintf("%.4f", $alpha);
    if ($can_byte) {
      return sprintf("rgba(%.0f, %.0f, %.0f, %s)", ( map { 255 * $_ } @rgb ), $apf);
    }
    else {
      # avoid outputting 2 decimals unless the precision is needed
      my ($rpc, $gpc, $bpc) = map { 0 + sprintf("%.2f", 100 * $_) } @rgb;
      return "rgba($rpc% $gpc% $bpc% / $apf)";
    }
  }
}

1;

__END__