File Coverage

blib/lib/IBM/StorageSystem/FileSystem.pm

Criterion	Covered	Total	%
statement	24	45	53.3
branch	0	10	0.0
condition			n/a
subroutine	8	17	47.0
pod	0	1	0.0
total	32	73	43.8

package IBM::StorageSystem::FileSystem;

use strict;
use warnings;

use IBM::StorageSystem::FileSystem::FileSet;
use IBM::StorageSystem::Snapshot;
use Scalar::Util qw(weaken);
use Carp qw(croak);

our $VERSION = '0.01';
our @ATTR = qw(ACLtype Atime Block_allocation_type Block_size Cluster Def_quota
Device_name Dmapi Ind_block_size Inode_size Inodes Last_update Locking_type
Log_placement Logf_size Max_Inodes Min_frag_size Mount_point Mtime Quota
Remote_device Replication Snapdir State Type Version);

our $OBJ = {
		fileset => {
			cmd	=> 'lsfset -v -Y',
			id	=> 'ID',
			class	=> 'IBM::StorageSystem::FileSystem::FileSet',
			type	=> 'fset',
			sl	=> 1
		},
		snapshot => {
			cmd	=> 'lssnapshot -Y',
			id	=> 'Snapshot_ID',
			class	=> 'IBM::StorageSystem::Snapshot',
			type	=> 'snapshot',
			sl	=> 1
		}
};

foreach my $obj ( keys %{ $OBJ } ) {
	{
	no strict 'refs';

	my $m = 'get_'.$obj.'s';

	*{ __PACKAGE__ ."::$obj" } =
		sub {
			my( $self, $id ) = @_;
			defined $id or return;

			return ( $self->{$obj}->{$id} 	? $self->{$obj}->{$id}
							: $self->$m( $id )
				)
		};

	*{ __PACKAGE__ .'::get_'. $obj } =
		sub {
			my ( $self, $id ) = @_;
			return $self->$m( $id )
		};

	*{ __PACKAGE__ . "::$m" } =
		sub {
			my ( $self, $id ) = @_;
			my %args = ( cmd	=> "$OBJ->{$obj}->{cmd} ".$self->device_name,
				     class	=> $OBJ->{$obj}->{class},
				     type	=> $OBJ->{$obj}->{type},
				     id		=> $OBJ->{$obj}->{id}
				);
			my @res = map { $_->device_name( $self->{device_name} ); $_
				      } $self->{__ibm}->__get_sl_objects( %args );

			return ( defined $id	? $self->{ $OBJ->{$obj}->{type} }->{$id}
						: @res
				)
		}
	}
}

foreach my $attr ( map lc, @ATTR ) {
        {
                no strict 'refs';
                *{ __PACKAGE__ .'::'. $attr } = sub {
                        my( $self, $val ) = @_;
                        $self->{$attr} = $val if $val;
                        return $self->{$attr}
                }
        }
}

sub new {
        my( $class, $ibm, %args ) = @_;
        my $self = bless {}, $class;
        defined $args{'Device_name'}
		or croak __PACKAGE__ . ' constructor failed: mandatory Device_name argument not supplied';
	weaken( $self->{__ibm} = $ibm );

        foreach my $attr ( @ATTR ) {
		$self->{lc $attr} = $args{$attr}
	}

        return $self
}

1;

__END__