File Coverage

blib/lib/HealthCheck/WebRequests.pm

Criterion	Covered	Total	%
statement	40	41	97.5
branch	7	12	58.3
condition	5	13	38.4
subroutine	9	9	100.0
pod	2	2	100.0
total	63	77	81.8

package HealthCheck::WebRequests;
use parent 'HealthCheck';

# ABSTRACT: Make HTTP/HTTPS requests to web servers to check connectivity
use version;
our $VERSION = 'v1.4.4'; # VERSION

use strict;
use warnings;

use Carp;
use HealthCheck::Diagnostic::WebRequest;
use Scalar::Util 'blessed';

sub new {
    my ($class, @params) = @_;

    my %params = @params == 1 && ( ref $params[0] || '' ) eq 'HASH'
        ? %{ $params[0] } : @params;

    my @bad_params = grep {
        !/^(  checks
            | content_regex
            | id
            | label
            | no_follow_redirects
            | options
            | response_time_threshold
            | status_code
            | status_code_eval
            | runbook
            | tags
            | timeout
            | ua
        )$/x
    } keys %params;

    carp("Invalid parameter: " . join(", ", @bad_params)) if @bad_params;

    croak "No checks specified!" unless $params{checks};

    my %default_params = %params;
    delete $default_params{checks};
    $params{default_params} = \%default_params;

    return $class->SUPER::new(
        label => 'web_requests',
        %params,
    );
}

sub register {
    my ( $self, @checks ) = @_;
    @checks = @{ $checks[0] } if @checks == 1 && ( ref $checks[0] || '' ) eq 'ARRAY';

    for my $check (@checks) {
        if ( ( ref $check || '' ) eq 'HASH' ) {
            $check = HealthCheck::Diagnostic::WebRequest->new( %{ $self->{default_params} }, %$check );
        }

        croak "Invalid check. Checks must either be a hashref or HealthCheck::Diagnostic::WebRequest"
            unless blessed $check
            and $check->isa("HealthCheck::Diagnostic::WebRequest");
    }

    return $self->SUPER::register(@checks);
}

1;

__END__